extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 help      = require('./help')
  30 hints     = require('./hints')
  31 prefs     = require('./prefs')
  32 translate = require('./l10n')
  33 utils     = require('./utils')
  34
  35 commands = {}
  36
  37
  38
  39 commands.focus_location_bar = ({vim}) ->
  40   vim.window.focusAndSelectUrlBar()
  41
  42 commands.focus_search_bar = ({vim, count}) ->
  43   # The `.webSearch()` method opens a search engine in a tab if the search bar
  44   # has been removed. Therefore we first check if it exists.
  45   if vim.window.BrowserSearch.searchBar
  46     vim.window.BrowserSearch.webSearch()
  47
  48 helper_paste_and_go = (props, {vim}) ->
  49   {gURLBar} = vim.window
  50   gURLBar.value = vim.window.readFromClipboard()
  51   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  52
  53 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  54
  55 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  56
  57 commands.copy_current_url = ({vim}) ->
  58   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  59   vim.notify(translate('notification.copy_current_url'))
  60
  61 commands.go_up_path = ({vim, count}) ->
  62   vim._run('go_up_path', {count})
  63
  64 commands.go_to_root = ({vim}) ->
  65   vim._run('go_to_root')
  66
  67 commands.go_home = ({vim}) ->
  68   vim.window.BrowserHome()
  69
  70 helper_go_history = (direction, {vim, count = 1}) ->
  71   {SessionStore, gBrowser} = vim.window
  72
  73   # TODO: When Firefox 43 is released, only use the `.getSessionHistory`
  74   # version and bump the minimum Firefox version.
  75   if SessionStore.getSessionHistory
  76     SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  77       {index} = sessionHistory
  78       newIndex = index + count * (if direction == 'back' then -1 else 1)
  79       newIndex = Math.max(newIndex, 0)
  80       newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  81       if newIndex == index
  82         vim.notify(translate("notification.history_#{direction}.limit"))
  83       else
  84         gBrowser.gotoIndex(newIndex)
  85     )
  86   else
  87     # Until then, fall back to a no-count version.
  88     if direction == 'back' then gBrowser.goBack() else gBrowser.goForward()
  89
  90 commands.history_back    = helper_go_history.bind(null, 'back')
  91
  92 commands.history_forward = helper_go_history.bind(null, 'forward')
  93
  94 commands.history_list = ({vim}) ->
  95   menu = vim.window.document.getElementById('backForwardMenu')
  96   utils.openPopup(menu)
  97   vim.notify(translate('notification.history_list.none')) unless menu.open
  98
  99 commands.reload = ({vim}) ->
 100   vim.window.BrowserReload()
 101
 102 commands.reload_force = ({vim}) ->
 103   vim.window.BrowserReloadSkipCache()
 104
 105 commands.reload_all = ({vim}) ->
 106   vim.window.gBrowser.reloadAllTabs()
 107
 108 commands.reload_all_force = ({vim}) ->
 109   for tab in vim.window.gBrowser.visibleTabs
 110     gBrowser = tab.linkedBrowser
 111     consts = gBrowser.webNavigation
 112     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 113     gBrowser.reload(flags)
 114   return
 115
 116 commands.stop = ({vim}) ->
 117   vim.window.BrowserStop()
 118
 119 commands.stop_all = ({vim}) ->
 120   for tab in vim.window.gBrowser.visibleTabs
 121     tab.linkedBrowser.stop()
 122   return
 123
 124
 125
 126 helper_scroll = (vim, uiEvent, args...) ->
 127   [
 128     method, type, directions, amounts
 129     properties = null, adjustment = 0, name = 'scroll'
 130   ] = args
 131   options = {
 132     method, type, directions, amounts, properties, adjustment
 133     smooth: (prefs.root.get('general.smoothScroll') and
 134              prefs.root.get("general.smoothScroll.#{type}"))
 135   }
 136   reset = prefs.root.tmp(
 137     'layout.css.scroll-behavior.spring-constant',
 138     vim.options["smoothScroll.#{type}.spring-constant"]
 139   )
 140
 141   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 142   if uiEvent or helpScroll
 143     activeElement = helpScroll or utils.getActiveElement(vim.window)
 144     if vim._state.scrollableElements.has(activeElement) or helpScroll
 145       utils.scroll(activeElement, options)
 146       reset()
 147       return
 148
 149   vim._run(name, options, reset)
 150
 151
 152 helper_scrollByLinesX = (amount, {vim, uiEvent, count = 1}) ->
 153   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 154   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['left'],
 155                 [amount * distance * count * 5])
 156
 157 helper_scrollByLinesY = (amount, {vim, uiEvent, count = 1}) ->
 158   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 159   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['top'],
 160                 [amount * distance * count * 20])
 161
 162 helper_scrollByPagesY = (amount, type, {vim, uiEvent, count = 1}) ->
 163   adjustment = prefs.get("scroll.#{type}_page_adjustment")
 164   helper_scroll(vim, uiEvent, 'scrollBy', 'pages', ['top'],
 165                 [amount * count], ['clientHeight'], adjustment)
 166
 167 helper_scrollToX = (amount, {vim, uiEvent}) ->
 168   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['left'],
 169                 [amount], ['scrollLeftMax'])
 170   helper_mark_last_scroll_position(vim)
 171
 172 helper_scrollToY = (amount, {vim, uiEvent}) ->
 173   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['top'],
 174                 [amount], ['scrollTopMax'])
 175   helper_mark_last_scroll_position(vim)
 176
 177 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 178 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 179 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 180 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 181 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 182 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 183 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 184 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 185 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 186 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 187 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 188 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 189
 190 helper_mark_last_scroll_position = (vim) ->
 191   keyStr = vim.options['scroll.last_position_mark']
 192   vim._run('mark_scroll_position', {keyStr, notify: false})
 193
 194 commands.mark_scroll_position = ({vim}) ->
 195   vim.enterMode('marks', (keyStr) -> vim._run('mark_scroll_position', {keyStr}))
 196
 197 commands.scroll_to_mark = ({vim}) ->
 198   vim.enterMode('marks', (keyStr) ->
 199     unless keyStr == vim.options['scroll.last_position_mark']
 200       helper_mark_last_scroll_position(vim)
 201     helper_scroll(vim, 'scrollTo', 'other', ['top', 'left'], keyStr,
 202                   ['scrollTopMax', 'scrollLeftMax'], 0, 'scroll_to_mark')
 203   )
 204
 205
 206
 207 commands.tab_new = ({vim}) ->
 208   utils.nextTick(vim.window, ->
 209     vim.window.BrowserOpenTab()
 210   )
 211
 212 commands.tab_duplicate = ({vim}) ->
 213   {gBrowser} = vim.window
 214   utils.nextTick(vim.window, ->
 215     gBrowser.duplicateTab(gBrowser.selectedTab)
 216   )
 217
 218 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 219   tabs = gBrowser.visibleTabs
 220   {selectedTab} = gBrowser
 221
 222   currentIndex  = tabs.indexOf(selectedTab)
 223   absoluteIndex = currentIndex + relativeIndex
 224   numTabsTotal  = tabs.length
 225   numPinnedTabs = gBrowser._numPinnedTabs
 226
 227   [numTabs, min] = switch
 228     when not pinnedSeparate  then [numTabsTotal,  0]
 229     when selectedTab.pinned  then [numPinnedTabs, 0]
 230     else [numTabsTotal - numPinnedTabs, numPinnedTabs]
 231
 232   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 233   # current direction.
 234   if (relativeIndex < 0 and currentIndex == min) or
 235      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 236     if absoluteIndex < min
 237       absoluteIndex += numTabs
 238     else if absoluteIndex >= min + numTabs
 239       absoluteIndex -= numTabs
 240
 241   absoluteIndex = Math.max(min, absoluteIndex)
 242   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 243
 244   return absoluteIndex
 245
 246 helper_switch_tab = (direction, {vim, count = 1}) ->
 247   {gBrowser} = vim.window
 248   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 249   utils.nextTick(vim.window, ->
 250     gBrowser.selectTabAtIndex(index)
 251   )
 252
 253 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 254
 255 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 256
 257 commands.tab_select_most_recent = ({vim}) ->
 258   {gBrowser} = vim.window
 259   mostRecentTab = null
 260   for tab in gBrowser.tabs when not tab.closing and tab != gBrowser.selectedTab
 261     if not mostRecentTab or tab.lastAccessed > mostRecentTab.lastAccessed
 262       mostRecentTab = tab
 263   gBrowser.selectedTab = mostRecentTab if mostRecentTab
 264
 265 helper_move_tab = (direction, {vim, count = 1}) ->
 266   {gBrowser} = vim.window
 267   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 268   utils.nextTick(vim.window, ->
 269     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 270   )
 271
 272 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 273
 274 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 275
 276 commands.tab_move_to_window = ({vim}) ->
 277   {gBrowser} = vim.window
 278   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 279
 280 commands.tab_select_first = ({vim, count = 1}) ->
 281   utils.nextTick(vim.window, ->
 282     vim.window.gBrowser.selectTabAtIndex(count - 1)
 283   )
 284
 285 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 286   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 287   utils.nextTick(vim.window, ->
 288     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 289   )
 290
 291 commands.tab_select_last = ({vim, count = 1}) ->
 292   utils.nextTick(vim.window, ->
 293     vim.window.gBrowser.selectTabAtIndex(-count)
 294   )
 295
 296 commands.tab_toggle_pinned = ({vim}) ->
 297   currentTab = vim.window.gBrowser.selectedTab
 298   if currentTab.pinned
 299     vim.window.gBrowser.unpinTab(currentTab)
 300   else
 301     vim.window.gBrowser.pinTab(currentTab)
 302
 303 commands.tab_close = ({vim, count = 1}) ->
 304   {gBrowser} = vim.window
 305   return if gBrowser.selectedTab.pinned
 306   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 307   utils.nextTick(vim.window, ->
 308     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 309       gBrowser.removeTab(tab)
 310     return
 311   )
 312
 313 commands.tab_restore = ({vim, count = 1}) ->
 314   utils.nextTick(vim.window, ->
 315     for index in [0...count] by 1
 316       restoredTab = vim.window.undoCloseTab()
 317       if not restoredTab and index == 0
 318         vim.notify(translate('notification.tab_restore.none'))
 319         break
 320     return
 321   )
 322
 323 commands.tab_restore_list = ({vim}) ->
 324   {window} = vim
 325   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 326     window, 'menuitem'
 327   )
 328   if fragment.childElementCount == 0
 329     vim.notify(translate('notification.tab_restore.none'))
 330   else
 331     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 332
 333 commands.tab_close_to_end = ({vim}) ->
 334   {gBrowser} = vim.window
 335   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 336
 337 commands.tab_close_other = ({vim}) ->
 338   {gBrowser} = vim.window
 339   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 340
 341
 342
 343 helper_follow = (name, vim, callback, count = null) ->
 344   vim.markPageInteraction()
 345
 346   # Enter hints mode immediately, with an empty set of markers. The user might
 347   # press keys before the `vim._run` callback is invoked. Those key presses
 348   # should be handled in hints mode, not normal mode.
 349   initialMarkers = []
 350   storage = vim.enterMode('hints', initialMarkers, callback, count)
 351
 352   vim._run(name, null, ({wrappers, viewport}) ->
 353     # The user might have exited hints mode (and perhaps even entered it again)
 354     # before this callback is invoked. If so, `storage.markers` has been
 355     # cleared, or set to a new value. Only proceed if it is unchanged.
 356     return unless storage.markers == initialMarkers
 357
 358     if wrappers.length > 0
 359       markers = hints.injectHints(vim.window, wrappers, viewport, vim.options)
 360       storage.markers = markers
 361     else
 362       vim.notify(translate('notification.follow.none'))
 363       vim.enterMode('normal')
 364   )
 365
 366 helper_follow_clickable = ({inTab, inBackground}, {vim, count = 1}) ->
 367   callback = (marker, timesLeft, keyStr) ->
 368     {type, elementIndex} = marker.wrapper
 369     isLast = (timesLeft == 1)
 370     isLink = (type == 'link')
 371
 372     switch
 373       when keyStr.startsWith(vim.options.hints_toggle_in_tab)
 374         inTab = not inTab
 375       when keyStr.startsWith(vim.options.hints_toggle_in_background)
 376         inTab = true
 377         inBackground = not inBackground
 378       else
 379         unless isLast
 380           inTab = true
 381           inBackground = true
 382
 383     inTab = false unless isLink
 384
 385     if type == 'text' or (isLink and not (inTab and inBackground))
 386       isLast = true
 387
 388     vim._focusMarkerElement(elementIndex)
 389
 390     if inTab
 391       utils.nextTick(vim.window, ->
 392         utils.openTab(vim.window, marker.wrapper.href, {
 393           inBackground
 394           relatedToCurrent: true
 395         })
 396       )
 397     else
 398       vim._run('click_marker_element', {
 399         elementIndex, type
 400         preventTargetBlank: vim.options.prevent_target_blank
 401       })
 402
 403     return not isLast
 404
 405   name = if inTab then 'follow_in_tab' else 'follow'
 406   helper_follow(name, vim, callback, count)
 407
 408 commands.follow =
 409   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 410
 411 commands.follow_in_tab =
 412   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 413
 414 commands.follow_in_focused_tab =
 415   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 416
 417 commands.follow_in_window = ({vim}) ->
 418   callback = (marker) ->
 419     vim._focusMarkerElement(marker.wrapper.elementIndex)
 420     vim.window.openLinkIn(marker.wrapper.href, 'window', {})
 421   helper_follow('follow_in_tab', vim, callback)
 422
 423 commands.follow_multiple = (args) ->
 424   args.count = Infinity
 425   commands.follow(args)
 426
 427 commands.follow_copy = ({vim}) ->
 428   callback = (marker) ->
 429     {elementIndex} = marker.wrapper
 430     property = switch marker.wrapper.type
 431       when 'link'            then 'href'
 432       when 'text'            then 'value'
 433       when 'contenteditable' then 'textContent'
 434     vim._run('copy_marker_element', {elementIndex, property})
 435   helper_follow('follow_copy', vim, callback)
 436
 437 commands.follow_focus = ({vim}) ->
 438   callback = (marker) ->
 439     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 440   return helper_follow('follow_focus', vim, callback)
 441
 442 commands.click_browser_element = ({vim}) ->
 443   markerElements = []
 444
 445   filter = (element, getElementShape) ->
 446     document = element.ownerDocument
 447     type = switch
 448       when vim._state.scrollableElements.has(element)
 449         'scrollable'
 450       when element.tabIndex > -1 and
 451            not (element.nodeName.endsWith('box') and
 452                 element.nodeName != 'checkbox') and
 453            element.nodeName != 'tabs'
 454         'clickable'
 455     return unless type
 456     return unless shape = getElementShape(element)
 457     length = markerElements.push(element)
 458     return {type, semantic: true, shape, elementIndex: length - 1}
 459
 460   callback = (marker) ->
 461     element = markerElements[marker.wrapper.elementIndex]
 462     switch marker.wrapper.type
 463       when 'scrollable'
 464         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 465       when 'clickable'
 466         utils.focusElement(element)
 467         utils.simulateClick(element)
 468
 469   {wrappers, viewport} =
 470     hints.getMarkableElementsAndViewport(vim.window, filter)
 471
 472   if wrappers.length > 0
 473     markers = hints.injectHints(vim.window, wrappers, viewport, {
 474       hint_chars: vim.options.hint_chars
 475       ui: true
 476     })
 477     vim.enterMode('hints', markers, callback)
 478   else
 479     vim.notify(translate('notification.follow.none'))
 480
 481 helper_follow_pattern = (type, {vim}) ->
 482   options =
 483     pattern_selector: vim.options.pattern_selector
 484     pattern_attrs:    vim.options.pattern_attrs
 485     patterns:         vim.options["#{type}_patterns"]
 486   vim._run('follow_pattern', {type, options})
 487
 488 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 489
 490 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 491
 492 commands.focus_text_input = ({vim, count}) ->
 493   vim.markPageInteraction()
 494   vim._run('focus_text_input', {count})
 495
 496
 497
 498 findStorage = {lastSearchString: ''}
 499
 500 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 501   helpSearchInput = help.getSearchInput(vim.window)
 502   if helpSearchInput
 503     helpSearchInput.select()
 504     return
 505
 506   helper_mark_last_scroll_position(vim)
 507   findBar = vim.window.gBrowser.getFindBar()
 508
 509   mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 510   findBar.startFind(mode)
 511   utils.focusElement(findBar._findField, {select: true})
 512
 513   return if linksOnly
 514   return unless highlightButton = findBar.getElement('highlight')
 515   if highlightButton.checked != highlight
 516     highlightButton.click()
 517
 518 commands.find = helper_find.bind(null, {highlight: false})
 519
 520 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 521
 522 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 523
 524 helper_find_again = (direction, {vim}) ->
 525   findBar = vim.window.gBrowser.getFindBar()
 526   if findStorage.lastSearchString.length == 0
 527     vim.notify(translate('notification.find_again.none'))
 528     return
 529   helper_mark_last_scroll_position(vim)
 530   findBar._findField.value = findStorage.lastSearchString
 531   findBar.onFindAgainCommand(direction)
 532   message = findBar._findStatusDesc.textContent
 533   vim.notify(message) if message
 534
 535 commands.find_next     = helper_find_again.bind(null, false)
 536
 537 commands.find_previous = helper_find_again.bind(null, true)
 538
 539
 540
 541 commands.window_new = ({vim}) ->
 542   vim.window.OpenBrowserWindow()
 543
 544 commands.window_new_private = ({vim}) ->
 545   vim.window.OpenBrowserWindow({private: true})
 546
 547 commands.enter_mode_ignore = ({vim}) ->
 548   vim.enterMode('ignore')
 549
 550 # Quote next keypress (pass it through to the page).
 551 commands.quote = ({vim, count = 1}) ->
 552   vim.enterMode('ignore', count)
 553
 554 commands.enter_reader_view = ({vim}) ->
 555   button = vim.window.document.getElementById('reader-mode-button')
 556   if not button?.hidden
 557     button.click()
 558   else
 559     vim.notify(translate('notification.enter_reader_view.none'))
 560
 561 commands.help = ({vim}) ->
 562   help.injectHelp(vim.window, vim._parent)
 563
 564 commands.dev = ({vim}) ->
 565   vim.window.DeveloperToolbar.show(true) # `true` to focus.
 566
 567 commands.esc = ({vim}) ->
 568   vim._run('esc')
 569   utils.blurActiveBrowserElement(vim)
 570   vim.window.DeveloperToolbar.hide()
 571   vim.window.gBrowser.getFindBar().close()
 572   # TODO: Remove when Tab Groups have been removed.
 573   vim.window.TabView?.hide()
 574   hints.removeHints(vim.window) # Better safe than sorry.
 575
 576   unless help.getSearchInput(vim.window)?.getAttribute('focused')
 577     help.removeHelp(vim.window)
 578
 579
 580
 581 module.exports = {
 582   commands
 583   findStorage
 584 }