extension/packages/marker.coffee

   1 { interfaces: Ci }      = Components
   2 XPathResult             = Ci.nsIDOMXPathResult
   3
   4 { getPref } = require 'prefs'
   5
   6 # All elements that have one or more of the following properties
   7 # qualify for their own marker in hints mode
   8 MARKABLE_ELEMENT_PROPERTIES = [
   9   "@tabindex"
  10   "@onclick"
  11   "@onmousedown"
  12   "@onmouseup"
  13   "@oncommand"
  14   "@role='link'"
  15   "@role='button'"
  16   "contains(@class, 'button')"
  17   "@contenteditable='' or translate(@contenteditable, 'TRUE', 'true')='true'"
  18 ]
  19
  20 # All the following elements qualify for their own marker in hints mode
  21 MARKABLE_ELEMENTS = [
  22   "a"
  23   "iframe"
  24   "area[@href]"
  25   "textarea"
  26   "button"
  27   "select"
  28   "input[not(@type='hidden' or @disabled or @readonly)]"
  29 ]
  30
  31
  32 # Marker class wraps the markable element and provides
  33 # methods to manipulate the markers
  34 class Marker
  35   # Creates the marker DOM node
  36   constructor: (@element) ->
  37     document = @element.ownerDocument
  38     window = document.defaultView
  39     @markerElement = document.createElement 'div'
  40     @markerElement.className = 'VimFxReset VimFxHintMarker'
  41
  42   # Shows the marker
  43   show: -> @markerElement.className = 'VimFxReset VimFxHintMarker'
  44
  45   # Hides the marker
  46   hide: -> @markerElement.className = 'VimFxReset VimFxHiddenHintMarker'
  47
  48   # Positions the marker on the page. The positioning is absulute
  49   setPosition: (rect) ->
  50     @markerElement.style.left = rect.left + 'px'
  51     @markerElement.style.top  = rect.top  + 'px'
  52
  53   # Assigns hint string to the marker
  54   setHint: (@hintChars) ->
  55     # number of hint chars that have been matched so far
  56     @enteredHintChars = ''
  57
  58     document = @element.ownerDocument
  59
  60     while @markerElement.hasChildNodes()
  61       @markerElement.removeChild @markedElement.firstChild
  62
  63     fragment = document.createDocumentFragment()
  64     for char in @hintChars
  65       span = document.createElement 'span'
  66       span.className = 'VimFxReset'
  67       span.textContent = char.toUpperCase()
  68
  69       fragment.appendChild span
  70
  71     @markerElement.appendChild fragment
  72
  73   # Add another char to the `enteredHintString`,
  74   # see if it still matches `hintString`, apply classes to
  75   # the distinct hint characters and show/hide marker when
  76   # the entered string partially (not) matches the hint string
  77   matchHintChar: (char) ->
  78     # Handle backspace key by removing a previously entered hint char
  79     # and resetting its class
  80     if char == 'backspace'
  81       if @enteredHintChars.length > 0
  82         @enteredHintChars = @enteredHintChars.slice(0, -1)
  83         @markerElement.children[@enteredHintChars.length]?.className = 'VimFxReset'
  84     # Otherwise append hint char and change hint class
  85     else
  86       @markerElement.children[@enteredHintChars.length]?.className = 'VimFxReset VimFxCharMatch'
  87       @enteredHintChars += char
  88
  89     # If entered hint chars no longer partially match the hint chars
  90     # then hide the marker. Othersie show it back
  91     if @hintChars.search(@enteredHintChars) == 0 then @show() else @hide()
  92
  93   # Checks if the marker will be matched if the next character entered is `char`
  94   willMatch: (char) ->
  95     char == 'backspace' or @hintChars.search(@enteredHintChars + char) == 0
  96
  97   # Checks if enterd hint chars completely match the hint chars
  98   isMatched: ->
  99     return @hintChars == @enteredHintChars
 100
 101
 102 # Selects all markable elements on the page, creates markers
 103 # for each of them The markers are then positioned on the page
 104 #
 105 # The array of markers is returned
 106 Marker.createMarkers = (document) ->
 107   hintChars = getPref('hint_chars').toLowerCase()
 108
 109   elementsSet = getMarkableElements(document)
 110   markers = [];
 111   j = 0
 112   for i in [0...elementsSet.snapshotLength] by 1
 113     element = elementsSet.snapshotItem(i)
 114     if rect = getElementRect element
 115       hint = indexToHint(j++, hintChars)
 116       marker = new Marker(element)
 117       marker.setPosition rect
 118       marker.setHint hint
 119       markers.push(marker)
 120
 121   return markers
 122
 123 # Function generator that creates a function that
 124 # returns hint string for supplied numeric index.
 125 indexToHint = do ->
 126   # Helper function that returns a permutation number `i`
 127   # of some of the characters in the `chars` agrument
 128   f = (i, chars) ->
 129     return '' if i < 0
 130
 131     n = chars.length
 132     l = Math.floor(i / n); k = i % n;
 133
 134     return f(l - 1, chars) + chars[k]
 135
 136   return (i, chars) ->
 137     # split the characters into two groups:
 138     #
 139     # *  left chars are used for the head
 140     # *  right chars are used to build the tail
 141     left = chars[...chars.length / 3]
 142     right = chars[chars.length / 3...]
 143
 144     n = Math.floor(i / left.length)
 145     m = i % left.length
 146     return f(n - 1, right) + left[m]
 147
 148
 149 # Returns elements that qualify for hint markers in hints mode.
 150 # Generates and memoizes an XPath query internally
 151 getMarkableElements = do ->
 152   # Some preparations done on startup
 153   elements = Array.concat \
 154     MARKABLE_ELEMENTS,
 155     ["*[#{ MARKABLE_ELEMENT_PROPERTIES.join(" or ") }]"]
 156
 157   xpath = elements.reduce((m, rule) ->
 158     m.concat(["//#{ rule }", "//xhtml:#{ rule }"])
 159   , []).join(' | ')
 160
 161   namespaceResolver = (namespace) ->
 162     if (namespace == "xhtml") then "http://www.w3.org/1999/xhtml" else null
 163
 164   # The actual function that will return the desired elements
 165   return (document, resultType = XPathResult.ORDERED_NODE_SNAPSHOT_TYPE) ->
 166     document.evaluate xpath, document.documentElement, namespaceResolver, resultType, null
 167
 168 # Checks if the given TextRectangle object qualifies
 169 # for its own Marker with respect to the `window` object
 170 isRectOk = (rect, window) ->
 171   rect.width > 2 and rect.height > 2 and \
 172   rect.top > -2 and rect.left > -2 and \
 173   rect.top < window.innerHeight - 2 and \
 174   rect.left < window.innerWidth - 2
 175
 176 # Will scan through `element.getClientRects()` and look for
 177 # the first visible rectange. If there are no visible rectangles, then
 178 # will look at the children of the markable node.
 179 #
 180 # The logic has been copied over from Vimiun
 181 getElementRect = (element) ->
 182   document = element.ownerDocument
 183   window   = document.defaultView
 184   docElem  = document.documentElement
 185   body     = document.body
 186
 187   clientTop  = docElem.clientTop  || body.clientTop  || 0;
 188   clientLeft = docElem.clientLeft || body.clientLeft || 0;
 189   scrollTop  = window.pageYOffset || docElem.scrollTop;
 190   scrollLeft = window.pageXOffset || docElem.scrollLeft;
 191
 192   rects = [rect for rect in element.getClientRects()]
 193   rects.push element.getBoundingClientRect()
 194
 195   for rect in rects
 196     if isRectOk rect, window
 197       return {
 198         top:    rect.top  + scrollTop  - clientTop
 199         left:   rect.left + scrollLeft - clientLeft
 200         width:  rect.width
 201         height: rect.height
 202       }
 203
 204   # If the element has 0 dimentions then check what's inside.
 205   # Floated or absolutely positioned elements are of particular interest
 206   for rect in rects
 207     if rect.width == 0 or rect.height == 0
 208       for childElement in element.children
 209         computedStyle = window.getComputedStyle childElement, null
 210         if computedStyle.getPropertyValue 'float' != 'none' or \
 211            computedStyle.getPropertyValue 'position' == 'absolute'
 212
 213           childRect if childRect = getElementRect childElement
 214
 215   return undefined
 216
 217 exports.Marker              = Marker