extension/packages/events.coffee

   1 utils                   = require 'utils'
   2 keyUtils                = require 'key-utils'
   3 { Vim }                 = require 'vim'
   4 { getPref }             = require 'prefs'
   5 { updateToolbarButton } = require 'button'
   6 { unload }              = require 'unload'
   7
   8 { interfaces: Ci } = Components
   9
  10 vimBucket = new utils.Bucket(utils.getWindowId, (w) -> new Vim(w))
  11
  12 keyStrFromEvent = (event) ->
  13   { ctrlKey: ctrl, metaKey: meta, altKey: alt, shiftKey: shift } = event
  14
  15   if !meta and !alt
  16     return unless keyChar = keyUtils.keyCharFromCode(event.keyCode, shift)
  17     keyStr = keyUtils.applyModifiers(keyChar, ctrl, alt, meta)
  18     return keyStr
  19
  20   return null
  21
  22 # Passthrough mode is activated when VimFx should temporarily stop processing keyboard input, for
  23 # example when a menu is shown.
  24 passthrough = false
  25 checkPassthrough = (event) ->
  26   if event.target.nodeName in ['menupopup', 'panel']
  27     passthrough = switch event.type
  28       when 'popupshown'  then true
  29       when 'popuphidden' then false
  30
  31 suppress = false
  32 keyListener = (event) ->
  33   try
  34     return if passthrough or getPref('disabled')
  35     return unless window = utils.getEventCurrentTabWindow(event)
  36     return unless vim = vimBucket.get(window)
  37     return if vim.blacklisted
  38
  39     if event.type == 'keydown'
  40       suppress = false
  41
  42       return unless keyStr = keyStrFromEvent(event)
  43
  44       isEditable = utils.isElementEditable(event.originalTarget)
  45
  46       suppress = vim.onInput(keyStr, event, {autoInsertMode: isEditable})
  47
  48     if suppress
  49       event.preventDefault()
  50       event.stopPropagation()
  51
  52   catch error
  53     console.log("#{ error } (in #{ event.type })\n#{ error.stack.replace(/@.+-> /g, '@') }")
  54
  55 removeVimFromTab = (tab, gBrowser) ->
  56   return unless browser = gBrowser.getBrowserForTab(tab)
  57   vimBucket.forget(browser.contentWindow)
  58
  59 updateButton = (vim) ->
  60   return unless rootWindow = utils.getRootWindow(vim.window)
  61   updateToolbarButton(rootWindow, {blacklisted: vim.blacklisted, insertMode: vim.mode == 'insert'})
  62
  63 # The following listeners are installed on every top level Chrome window
  64 windowsListeners =
  65   keydown:     keyListener
  66   keypress:    keyListener
  67   keyup:       keyListener
  68   popupshown:  checkPassthrough
  69   popuphidden: checkPassthrough
  70
  71   # When the top level window closes we should release all Vims that were
  72   # associated with tabs in this window
  73   DOMWindowClose: (event) ->
  74     return unless { gBrowser } = event.originalTarget
  75     for tab in gBrowser.tabs
  76       removeVimFromTab(tab, gBrowser)
  77
  78   TabClose: (event) ->
  79     return unless { gBrowser } = utils.getEventRootWindow(event) ? {}
  80     tab = event.originalTarget
  81     removeVimFromTab(tab, gBrowser)
  82
  83   # Update the toolbar button icon to reflect the blacklisted state
  84   TabSelect: (event) ->
  85     return unless window = event.originalTarget?.linkedBrowser?.contentDocument?.defaultView
  86     return unless vim = vimBucket.get(window)
  87     updateButton(vim)
  88
  89 # This listener works on individual tabs within Chrome Window
  90 tabsListener =
  91   # Listenfor location changes and disable the extension on blacklisted urls
  92   onLocationChange: (browser, webProgress, request, location) ->
  93     return unless vim = vimBucket.get(browser.contentWindow)
  94
  95     # If the location changes when in hints mode (for example because the reload button has been
  96     # clicked), we're going to end up in hints mode without any markers. So switch back to normal
  97     # mode in that case.
  98     if vim.mode == 'hints'
  99       vim.enterMode('normal')
 100
 101     vim.blacklisted = utils.isBlacklisted(location.spec)
 102     updateButton(vim)
 103
 104 addEventListeners = (window) ->
 105   for name, listener of windowsListeners
 106     window.addEventListener(name, listener, true)
 107
 108   window.gBrowser.addTabsProgressListener(tabsListener)
 109
 110   unload ->
 111     for name, listener of windowsListeners
 112       window.removeEventListener(name, listener, true)
 113
 114     window.gBrowser.removeTabsProgressListener(tabsListener)
 115
 116 exports.addEventListeners = addEventListeners