extension/lib/events.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file sets up all event listeners needed to power VimFx: To know when to
  22 # launch commands and to provide state to them. Events in web page content are
  23 # listened for in events-frame.coffee.
  24
  25 button = require('./button')
  26 utils  = require('./utils')
  27
  28 HELD_MODIFIERS_ATTRIBUTE = 'vimfx-held-modifiers'
  29
  30 class UIEventManager
  31   constructor: (@vimfx, @window) ->
  32     @listen = utils.listen.bind(null, @window)
  33     @listenOnce = utils.listenOnce.bind(null, @window)
  34
  35     # This flag controls whether to suppress the various key events or not.
  36     @suppress = false
  37
  38     # When a menu or panel is shown VimFx should temporarily stop processing
  39     # keyboard input, allowing accesskeys to be used.
  40     @popupPassthrough = false
  41
  42   addListeners: ->
  43     checkPassthrough = (value, event) =>
  44       if event.target.nodeName in ['menupopup', 'panel']
  45         @popupPassthrough = value
  46
  47     @listen('popupshown',  checkPassthrough.bind(null, true))
  48     @listen('popuphidden', checkPassthrough.bind(null, false))
  49
  50     @listen('keydown', (event) =>
  51       try
  52         # No matter what, always reset the `suppress` flag, so we don't suppress
  53         # more than intended.
  54         @suppress = false
  55
  56         if @popupPassthrough
  57           # The `@popupPassthrough` flag is set a bit unreliably. Sometimes it
  58           # can be stuck as `true` even though no popup is shown, effectively
  59           # disabling the extension. Therefore we check if there actually _are_
  60           # any open popups before stopping processing keyboard input. This is
  61           # only done when popups (might) be open (not on every keystroke) of
  62           # performance reasons.
  63           #
  64           # The autocomplete popup in text inputs (for example) is technically a
  65           # panel, but it does not respond to key presses. Therefore
  66           # `[ignorekeys="true"]` is excluded.
  67           #
  68           # coffeelint: disable=max_line_length
  69           # <https://developer.mozilla.org/en-US/docs/Mozilla/Tech/XUL/PopupGuide/PopupKeys#Ignoring_Keys>
  70           # coffeelint: enable=max_line_length
  71           popups = @window.document.querySelectorAll(
  72             ':-moz-any(menupopup, panel):not([ignorekeys="true"])'
  73           )
  74           for popup in popups
  75             return if popup.state == 'open'
  76           @popupPassthrough = false # No popup was actually open.
  77
  78         vim = @vimfx.getCurrentVim(@window)
  79
  80         if vim.isFrameEvent(event)
  81           vim._listenOnce('consumeKeyEvent', ({ focusType }) =>
  82             @consumeKeyEvent(vim, event, focusType, { isFrameEvent: true })
  83             return @suppress
  84           )
  85         else
  86           @consumeKeyEvent(vim, event, utils.getFocusType(event))
  87           # This also suppresses the 'keypress' event.
  88           utils.suppressEvent(event) if @suppress
  89
  90       catch error
  91         console.error(utils.formatError(error))
  92     )
  93
  94     @listen('keyup', (event) =>
  95       utils.suppressEvent(event) if @suppress
  96       @setHeldModifiers(event, {filterCurrentOnly: true})
  97     )
  98
  99     checkFindbar = (mode, event) =>
 100       target = event.originalTarget
 101       findBar = @window.gBrowser.getFindBar()
 102       if target == findBar._findField.mInputField
 103         vim = @vimfx.getCurrentVim(@window)
 104         vim.enterMode(mode)
 105
 106     @listen('focus', checkFindbar.bind(null, 'find'))
 107     @listen('blur',  checkFindbar.bind(null, 'normal'))
 108
 109     @listen('click', (event) =>
 110       target = event.originalTarget
 111       vim = @vimfx.getCurrentVim(@window)
 112
 113       # If the user clicks the reload button or a link when in hints mode, we’re
 114       # going to end up in hints mode without any markers. Or if the user clicks
 115       # a text input, then that input will be focused, but you can’t type in it
 116       # (instead markers will be matched). So if the user clicks anything in
 117       # hints mode it’s better to leave it.
 118       if vim.mode == 'hints' and not vim.isFrameEvent(event) and
 119          # Exclude the VimFx button, though, since clicking it returns to normal
 120          # mode. Otherwise we’d first return to normal mode and then the button
 121          # would open the help dialog.
 122          target != button.getButton(@window)
 123         vim.enterMode('normal')
 124     )
 125
 126     @listen('TabSelect', (event) =>
 127       @vimfx.emit('TabSelect', event)
 128
 129       # The initial 'TabSelect' when the browser starts fires before a vim
 130       # object has been created for that tab.
 131       return unless vim = @vimfx.getCurrentVim(@window)
 132       vim._send('TabSelect')
 133     )
 134
 135     lastUrl = null
 136     progressListener =
 137       onLocationChange: (progress, request, location, flags) =>
 138         url     = location.spec
 139         refresh = (url == lastUrl)
 140         lastUrl = url
 141         unless flags & Ci.nsIWebProgressListener.LOCATION_CHANGE_SAME_DOCUMENT
 142           # `onLocationChange` might fire before a vim object has been created
 143           # for the current tab.
 144           return unless vim = @vimfx.getCurrentVim(@window)
 145           vim._onLocationChange(url, {refresh})
 146
 147     @window.gBrowser.addProgressListener(progressListener)
 148     module.onShutdown(=>
 149       @window.gBrowser.removeProgressListener(progressListener)
 150     )
 151
 152   consumeKeyEvent: (vim, event, focusType, options = {}) ->
 153     match = vim._consumeKeyEvent(event, focusType)
 154     switch
 155       when not match
 156         @suppress = null
 157       when match.specialKeys['<late>']
 158         @suppress = false
 159         @consumeLateKeydown(vim, event, match, options)
 160       else
 161         @suppress = vim._onInput(match, options)
 162     @setHeldModifiers(event)
 163
 164   consumeLateKeydown: (vim, event, match, options) ->
 165     { isFrameEvent = false } = options
 166
 167     # The passed in `event` is the regular non-late browser UI keydown event.
 168     # It is only used to set held keys. This is easier than sending an event
 169     # subset from frame scripts.
 170     listener = ({ defaultPrevented }) =>
 171       @suppress =
 172         if defaultPrevented
 173           false
 174         else
 175           vim._onInput(match, options)
 176       @setHeldModifiers(event)
 177       return @suppress
 178
 179     if isFrameEvent
 180       vim._listenOnce('lateKeydown', listener)
 181     else
 182       @listenOnce('keydown', ((lateEvent) =>
 183         listener(lateEvent)
 184         if @suppress
 185           utils.suppressEvent(lateEvent)
 186           @listenOnce('keyup', utils.suppressEvent, false)
 187       ), false)
 188
 189   setHeldModifiers: (event, { filterCurrentOnly = false } = {}) ->
 190     mainWindow = @window.document.documentElement
 191     modifiers =
 192       if filterCurrentOnly
 193         mainWindow.getAttribute(HELD_MODIFIERS_ATTRIBUTE)
 194       else
 195         if @suppress == null then 'alt ctrl meta shift' else ''
 196     isHeld = (modifier) -> event["#{ modifier }Key"]
 197     mainWindow.setAttribute(HELD_MODIFIERS_ATTRIBUTE,
 198                             modifiers.split(' ').filter(isHeld).join(' '))
 199
 200 module.exports = UIEventManager