extension/packages/help.coffee

   1 utils        = require 'utils'
   2 prefs        = require 'prefs'
   3 { _ }        = require 'l10n'
   4
   5 { classes: Cc, interfaces: Ci, utils: Cu } = Components
   6
   7 XULDocument  = Ci.nsIDOMXULDocument
   8
   9 CONTAINER_ID = 'VimFxHelpDialogContainer'
  10
  11 removeHelp = (document) ->
  12   document.getElementById(CONTAINER_ID)?.remove()
  13
  14 injectHelp = (document, commands) ->
  15   if document.documentElement
  16     removeHelp(document)
  17
  18     if document instanceof XULDocument
  19       container = document.createElement('box')
  20       # The `.VimFxReset` class is not needed in XUL documents. Instead it actullay causes layout
  21       # problems there!
  22     else
  23       container = document.createElement('div')
  24       container.className = 'VimFxReset'
  25     container.id = CONTAINER_ID
  26
  27     container.appendChild(utils.parseHTML(document, helpDialogHtml(commands)))
  28
  29     document.documentElement.appendChild(container)
  30
  31     installHandlers(document, commands)
  32
  33     if button = document.getElementById('VimFxClose')
  34       clickHandler = (event) ->
  35         event.stopPropagation()
  36         event.preventDefault()
  37         removeHelp(document)
  38       button.addEventListener('click', clickHandler, false)
  39
  40 installHandlers = (document, commands) ->
  41   promptService = Cc["@mozilla.org/embedcomp/prompt-service;1"].getService(Ci.nsIPromptService)
  42
  43   changeHandler = (event) ->
  44     name = event.target.getAttribute('data-name')
  45     cmd = commands.reduce(((m, v) -> if (v.name == name) then v else m), null)
  46     cmd.enabled(event.target.checked)
  47
  48   for cb in document.getElementsByClassName('VimFxKeyCheckbox')
  49     cb.addEventListener('change', changeHandler)
  50
  51   removeHandler = (event) ->
  52     event.preventDefault()
  53     event.stopPropagation()
  54     key = event.target.getAttribute('data-key')
  55     name = event.target.getAttribute('data-command')
  56     if cmd = commands.reduce(((m, v) -> if (v.name == name) then v else m), null)
  57       title = _('help_remove_shortcut_title')
  58       text = _('help_remove_shortcut_text')
  59       if promptService.confirm(document.defaultView, title, text)
  60         cmd.keys(cmd.keys().filter((a) -> a != key))
  61         event.target.parentNode.removeChild(event.target)
  62
  63   for a in document.getElementsByClassName('VimFxKeyLink')
  64     a.addEventListener('click', removeHandler)
  65
  66   addHandler = (event) ->
  67     event.preventDefault()
  68     event.stopPropagation()
  69     name = event.target.getAttribute('data-command')
  70     if cmd = commands.reduce(((m, v) -> if (v.name == name) then v else m), null)
  71       title = _('help_add_shortcut_title')
  72       text = _('help_add_shortcut_text')
  73       value = { value: null }
  74       check = { value: null }
  75       if promptService.prompt(document.defaultView, title, text, value, null, check)
  76         conflict_cmd = commands.filter((c) => c.keys().indexOf(value.value) != -1)
  77         if conflict_cmd.length > 0
  78           textError = _('help_add_shortcut_text_already_used_by', null, value.value, conflict_cmd[0].help())
  79           promptService.alert(document.defaultView, title, textError)
  80         else
  81           cmd.keys(cmd.keys().concat(value.value))
  82           for div in document.getElementsByClassName('VimFxKeySequence')
  83             if div.getAttribute('data-command') == cmd.name
  84               node = utils.parseHTML(document, hint(cmd, value.value))
  85               node.querySelector('a').addEventListener('click', removeHandler)
  86               div.appendChild(node)
  87
  88   for a in document.getElementsByClassName('VimFxAddShortcutLink')
  89     a.addEventListener('click', addHandler, false)
  90
  91 td = (text, klass='') ->
  92   """<td class="VimFxReset #{ klass }">#{ text }</td>"""
  93
  94 hint = (cmd, key) ->
  95   keyDisplay = key.replace(/,/g, '')
  96   """<a href="#" class="VimFxReset VimFxKeyLink" title="#{ _('help_remove_shortcut') }"
  97           data-command="#{ cmd.name }" data-key="#{ key }">#{ keyDisplay }</a>"""
  98
  99 tr = (cmd) ->
 100   checked = if cmd.enabled() then 'checked' else null
 101   hints = """
 102     <div class="VimFxKeySequence" data-command="#{ cmd.name }">
 103       #{ (hint(cmd, key) for key in cmd.keys()).join('\n') }
 104     </div>
 105   """
 106   dot = """<span class="VimFxReset VimFxDot">&#8729;</span>"""
 107   cb = """<input type="checkbox" class="VimFxReset VimFxKeyCheckbox" data-name="#{ cmd.name }" #{ checked }></input>"""
 108   a = """#{ cmd.help() }"""
 109   add = """
 110     <a href="#" data-command="#{ cmd.name }"
 111         class="VimFxReset VimFxAddShortcutLink" title="#{ _('help_add_shortcut') }">&#8862;</a>
 112   """
 113
 114   return """
 115     <tr class="VimFxReset">
 116         #{ td(hints) }
 117         #{ td(add) }
 118         #{ td(dot) }
 119         #{ td(cb) }
 120         #{ td(a) }
 121     </tr>
 122   """
 123
 124 table = (commands) ->
 125   """
 126   <table class="VimFxReset">
 127     #{ (tr(cmd) for cmd in commands).join('') }
 128   </table>
 129   """
 130
 131 section = (title, commands) ->
 132   """
 133   <div class="VimFxReset VimFxSectionTitle">#{ title }</div>
 134   #{ table(commands) }
 135   """
 136
 137 helpDialogHtml = (commands) ->
 138   return """
 139   <div id="VimFxHelpDialog" class="VimFxReset">
 140     <div class="VimFxReset VimFxHeader">
 141       <div class="VimFxReset VimFxTitle">
 142         <span class="VimFxReset VimFxTitleVim">Vim</span><span class="VimFxReset VimFxTitleFx">Fx</span>
 143         <span class="VimFxReset">#{ _('help_title') }</span>
 144       </div>
 145       <span class="VimFxReset VimFxVersion">#{ _('help_version') } #{ utils.getVersion() }</span>
 146       <a class="VimFxReset VimFxClose" id="VimFxClose" href="#">&#10006;</a>
 147       <div class="VimFxReset VimFxClearFix"></div>
 148     </div>
 149
 150     <div class="VimFxReset VimFxBody">
 151       <div class="VimFxReset VimFxColumn">
 152         #{ section(_('help_section_urls'),    commands.filter((a) -> a.group == 'urls')) }
 153         #{ section(_('help_section_nav'),     commands.filter((a) -> a.group == 'nav')) }
 154       </div>
 155       <div class="VimFxReset VimFxColumn">
 156         #{ section(_('help_section_tabs'),    commands.filter((a) -> a.group == 'tabs')) }
 157         #{ section(_('help_section_browse'),  commands.filter((a) -> a.group == 'browse')) }
 158         #{ section(_('help_section_misc'),    commands.filter((a) -> a.group == 'misc')) }
 159       </div>
 160       <div class="VimFxReset VimFxClearFix"></div>
 161     </div>
 162
 163     <div class="VimFxReset VimFxFooter">
 164       <p class="VimFxReset">#{ _('help_overlapping_hints') }</p>
 165       <p class="VimFxReset">
 166         #{ _('help_found_bug') }
 167         <a class="VimFxReset" target="_blank" href="https://github.com/akhodakivskiy/VimFx/issues">
 168           #{ _('help_report_bug') }
 169         </a>
 170       </p>
 171       <p class="VimFxReset">
 172         #{ _('help_enjoying') }
 173         <a class="VimFxReset" target="_blank" href="https://addons.mozilla.org/en-US/firefox/addon/vimfx/">
 174           #{ _('help_feedback') }
 175         </a>
 176       </p>
 177     </div>
 178   </div>
 179   """
 180
 181 exports.injectHelp = injectHelp
 182 exports.removeHelp = removeHelp