packages/vim.coffee

   1 { getWindowId, Bucket } = require 'utils'
   2
   3 { commands,
   4   hintCharHandler
   5 } = require 'commands'
   6
   7 MODE_NORMAL = 1
   8 MODE_HINTS  = 2
   9
  10 class Vim
  11   constructor: (@window) ->
  12     @mode     = MODE_NORMAL
  13     @keys     = []
  14     @markers  = undefined
  15     @cb       = undefined
  16
  17   pushKey: (keyStr) ->
  18     console.log keyStr
  19     if _maybeCommand(@mode, @keys, keyStr)
  20       @keys.push keyStr
  21       return true
  22
  23     return false
  24
  25   execKeys: ->
  26     console.log @keys.join(',')
  27     if command = _getCommand(@mode, @keys)
  28       lastKey = @keys[@keys.length - 1]
  29       command @
  30       @keys = []
  31       return lastKey != 'Esc'
  32
  33   enterHintsMode: () ->
  34     @mode = MODE_HINTS
  35
  36   enterNormalMode: () ->
  37     @markers = @cb = undefined
  38
  39     @mode = MODE_NORMAL
  40
  41 _getCommand = (mode, keys) ->
  42   lastKey = keys[keys.length - 1]
  43
  44   if mode == MODE_NORMAL or lastKey == 'Esc'
  45     sequence = keys.join(',')
  46     if command = commands[sequence]
  47       return command
  48     else if keys.length > 0
  49       return _getCommand mode, keys.slice(1)
  50
  51   else if mode == MODE_HINTS and keys.length > 0
  52     return (vim) =>
  53       return hintCharHandler(vim, lastKey.toLowerCase())
  54
  55   return undefined
  56
  57 _maybeCommand = (mode, keys, keyStr) ->
  58   if mode == MODE_NORMAL || keyStr == 'Esc'
  59     sequence = keys.concat([keyStr]).join(',')
  60     for commandSequence in Object.keys(commands)
  61       if commandSequence.search(sequence) == 0
  62         return true
  63
  64     if keys.length > 0
  65       return _maybeCommand mode, keys.slice(1), keyStr
  66
  67   else if mode == MODE_HINTS
  68     return true
  69
  70   return false
  71
  72 exports.Vim = Vim