extension/lib/vim-frame.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file is the equivalent to vim.coffee. `vim.window` is called
  22 # `vim.content` to be consistent with Firefox’s frame script terminology and to
  23 # avoid confusion about what it represents. There is one `VimFrame` instance for
  24 # each tab. It mostly tries to mimic the `Vim` class in vim.coffee, but also
  25 # keeps track of web page state. `VimFrame` is not part of the config file API.
  26
  27 messageManager = require('./message-manager')
  28 ScrollableElements = require('./scrollable-elements')
  29 utils = require('./utils')
  30
  31 class VimFrame
  32   constructor: (@content) ->
  33     @mode = 'normal'
  34     @hintMatcher = null
  35
  36     @resetState()
  37
  38     messageManager.listen('modeChange', ({mode}) =>
  39       @mode = mode
  40     )
  41
  42     messageManager.listen('markPageInteraction',
  43                           @markPageInteraction.bind(this))
  44
  45     messageManager.listen('clearHover', @clearHover.bind(this))
  46
  47   # If the target is the topmost document, reset everything. Otherwise filter
  48   # out elements belonging to the target frame. On some sites, such as Gmail,
  49   # some elements might be dead at this point.
  50   resetState: (target = @content.document) ->
  51     if target == @content.document
  52       @state = {
  53         hasInteraction: false
  54         shouldRefocus: false
  55         marks: {}
  56         explicitBodyFocus: false
  57         hasFocusedTextInput: false
  58         lastFocusedTextInput: null
  59         lastHoveredElement: null
  60         scrollableElements: new ScrollableElements(@content)
  61         markerElements: []
  62         inputs: null
  63       }
  64
  65     else
  66       isDead = (element) ->
  67         return Cu.isDeadWrapper(element) or element.ownerDocument == target
  68       check = (prop) =>
  69         @state[prop] = null if @state[prop] and isDead(@state[prop])
  70
  71       check('lastFocusedTextInput')
  72       check('lastHoveredElement')
  73       @state.scrollableElements.reject(isDead)
  74       # `markerElements` and `inputs` could theoretically need to be filtered
  75       # too at this point. YAGNI until an issue arises from it.
  76
  77   options: (prefs) -> messageManager.get('options', {prefs})
  78
  79   enterMode: (@mode, args...) ->
  80     messageManager.send('vimMethod', {
  81       method: 'enterMode'
  82       args: [@mode, args...]
  83     })
  84
  85   onInput: (event) ->
  86     focusType = utils.getFocusType(event.originalTarget)
  87     suppress = messageManager.get('consumeKeyEvent', {focusType})
  88     return suppress
  89
  90   notify: (args...) ->
  91     messageManager.send('vimMethod', {method: 'notify', args})
  92
  93   markPageInteraction: (value = true) -> @state.hasInteraction = value
  94
  95   setHover: (element) ->
  96     utils.setHover(element, true)
  97     utils.simulateMouseEvents(element, 'hover-start')
  98     @state.lastHoveredElement = element
  99
 100   clearHover: ->
 101     if @state.lastHoveredElement
 102       utils.setHover(@state.lastHoveredElement, false)
 103       utils.simulateMouseEvents(@state.lastHoveredElement, 'hover-end')
 104     @state.lastHoveredElement = null
 105
 106 module.exports = VimFrame