extension/bootstrap.coffee

   1 "use strict"
   2
   3 { classes: Cc, interfaces: Ci, utils: Cu } = Components
   4
   5 Cu.import "resource://gre/modules/Services.jsm"
   6 Cu.import "resource://gre/modules/AddonManager.jsm"
   7
   8 # Populate the global namespace with console, require, and include
   9 do (global = this) ->
  10   baseURI = Services.io.newURI __SCRIPT_URI_SPEC__, null, null
  11   getResourceURI = (path) -> Services.io.newURI path, null, baseURI
  12
  13   loader = Cc["@mozilla.org/moz/jssubscript-loader;1"].getService(Ci.mozIJSSubScriptLoader)
  14
  15   include = (src, scope = {}) ->
  16     try
  17       uri = getResourceURI src
  18       loader.loadSubScript uri.spec, scope
  19     catch error
  20       dump "Failed to load #{ src }: #{ error }\n"
  21
  22     return scope
  23
  24
  25   modules = {}
  26   require = (src) ->
  27     if modules[src]
  28       return modules[src]
  29     else
  30       scope =
  31         require: require
  32         include: include
  33         exports: {}
  34
  35       include "packages/#{ src }.js", scope
  36
  37       return modules[src] = scope.exports
  38
  39   global.include = include
  40   global.require = require
  41   global.getResourceURI = getResourceURI
  42   global.regexpEscape = (s) -> s and s.replace(/[-\/\\^$*+?.()|[\]{}]/g, '\\$&')
  43
  44   # Include into global scope
  45   include("includes/#{ name }.js", global) for name in [
  46     'console',
  47     'unload',
  48   ]
  49
  50   # Init localization `underscore` method
  51   global._ = require('l10n').l10n "vimfx.properties"
  52
  53   # Requires for startup/install
  54   { loadCss }             = require 'utils'
  55   { addEventListeners }   = require 'events'
  56   { getPref }             = require 'prefs'
  57   { setButtonInstallPosition
  58   , addToolbarButton }    = require 'button'
  59   { watchWindows }        = require 'window-utils'
  60
  61   # Firefox will call this method on startup/enabling
  62   global.startup = (data, reason) ->
  63
  64     if reason == ADDON_INSTALL
  65       # Position the toolbar button right before the default Bookmarks button
  66       # If Bookmarks button is hidden - then VimFx button will be appended to the toolbar
  67       setButtonInstallPosition 'nav-bar', 'bookmarks-menu-button-container'
  68
  69     loadCss 'style'
  70
  71     watchWindows addEventListeners, 'navigator:browser'
  72     watchWindows addToolbarButton, 'navigator:browser'
  73
  74   # Firefox will call this method on shutdown/disabling
  75   global.shutdown = (data, reason) ->
  76     # Don't bother to clean up if the browser is shutting down
  77     if reason != APP_SHUTDOWN
  78       unload()
  79
  80   global.install = (data, reason) ->
  81
  82   global.uninstall = (data, reason) ->