extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 config = require('./config')
  30 help = require('./help')
  31 markableElements = require('./markable-elements')
  32 MarkerContainer = require('./marker-container')
  33 parsePrefs = require('./parse-prefs')
  34 prefs = require('./prefs')
  35 SelectionManager = require('./selection')
  36 translate = require('./translate')
  37 utils = require('./utils')
  38 viewportUtils = require('./viewport')
  39
  40 {ContentClick} = Cu.import('resource:///modules/ContentClick.jsm', {})
  41 {FORWARD, BACKWARD} = SelectionManager
  42
  43 SPRING_CONSTANT_PREF = 'layout.css.scroll-behavior.spring-constant'
  44
  45 commands = {}
  46
  47
  48
  49 commands.focus_location_bar = ({vim}) ->
  50   vim.window.focusAndSelectUrlBar()
  51
  52 commands.focus_search_bar = ({vim, count}) ->
  53   # The `.webSearch()` method opens a search engine in a tab if the search bar
  54   # has been removed. Therefore we first check if it exists.
  55   if vim.window.BrowserSearch.searchBar
  56     vim.window.BrowserSearch.webSearch()
  57   else
  58     vim.notify(translate('notification.focus_search_bar.none'))
  59
  60 helper_paste_and_go = (props, {vim}) ->
  61   {gURLBar} = vim.window
  62   gURLBar.value = vim.window.readFromClipboard()
  63   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  64
  65 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  66
  67 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  68
  69 commands.copy_current_url = ({vim}) ->
  70   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  71   vim.notify(translate('notification.copy_current_url.success'))
  72
  73 commands.go_up_path = ({vim, count}) ->
  74   vim._run('go_up_path', {count})
  75
  76 commands.go_to_root = ({vim}) ->
  77   vim._run('go_to_root')
  78
  79 commands.go_home = ({vim}) ->
  80   vim.window.BrowserHome()
  81
  82 helper_go_history = (direction, {vim, count = 1}) ->
  83   {window} = vim
  84   {SessionStore, gBrowser} = window
  85
  86   if (direction == 'back'    and not gBrowser.canGoBack) or
  87      (direction == 'forward' and not gBrowser.canGoForward)
  88     vim.notify(translate("notification.history_#{direction}.limit"))
  89     return
  90
  91   # `SessionStore.getSessionHistory()` (used below to support counts) starts
  92   # lots of asynchronous tasks internally, which is a bit unreliable, it has
  93   # turned out. The primary use of the `history_back` and `history_forward`
  94   # commands is to go _one_ step back or forward, though, so those cases are
  95   # optimized to use more reliable ways of going back and forward. Also, some
  96   # extensions override the following functions, so calling them also gives
  97   # better interoperability.
  98   if count == 1
  99     if direction == 'back'
 100       window.BrowserBack()
 101     else
 102       window.BrowserForward()
 103     return
 104
 105   SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
 106     {index} = sessionHistory
 107     newIndex = index + count * (if direction == 'back' then -1 else 1)
 108     newIndex = Math.max(newIndex, 0)
 109     newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
 110     gBrowser.gotoIndex(newIndex)
 111   )
 112
 113 commands.history_back    = helper_go_history.bind(null, 'back')
 114
 115 commands.history_forward = helper_go_history.bind(null, 'forward')
 116
 117 commands.history_list = ({vim}) ->
 118   menu = vim.window.document.getElementById('backForwardMenu')
 119   utils.openPopup(menu)
 120   if menu.childElementCount == 0
 121     vim.notify(translate('notification.history_list.none'))
 122
 123 commands.reload = ({vim}) ->
 124   vim.window.BrowserReload()
 125
 126 commands.reload_force = ({vim}) ->
 127   vim.window.BrowserReloadSkipCache()
 128
 129 commands.reload_all = ({vim}) ->
 130   vim.window.gBrowser.reloadAllTabs()
 131
 132 commands.reload_all_force = ({vim}) ->
 133   for tab in vim.window.gBrowser.visibleTabs
 134     gBrowser = tab.linkedBrowser
 135     consts = gBrowser.webNavigation
 136     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 137     gBrowser.reload(flags)
 138   return
 139
 140 commands.stop = ({vim}) ->
 141   vim.window.BrowserStop()
 142
 143 commands.stop_all = ({vim}) ->
 144   for tab in vim.window.gBrowser.visibleTabs
 145     tab.linkedBrowser.stop()
 146   return
 147
 148
 149
 150 springConstant = {
 151   nonce: null
 152   value: null
 153 }
 154
 155 helper_scroll = (vim, event, args...) ->
 156   [
 157     method, type, directions, amounts
 158     properties = null, adjustment = 0, name = 'scroll', extra = {}
 159   ] = args
 160   options = {
 161     method, type, directions, amounts, properties, adjustment, extra
 162     smooth: (
 163       prefs.root.get('general.smoothScroll') and
 164       prefs.root.get("general.smoothScroll.#{type}")
 165     )
 166   }
 167
 168   # Temporarily set Firefox’s “spring constant” pref to get the desired smooth
 169   # scrolling speed. Reset it `reset_timeout` milliseconds after the last
 170   # scrolling command was invoked.
 171   springConstant.nonce = nonce = {}
 172   springConstant.value ?= prefs.root.get(SPRING_CONSTANT_PREF)
 173   prefs.root.set(
 174     SPRING_CONSTANT_PREF,
 175     vim.options["smoothScroll.#{type}.spring-constant"]
 176   )
 177   reset = ->
 178     vim.window.setTimeout((->
 179       return unless springConstant.nonce == nonce
 180       prefs.root.set(SPRING_CONSTANT_PREF, springConstant.value)
 181       springConstant.nonce = null
 182       springConstant.value = null
 183     ), vim.options['scroll.reset_timeout'])
 184
 185   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 186   if (event and vim.isUIEvent(event)) or helpScroll
 187     activeElement = helpScroll or utils.getActiveElement(vim.window)
 188     if vim._state.scrollableElements.has(activeElement) or helpScroll
 189       viewportUtils.scroll(activeElement, options)
 190       reset()
 191       return
 192
 193   vim._run(name, options, reset)
 194
 195
 196 helper_scrollByLinesX = (amount, {vim, event, count = 1}) ->
 197   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 198   boost = if event.repeat then vim.options['scroll.horizontal_boost'] else 1
 199   helper_scroll(
 200     vim, event, 'scrollBy', 'lines', ['left'],
 201     [amount * distance * boost * count * 5]
 202   )
 203
 204 helper_scrollByLinesY = (amount, {vim, event, count = 1}) ->
 205   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 206   boost = if event.repeat then vim.options['scroll.vertical_boost'] else 1
 207   helper_scroll(
 208     vim, event, 'scrollBy', 'lines', ['top'],
 209     [amount * distance * boost * count * 20]
 210   )
 211
 212 helper_scrollByPagesY = (amount, type, {vim, event, count = 1}) ->
 213   adjustment = vim.options["scroll.#{type}_page_adjustment"]
 214   helper_scroll(
 215     vim, event, 'scrollBy', 'pages', ['top'], [amount * count],
 216     ['clientHeight'], adjustment
 217   )
 218
 219 helper_scrollToX = (amount, {vim, event}) ->
 220   helper_mark_last_scroll_position(vim)
 221   helper_scroll(
 222     vim, event, 'scrollTo', 'other', ['left'], [amount], ['scrollLeftMax']
 223   )
 224
 225 helper_scrollToY = (amount, {vim, event}) ->
 226   helper_mark_last_scroll_position(vim)
 227   helper_scroll(
 228     vim, event, 'scrollTo', 'other', ['top'], [amount], ['scrollTopMax']
 229   )
 230
 231 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 232 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 233 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 234 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 235 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 236 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 237 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 238 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 239 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 240 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 241 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 242 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 243
 244 helper_mark_last_scroll_position = (vim) ->
 245   keyStr = vim.options['scroll.last_position_mark']
 246   vim._run('mark_scroll_position', {keyStr, notify: false, addToJumpList: true})
 247
 248 commands.mark_scroll_position = ({vim}) ->
 249   vim._enterMode('marks', (keyStr) ->
 250     vim._run('mark_scroll_position', {keyStr})
 251   )
 252   vim.notify(translate('notification.mark_scroll_position.enter'))
 253
 254 commands.scroll_to_mark = ({vim}) ->
 255   vim._enterMode('marks', (keyStr) ->
 256     helper_scroll(
 257       vim, null, 'scrollTo', 'other', ['left', 'top'], [0, 0]
 258       ['scrollLeftMax', 'scrollTopMax'], 0, 'scroll_to_mark'
 259       {keyStr, lastPositionMark: vim.options['scroll.last_position_mark']}
 260     )
 261     vim.hideNotification()
 262   )
 263   vim.notify(translate('notification.scroll_to_mark.enter'))
 264
 265 helper_scroll_to_position = (direction, {vim, count = 1}) ->
 266   lastPositionMark = vim.options['scroll.last_position_mark']
 267   helper_scroll(
 268     vim, null, 'scrollTo', 'other', ['left', 'top'], [0, 0]
 269     ['scrollLeftMax', 'scrollTopMax'], 0, 'scroll_to_position'
 270     {count, direction, lastPositionMark}
 271   )
 272
 273 commands.scroll_to_previous_position =
 274   helper_scroll_to_position.bind(null, 'previous')
 275
 276 commands.scroll_to_next_position =
 277   helper_scroll_to_position.bind(null, 'next')
 278
 279
 280
 281 commands.tab_new = ({vim}) ->
 282   utils.nextTick(vim.window, ->
 283     vim.window.BrowserOpenTab()
 284   )
 285
 286 commands.tab_new_after_current = ({vim}) ->
 287   {window} = vim
 288   newTabPosition = window.gBrowser.selectedTab._tPos + 1
 289   utils.nextTick(window, ->
 290     utils.listenOnce(window, 'TabOpen', (event) ->
 291       newTab = event.originalTarget
 292       window.gBrowser.moveTabTo(newTab, newTabPosition)
 293     )
 294     window.BrowserOpenTab()
 295   )
 296
 297 commands.tab_duplicate = ({vim}) ->
 298   {gBrowser} = vim.window
 299   utils.nextTick(vim.window, ->
 300     gBrowser.duplicateTab(gBrowser.selectedTab)
 301   )
 302
 303 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 304   tabs = gBrowser.visibleTabs
 305   {selectedTab} = gBrowser
 306
 307   currentIndex = tabs.indexOf(selectedTab)
 308   absoluteIndex = currentIndex + relativeIndex
 309   numTabsTotal = tabs.length
 310   numPinnedTabs = gBrowser._numPinnedTabs
 311
 312   [numTabs, min] = switch
 313     when not pinnedSeparate
 314       [numTabsTotal,  0]
 315     when selectedTab.pinned
 316       [numPinnedTabs, 0]
 317     else
 318       [numTabsTotal - numPinnedTabs, numPinnedTabs]
 319
 320   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 321   # current direction.
 322   if (relativeIndex < 0 and currentIndex == min) or
 323      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 324     if absoluteIndex < min
 325       absoluteIndex += numTabs
 326     else if absoluteIndex >= min + numTabs
 327       absoluteIndex -= numTabs
 328
 329   absoluteIndex = Math.max(min, absoluteIndex)
 330   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 331
 332   return absoluteIndex
 333
 334 helper_switch_tab = (direction, {vim, count = 1}) ->
 335   {gBrowser} = vim.window
 336   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 337   utils.nextTick(vim.window, ->
 338     gBrowser.selectTabAtIndex(index)
 339   )
 340
 341 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 342
 343 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 344
 345 helper_is_visited = (tab) ->
 346   return tab.getAttribute('VimFx-visited') or not tab.getAttribute('unread')
 347
 348 commands.tab_select_most_recent = ({vim, count = 1}) ->
 349   {gBrowser} = vim.window
 350   tabsSorted =
 351     Array.filter(
 352       gBrowser.tabs,
 353       (tab) -> not tab.closing and helper_is_visited(tab)
 354     ).sort((a, b) -> b.lastAccessed - a.lastAccessed)[1..] # Remove current tab.
 355   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 356   if tab
 357     gBrowser.selectedTab = tab
 358   else
 359     vim.notify(translate('notification.tab_select_most_recent.none'))
 360
 361 commands.tab_select_oldest_unvisited = ({vim, count = 1}) ->
 362   {gBrowser} = vim.window
 363   tabsSorted =
 364     Array.filter(
 365       gBrowser.tabs,
 366       (tab) -> not tab.closing and not helper_is_visited(tab)
 367     ).sort((a, b) -> a.lastAccessed - b.lastAccessed)
 368   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 369   if tab
 370     gBrowser.selectedTab = tab
 371   else
 372     vim.notify(translate('notification.tab_select_oldest_unvisited.none'))
 373
 374 helper_move_tab = (direction, {vim, count = 1}) ->
 375   {gBrowser} = vim.window
 376   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 377   utils.nextTick(vim.window, ->
 378     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 379   )
 380
 381 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 382
 383 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 384
 385 commands.tab_move_to_window = ({vim}) ->
 386   {gBrowser} = vim.window
 387   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 388
 389 commands.tab_select_first = ({vim, count = 1}) ->
 390   utils.nextTick(vim.window, ->
 391     vim.window.gBrowser.selectTabAtIndex(count - 1)
 392   )
 393
 394 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 395   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 396   utils.nextTick(vim.window, ->
 397     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 398   )
 399
 400 commands.tab_select_last = ({vim, count = 1}) ->
 401   utils.nextTick(vim.window, ->
 402     vim.window.gBrowser.selectTabAtIndex(-count)
 403   )
 404
 405 commands.tab_toggle_pinned = ({vim}) ->
 406   currentTab = vim.window.gBrowser.selectedTab
 407   if currentTab.pinned
 408     vim.window.gBrowser.unpinTab(currentTab)
 409   else
 410     vim.window.gBrowser.pinTab(currentTab)
 411
 412 commands.tab_close = ({vim, count = 1}) ->
 413   {gBrowser} = vim.window
 414   return if gBrowser.selectedTab.pinned
 415   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 416   utils.nextTick(vim.window, ->
 417     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 418       gBrowser.removeTab(tab)
 419     return
 420   )
 421
 422 commands.tab_restore = ({vim, count = 1}) ->
 423   utils.nextTick(vim.window, ->
 424     for index in [0...count] by 1
 425       restoredTab = vim.window.undoCloseTab()
 426       if not restoredTab and index == 0
 427         vim.notify(translate('notification.tab_restore.none'))
 428         break
 429     return
 430   )
 431
 432 commands.tab_restore_list = ({vim}) ->
 433   {window} = vim
 434   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 435     window, 'menuitem'
 436   )
 437   if fragment.childElementCount == 0
 438     vim.notify(translate('notification.tab_restore.none'))
 439   else
 440     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 441
 442 commands.tab_close_to_end = ({vim}) ->
 443   {gBrowser} = vim.window
 444   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 445
 446 commands.tab_close_other = ({vim}) ->
 447   {gBrowser} = vim.window
 448   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 449
 450
 451
 452 helper_follow = ({name, callback}, {vim, count, callbackOverride = null}) ->
 453   {window} = vim
 454   vim.markPageInteraction()
 455   help.removeHelp(window)
 456
 457   markerContainer = new MarkerContainer({
 458     window
 459     hintChars: vim.options['hints.chars']
 460     getComplementaryWrappers: (callback) ->
 461       vim._run(name, {pass: 'complementary'}, ({wrappers, viewport}) ->
 462         # `markerContainer.container` is `null`ed out when leaving Hints mode.
 463         # If this callback is called after we’ve left Hints mode (and perhaps
 464         # even entered it again), simply discard the result.
 465         return unless markerContainer.container
 466         if wrappers.length == 0
 467           vim.notify(translate('notification.follow.none'))
 468         callback({wrappers, viewport})
 469       )
 470   })
 471   MarkerContainer.remove(window) # Better safe than sorry.
 472   window.gBrowser.selectedBrowser.parentNode.appendChild(
 473     markerContainer.container
 474   )
 475
 476   chooseCallback = (marker, timesLeft, keyStr) ->
 477     if callbackOverride
 478       {type, href = null, elementIndex} = marker.wrapper
 479       return callbackOverride({type, href, id: elementIndex, timesLeft})
 480     else
 481       return callback(marker, timesLeft, keyStr)
 482
 483   # Enter Hints mode immediately, with an empty set of markers. The user might
 484   # press keys before any hints have been generated. Those keypresses should be
 485   # handled in Hints mode, not Normal mode.
 486   vim._enterMode('hints', {
 487     markerContainer, count
 488     callback: chooseCallback
 489     matchText: vim.options['hints.match_text']
 490     sleep: vim.options['hints.sleep']
 491   })
 492
 493   injectHints = ({wrappers, viewport, pass}) ->
 494     # See `getComplementaryWrappers` above.
 495     return unless markerContainer.container
 496
 497     if wrappers.length == 0
 498       if pass in ['single', 'second'] and markerContainer.markers.length == 0
 499         vim.notify(translate('notification.follow.none'))
 500         vim._enterMode('normal')
 501     else
 502       markerContainer.injectHints(wrappers, viewport, pass)
 503
 504     if pass == 'first'
 505       vim._run(name, {pass: 'second'}, injectHints)
 506
 507   vim._run(name, {pass: 'auto'}, injectHints)
 508
 509 helper_follow_clickable = (options, args) ->
 510   {vim} = args
 511
 512   callback = (marker, timesLeft, keyStr) ->
 513     {inTab, inBackground} = options
 514     {type, elementIndex} = marker.wrapper
 515     isLast = (timesLeft == 1)
 516     isLink = (type == 'link')
 517     {window} = vim
 518
 519     switch
 520       when keyStr.startsWith(vim.options['hints.toggle_in_tab'])
 521         inTab = not inTab
 522       when keyStr.startsWith(vim.options['hints.toggle_in_background'])
 523         inTab = true
 524         inBackground = not inBackground
 525       else
 526         unless isLast
 527           inTab = true
 528           inBackground = true
 529
 530     inTab = false unless isLink
 531
 532     if type == 'text' or (isLink and not (inTab and inBackground))
 533       isLast = true
 534
 535     vim._focusMarkerElement(elementIndex)
 536
 537     if inTab
 538       utils.nextTick(window, ->
 539         # `ContentClick.contentAreaClick` is what Firefox invokes when you click
 540         # links using the mouse. Using that instead of simply
 541         # `gBrowser.loadOneTab(url, options)` gives better interoperability with
 542         # other add-ons, such as Tree Style Tab and BackTrack Tab History.
 543         reset = prefs.root.tmp('browser.tabs.loadInBackground', true)
 544         ContentClick.contentAreaClick({
 545           href: marker.wrapper.href
 546           shiftKey: not inBackground
 547           ctrlKey: true
 548           metaKey: true
 549           originAttributes: window.document.nodePrincipal?.originAttributes ? {}
 550         }, vim.browser)
 551         reset()
 552       )
 553
 554     # The point of “clicking” scrollable elements is focusing them (which is
 555     # done above) so that scrolling commands may scroll them. Simulating a click
 556     # here usually _unfocuses_ the element.
 557     else if type != 'scrollable'
 558       vim._run('click_marker_element', {
 559         elementIndex, type
 560         browserOffset: vim._getBrowserOffset()
 561         preventTargetBlank: vim.options.prevent_target_blank
 562       })
 563
 564     return not isLast
 565
 566   name = if options.inTab then 'follow_in_tab' else 'follow'
 567   helper_follow({name, callback}, args)
 568
 569 commands.follow =
 570   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 571
 572 commands.follow_in_tab =
 573   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 574
 575 commands.follow_in_focused_tab =
 576   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 577
 578 helper_follow_in_window = (options, args) ->
 579   {vim} = args
 580
 581   callback = (marker) ->
 582     vim._focusMarkerElement(marker.wrapper.elementIndex)
 583     {href} = marker.wrapper
 584     vim.window.openLinkIn(href, 'window', options) if href
 585     return false
 586
 587   helper_follow({name: 'follow_in_tab', callback}, args)
 588
 589 commands.follow_in_window =
 590   helper_follow_in_window.bind(null, {})
 591
 592 commands.follow_in_private_window =
 593   helper_follow_in_window.bind(null, {private: true})
 594
 595 commands.follow_multiple = (args) ->
 596   args.count = Infinity
 597   commands.follow(args)
 598
 599 commands.follow_copy = (args) ->
 600   {vim} = args
 601
 602   callback = (marker) ->
 603     property = switch marker.wrapper.type
 604       when 'link'
 605         'href'
 606       when 'text'
 607         'value'
 608       when 'contenteditable', 'complementary'
 609         '_selection'
 610     helper_copy_marker_element(vim, marker.wrapper.elementIndex, property)
 611     return false
 612
 613   helper_follow({name: 'follow_copy', callback}, args)
 614
 615 commands.follow_focus = (args) ->
 616   {vim} = args
 617
 618   callback = (marker) ->
 619     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 620     return false
 621
 622   helper_follow({name: 'follow_focus', callback}, args)
 623
 624 commands.open_context_menu = (args) ->
 625   {vim} = args
 626
 627   callback = (marker) ->
 628     {type, elementIndex} = marker.wrapper
 629     vim._run('click_marker_element', {
 630       elementIndex, type
 631       browserOffset: vim._getBrowserOffset()
 632     })
 633     return false
 634
 635   helper_follow({name: 'follow_context', callback}, args)
 636
 637 commands.click_browser_element = ({vim}) ->
 638   {window} = vim
 639   markerElements = []
 640
 641   getButtonMenu = (element) ->
 642     if element.localName == 'dropmarker' and
 643        element.parentNode?.localName == 'toolbarbutton'
 644       return element.parentNode.querySelector('menupopup')
 645     else
 646       return null
 647
 648   filter = ({complementary}, element, getElementShape) ->
 649     type = switch
 650       when vim._state.scrollableElements.has(element)
 651         'scrollable'
 652       when getButtonMenu(element)
 653         'dropmarker'
 654       when utils.isFocusable(element) or
 655            (element.onclick and element.localName != 'statuspanel')
 656         'clickable'
 657
 658     if complementary
 659       type = if type then null else 'complementary'
 660
 661     return unless type
 662
 663     # `getElementShape(element, -1)` is intentionally _not_ used in the
 664     # `complementary` run, because it results in tons of useless hints for
 665     # hidden context menus.
 666     shape = getElementShape(element)
 667     return unless shape.nonCoveredPoint
 668
 669     # The tabs and their close buttons as well as the tab bar scroll arrows get
 670     # better hints, since switching or closing tabs is the most common use case
 671     # for the `eb` command.
 672     isTab = element.classList?.contains('tabbrowser-tab')
 673     isPrioritized =
 674       isTab or
 675       element.classList?.contains('tab-close-button') or
 676       element.classList?.contains('scrollbutton-up') or
 677       element.classList?.contains('scrollbutton-down')
 678
 679     length = markerElements.push(element)
 680     return {
 681       type, shape, isTab, isPrioritized,
 682       combinedArea: shape.area,
 683       elementIndex: length - 1,
 684     }
 685
 686   callback = (marker) ->
 687     element = markerElements[marker.wrapper.elementIndex]
 688     switch marker.wrapper.type
 689       when 'scrollable'
 690         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 691       when 'dropmarker'
 692         getButtonMenu(element).openPopup(
 693           element.parentNode, # Anchor node.
 694           'after_end', # Position.
 695           0, 0, # Offset.
 696           false, # Isn’t a context menu.
 697           true, # Allow the 'position' attribute to override the above position.
 698         )
 699       when 'clickable', 'complementary'
 700         # VimFx’s own button won’t trigger unless the click is simulated in the
 701         # next tick. This might be true for other buttons as well.
 702         utils.nextTick(window, ->
 703           utils.focusElement(element)
 704           browserOffset = {x: window.screenX, y: window.screenY}
 705           switch
 706             when element.localName == 'tab'
 707               # Only 'mousedown' seems to be able to activate tabs.
 708               utils.simulateMouseEvents(element, ['mousedown'], browserOffset)
 709             when element.closest('tab')
 710               # If `.click()` is used on a tab close button, its tab will be
 711               # selected first, which might cause the selected tab to change.
 712               utils.simulateMouseEvents(element, 'click-xul', browserOffset)
 713             else
 714               # `.click()` seems to trigger more buttons (such as NoScript’s
 715               # button and Firefox’s “hamburger” menu button) than simulating
 716               # 'click-xul'.
 717               element.click()
 718               utils.openDropdown(element)
 719         )
 720     return false
 721
 722   wrappers = markableElements.find(
 723     window, filter.bind(null, {complementary: false})
 724   )
 725
 726   if wrappers.length > 0
 727     viewport = viewportUtils.getWindowViewport(window)
 728
 729     markerContainer = new MarkerContainer({
 730       window
 731       hintChars: vim.options['hints.chars']
 732       adjustZoom: false
 733       minWeightDiff: 0
 734       getComplementaryWrappers: (callback) ->
 735         newWrappers = markableElements.find(
 736           window, filter.bind(null, {complementary: true})
 737         )
 738         callback({wrappers: newWrappers, viewport})
 739     })
 740     MarkerContainer.remove(window) # Better safe than sorry.
 741     markerContainer.container.classList.add('ui')
 742     window.document.getElementById('browser-panel').appendChild(
 743       markerContainer.container
 744     )
 745
 746     [firstWrappers, secondWrappers] =
 747       utils.partition(wrappers, (wrapper) -> wrapper.isPrioritized)
 748
 749     numChars = markerContainer.alphabet.length
 750     numPrimary = markerContainer.primaryHintChars.length
 751     index = 0
 752
 753     for wrapper in firstWrappers
 754       if wrapper.isTab
 755         # Given the hint chars `abc de`, give the tabs weights so that the hints
 756         # consistently become `a b ca cb cc cd cea ceb cec ced ceea ceeb` and so
 757         # on. The rule is that the weight of a tab must be larger than the sum
 758         # of all tabs with a longer hint. We start out at `1` and then use
 759         # smaller and smaller fractions. This is to make sure that the tabs get
 760         # consistent hints as the number of tabs or the size of the window
 761         # changes.
 762         exponent = (index - numPrimary + 1) // (numChars - 1) + 1
 763         wrapper.combinedArea = 1 / numChars ** exponent
 764         index += 1
 765       else
 766         # Make sure that the tab close buttons and the tab bar scroll buttons
 767         # come after all the tabs. Treating them all as the same size is fine.
 768         wrapper.combinedArea = 0
 769
 770     markerContainer.injectHints(firstWrappers, viewport, 'first')
 771     markerContainer.injectHints(secondWrappers, viewport, 'second')
 772     vim._enterMode('hints', {markerContainer, callback, matchText: false})
 773
 774   else
 775     vim.notify(translate('notification.follow.none'))
 776
 777 helper_follow_pattern = (type, {vim}) ->
 778   options = {
 779     pattern_selector: vim.options.pattern_selector
 780     pattern_attrs: vim.options.pattern_attrs
 781     patterns: vim.options["#{type}_patterns"]
 782   }
 783   browserOffset = vim._getBrowserOffset()
 784   vim._run('follow_pattern', {type, browserOffset, options})
 785
 786 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 787
 788 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 789
 790 commands.focus_text_input = ({vim, count}) ->
 791   vim.markPageInteraction()
 792   vim._run('focus_text_input', {count})
 793
 794 helper_follow_selectable = ({select}, args) ->
 795   {vim} = args
 796
 797   callback = (marker) ->
 798     vim._run('element_text_select', {
 799       elementIndex: marker.wrapper.elementIndex
 800       full: select
 801       scroll: select
 802     })
 803     vim._enterMode('caret', {select})
 804     return false
 805
 806   helper_follow({name: 'follow_selectable', callback}, args)
 807
 808 commands.element_text_caret =
 809   helper_follow_selectable.bind(null, {select: false})
 810
 811 commands.element_text_select =
 812   helper_follow_selectable.bind(null, {select: true})
 813
 814 commands.element_text_copy = (args) ->
 815   {vim} = args
 816
 817   callback = (marker) ->
 818     helper_copy_marker_element(vim, marker.wrapper.elementIndex, '_selection')
 819     return false
 820
 821   helper_follow({name: 'follow_selectable', callback}, args)
 822
 823 helper_copy_marker_element = (vim, elementIndex, property) ->
 824   if property == '_selection'
 825     # Selecting the text and then copying that selection is better than copying
 826     # `.textContent`. Slack uses markdown-style backtick syntax for code spans
 827     # and then includes those backticks in the compiled output (!), in hidden
 828     # `<span>`s, so `.textContent` would copy those too. In `contenteditable`
 829     # elements, text selection gives better whitespace than `.textContent`.
 830     vim._run('element_text_select', {elementIndex, full: true}, ->
 831       vim.window.goDoCommand('cmd_copy') # See `caret.copy_selection_and_exit`.
 832       vim._run('clear_selection')
 833     )
 834   else
 835     vim._run('copy_marker_element', {elementIndex, property})
 836
 837
 838
 839 findStorage = {
 840   lastSearchString: ''
 841   busy: false
 842 }
 843
 844 helper_find_from_top_of_viewport = (vim, direction, callback) ->
 845   if vim.options.find_from_top_of_viewport
 846     vim._run('find_from_top_of_viewport', {direction}, ->
 847       callback()
 848     )
 849   else
 850     callback()
 851
 852 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 853   if findStorage.busy
 854     # Make sure to enter find mode here, since that’s where `findStorage.busy`
 855     # is reset to `false` again. Otherwise we can get stuck in the “busy” state.
 856     vim._enterMode('find')
 857     return
 858
 859   helpSearchInput = help.getSearchInput(vim.window)
 860   if helpSearchInput
 861     helpSearchInput.select()
 862     return
 863
 864   # Important: Enter Find mode immediately. See `onInput` for Find mode.
 865   findStorage.busy = true
 866   vim._enterMode('find')
 867
 868   helper_mark_last_scroll_position(vim)
 869   vim._run('mark_scroll_position', {
 870     keyStr: vim.options['scroll.last_find_mark']
 871     notify: false
 872   })
 873
 874   helper_find_from_top_of_viewport(vim, FORWARD, ->
 875     return unless vim.mode == 'find'
 876     findBar = vim.window.gBrowser.getFindBar()
 877
 878     mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 879     findBar.startFind(mode)
 880     utils.focusElement(findBar._findField, {select: true})
 881
 882     return if linksOnly
 883     return unless highlightButton = findBar.getElement('highlight')
 884     if highlightButton.checked != highlight
 885       highlightButton.click()
 886   )
 887
 888 commands.find = helper_find.bind(null, {highlight: false})
 889
 890 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 891
 892 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 893
 894 helper_find_again = (direction, {vim}) ->
 895   return if findStorage.busy
 896
 897   findBar = vim.window.gBrowser.getFindBar()
 898   if findStorage.lastSearchString.length == 0
 899     vim.notify(translate('notification.find_again.none'))
 900     return
 901
 902   findStorage.busy = true
 903
 904   helper_mark_last_scroll_position(vim)
 905   helper_find_from_top_of_viewport(vim, direction, ->
 906     findBar._findField.value = findStorage.lastSearchString
 907
 908     # `.onFindResult` is temporarily hacked to be able to know when the
 909     # asynchronous `.onFindAgainCommand` is done. When PDFs are shown using
 910     # PDF.js, `.updateControlState` is called instead of `.onFindResult`, so
 911     # hack that one too.
 912     originalOnFindResult = findBar.onFindResult
 913     originalUpdateControlState = findBar.updateControlState
 914
 915     findBar.onFindResult = (data) ->
 916       # Prevent the find bar from re-opening if there are no matches.
 917       data.storeResult = false
 918       findBar.onFindResult = originalOnFindResult
 919       findBar.updateControlState = originalUpdateControlState
 920       findBar.onFindResult(data)
 921       callback()
 922
 923     findBar.updateControlState = (args...) ->
 924       # Firefox inconsistently _doesn’t_ re-open the find bar if there are no
 925       # matches here, so no need to take care of that in this case.
 926       findBar.onFindResult = originalOnFindResult
 927       findBar.updateControlState = originalUpdateControlState
 928       findBar.updateControlState(args...)
 929       callback()
 930
 931     callback = ->
 932       message = findBar._findStatusDesc.textContent
 933       vim.notify(message) if message
 934       findStorage.busy = false
 935
 936     findBar.onFindAgainCommand(not direction)
 937   )
 938
 939 commands.find_next     = helper_find_again.bind(null, FORWARD)
 940
 941 commands.find_previous = helper_find_again.bind(null, BACKWARD)
 942
 943
 944
 945 commands.window_new = ({vim}) ->
 946   vim.window.OpenBrowserWindow()
 947
 948 commands.window_new_private = ({vim}) ->
 949   vim.window.OpenBrowserWindow({private: true})
 950
 951 commands.enter_mode_ignore = ({vim, blacklist = false}) ->
 952   type = if blacklist then 'blacklist' else 'explicit'
 953   vim._enterMode('ignore', {type})
 954
 955 # Quote next keypress (pass it through to the page).
 956 commands.quote = ({vim, count = 1}) ->
 957   vim._enterMode('ignore', {type: 'explicit', count})
 958
 959 commands.enter_reader_view = ({vim}) ->
 960   button = vim.window.document.getElementById('reader-mode-button')
 961   if not button?.hidden
 962     button.click()
 963   else
 964     vim.notify(translate('notification.enter_reader_view.none'))
 965
 966 commands.reload_config_file = ({vim}) ->
 967   vim._parent.emit('shutdown')
 968   config.load(vim._parent, {allowDeprecated: false}, (status) -> switch status
 969     when null
 970       vim.notify(translate('notification.reload_config_file.none'))
 971     when true
 972       vim.notify(translate('notification.reload_config_file.success'))
 973     else
 974       vim.notify(translate('notification.reload_config_file.failure'))
 975   )
 976
 977 commands.edit_blacklist = ({vim}) ->
 978   url = vim.browser.currentURI.spec
 979   location = new vim.window.URL(url)
 980   newPattern = if location.host then "*#{location.host}*" else location.href
 981   delimiter = '  '
 982   blacklistString = prefs.get('blacklist')
 983
 984   if vim._isBlacklisted(url)
 985     blacklist = parsePrefs.parseSpaceDelimitedString(blacklistString).parsed
 986     [matching, nonMatching] = utils.partition(blacklist, (string, index) ->
 987       return vim.options.blacklist[index].test(url)
 988     )
 989     newBlacklistString = "
 990       #{matching.join(delimiter)}\
 991       #{delimiter.repeat(7)}\
 992       #{nonMatching.join(delimiter)}
 993     "
 994     extraMessage = translate('pref.blacklist.extra.is_blacklisted')
 995   else
 996     newBlacklistString = "#{newPattern}#{delimiter}#{blacklistString}"
 997     extraMessage = translate('pref.blacklist.extra.added', newPattern)
 998
 999   message = """
1000     #{translate('pref.blacklist.title')}: #{translate('pref.blacklist.desc')}
1001
1002     #{extraMessage}
1003   """
1004
1005   vim._modal('prompt', [message, newBlacklistString.trim()], (input) ->
1006     return if input == null
1007     # Just set the blacklist as if the user had typed it in the Add-ons Manager,
1008     # and let the regular pref parsing take care of it.
1009     prefs.set('blacklist', input)
1010     vim._onLocationChange(url)
1011   )
1012
1013 commands.help = ({vim}) ->
1014   help.toggleHelp(vim.window, vim._parent)
1015
1016 commands.dev = ({vim}) ->
1017   vim.window.DeveloperToolbar.show(true) # `true` to focus.
1018
1019 commands.esc = ({vim}) ->
1020   vim._run('esc')
1021   vim.hideNotification()
1022   utils.blurActiveBrowserElement(vim)
1023   vim.window.gBrowser.getFindBar().close()
1024
1025   # Better safe than sorry.
1026   MarkerContainer.remove(vim.window)
1027   vim._parent.resetCaretBrowsing()
1028
1029   # Calling `.hide()` when the toolbar is not open can destroy it for the rest
1030   # of the Firefox session. The code here is taken from the `.toggle()` method.
1031   {DeveloperToolbar} = vim.window
1032   if DeveloperToolbar.visible
1033     DeveloperToolbar.hide().catch(console.error)
1034
1035   unless help.getSearchInput(vim.window)?.getAttribute('focused')
1036     help.removeHelp(vim.window)
1037
1038   vim._setFocusType('none') # Better safe than sorry.
1039
1040
1041
1042 module.exports = {
1043   commands
1044   findStorage
1045 }