extension/bootstrap.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015, 2016.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file boots the main VimFx process, as well as each frame script. It tries
  22 # to do the minimum amount of things to run main.coffee, or main-frame.coffee
  23 # for frame scripts. It defines a few global variables, and sets up a
  24 # Node.js-style `require` module loader.
  25
  26 # `bootstrap.js` files of different add-ons do _not_ share scope. However, frame
  27 # scripts for the same `<browser>` but from different add-ons _do_ share scope.
  28 # In order not to pollute that global scope in frame scripts, everything is done
  29 # in an IIFE here, and the `global` variable is handled with care.
  30
  31 do (global = this) ->
  32
  33   {classes: Cc, interfaces: Ci, utils: Cu} = Components
  34   ADDON_PATH = 'chrome://vimfx'
  35   IS_FRAME_SCRIPT = (typeof content != 'undefined')
  36   BUILD_TIME = do -> # @echo BUILD_TIME
  37   REQUIRE_DATA = do -> # @echo REQUIRE_DATA
  38
  39   unless IS_FRAME_SCRIPT
  40     # Make `Services` and `console` available globally, just like they are in
  41     # frame scripts by default.
  42     Cu.import('resource://gre/modules/Services.jsm')
  43     try
  44       # TODO: Only use this path when Firefox 44 is released.
  45       Cu.import('resource://gre/modules/Console.jsm')
  46     catch
  47       Cu.import('resource://gre/modules/devtools/Console.jsm')
  48
  49   shutdownHandlers = []
  50
  51   dirname = (uri) -> uri.split('/')[...-1].join('/') or '.'
  52
  53   require = (path, moduleRoot = '.', dir = '.') ->
  54     unless path[0] == '.'
  55       # Allow `require('module/lib/foo')` in additon to `require('module')`.
  56       [match, name, subPath] = path.match(///^ ([^/]+) (?: /(.+) )? ///)
  57       base = REQUIRE_DATA[moduleRoot]?[name] ? moduleRoot
  58       dir  = "#{base}/node_modules/#{name}"
  59       main = REQUIRE_DATA[dir]?['']
  60       path = subPath ? main ? 'index'
  61       moduleRoot = dir
  62
  63     prefix = "#{ADDON_PATH}/content"
  64     uri = "#{prefix}/#{dir}/#{path}.js"
  65     normalizedUri = Services.io.newURI(uri, null, null).spec
  66     currentDir = dirname(".#{normalizedUri[prefix.length..]}")
  67
  68     unless require.scopes[normalizedUri]?
  69       module = {
  70         exports: {}
  71         onShutdown: (fn) -> shutdownHandlers.push(fn)
  72       }
  73       require.scopes[normalizedUri] = scope = {
  74         require: (path) -> require.call(null, path, moduleRoot, currentDir)
  75         module, exports: module.exports
  76         Cc, Ci, Cu
  77         ADDON_PATH, BUILD_TIME
  78         IS_FRAME_SCRIPT
  79         FRAME_SCRIPT_ENVIRONMENT: if IS_FRAME_SCRIPT then global else null
  80       }
  81       Services.scriptloader.loadSubScript(normalizedUri, scope, 'UTF-8')
  82
  83     return require.scopes[normalizedUri].module.exports
  84
  85   require.scopes = {}
  86
  87   startup = (args...) ->
  88     main = if IS_FRAME_SCRIPT then './lib/main-frame' else './lib/main'
  89     require(main)(args...)
  90
  91   shutdown = ->
  92     for shutdownHandler in shutdownHandlers
  93       try
  94         shutdownHandler()
  95       catch error
  96         Cu.reportError(error)
  97     shutdownHandlers = []
  98
  99     # Release everything in `require`d modules. This must be done _after_ all
 100     # shutdownHandlers, since they use variables in these scopes.
 101     for path, scope of require.scopes
 102       for name of scope
 103         scope[name] = null
 104     require.scopes = {}
 105
 106   if IS_FRAME_SCRIPT
 107     messageManager = require('./lib/message-manager')
 108
 109     # Tell the main process that this frame script was created, and ask if
 110     # anything should be done in this frame.
 111     messageManager.send('tabCreated', null, (ok) ->
 112       # After dragging a tab from one window to another, `content` might have
 113       # been set to `null` by Firefox when this runs. If so, simply return.
 114       return unless ok and content?
 115
 116       startup()
 117
 118       messageManager.listenOnce('shutdown', shutdown)
 119     )
 120   else
 121     global.startup = startup
 122     global.shutdown = shutdown
 123     global.install = ->
 124     global.uninstall = ->