extension/lib/modes.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2013.
   3 # Copyright Simon Lydell 2013, 2014.
   4 # Copyright Wang Zhuochun 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 utils                   = require('./utils')
  23 { mode_hints }          = require('./mode-hints/mode-hints')
  24 { updateToolbarButton } = require('./button')
  25 { commands
  26 , searchForMatchingCommand
  27 , escapeCommand
  28 , Command
  29 , findStorage }         = require('./commands')
  30
  31 { interfaces: Ci } = Components
  32
  33 XULDocument = Ci.nsIDOMXULDocument
  34
  35 exports['normal'] =
  36   onEnter: (vim, storage) ->
  37     storage.keys ?= []
  38     storage.commands ?= {}
  39
  40   onLeave: (vim, storage) ->
  41     storage.keys.length = 0
  42
  43   onInput: (vim, storage, keyStr, event) ->
  44     isEditable = utils.isElementEditable(event.originalTarget)
  45     autoInsertMode = isEditable or vim.rootWindow.TabView.isVisible()
  46
  47     storage.keys.push(keyStr)
  48
  49     { match, exact, command, count } = searchForMatchingCommand(storage.keys)
  50
  51     if vim.blacklistedKeys and storage.keys.join('') in vim.blacklistedKeys
  52       match = false
  53
  54     if match
  55
  56       if autoInsertMode and command != escapeCommand
  57         storage.keys.pop()
  58         return false
  59
  60       if exact
  61         command.func(vim, event, count)
  62         storage.keys.length = 0
  63
  64       # Esc key is not suppressed, and passed to the browser in normal mode.
  65       #
  66       # - It allows for stopping the loading of the page.
  67       # - It allows for closing many custom dialogs (and perhaps other things
  68       #   -- Esc is a very commonly used key).
  69       # - It is not passed if Esc is used for `command_Esc` and we’re blurring
  70       #   an element. That allows for blurring an input in a custom dialog
  71       #   without closing the dialog too.
  72       # - There are two reasons we might suppress it in other modes. If some
  73       #   custom dialog of a website is open, we should be able to cancel hint
  74       #   markers on it without closing it. Secondly, otherwise cancelling hint
  75       #   markers on Google causes its search bar to be focused.
  76       # - It may only be suppressed in web pages, not in browser chrome. That
  77       #   allows for reseting the location bar when blurring it, and closing
  78       #   dialogs such as the “bookmark this page” dialog (<c-d>).
  79       document = event.originalTarget.ownerDocument
  80       inBrowserChrome = (document instanceof XULDocument)
  81       if keyStr == '<escape>' and (not autoInsertMode or inBrowserChrome)
  82         return false
  83
  84       return true
  85
  86     else
  87       storage.keys.length = 0 unless /\d/.test(keyStr)
  88
  89       return false
  90
  91   commands: commands
  92
  93 exports['insert'] =
  94   onEnter: (vim) ->
  95     updateToolbarButton(vim.rootWindow, {insertMode: true})
  96   onLeave: (vim) ->
  97     updateToolbarButton(vim.rootWindow, {insertMode: false})
  98     utils.blurActiveElement(vim.window)
  99   onInput: (vim, storage, keyStr) ->
 100     if @commands['exit'].match(keyStr)
 101       vim.enterMode('normal')
 102       return true
 103   commands:
 104     exit: ['<c-escape>']
 105
 106 exports['find'] =
 107   onEnter: ->
 108
 109   onLeave: (vim) ->
 110     findBar = vim.rootWindow.gBrowser.getFindBar()
 111     findStorage.lastSearchString = findBar._findField.value
 112
 113   onInput: (vim, storage, keyStr) ->
 114     findBar = vim.rootWindow.gBrowser.getFindBar()
 115     if @commands['exit'].match(keyStr)
 116       findBar.close()
 117       return true
 118     return false
 119
 120   commands:
 121     exit: ['<escape>', '<enter>']
 122
 123 exports['hints'] = mode_hints
 124
 125 for modeName of exports
 126   mode = exports[modeName]
 127   continue if Array.isArray(mode.commands)
 128   for commandName of mode.commands
 129     name = "mode_#{ modeName }_#{ commandName }"
 130     keys = mode.commands[commandName].map((key) -> [key])
 131     mode.commands[commandName] = new Command(null, name, null, keys)