extension/lib/commands.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 # Copyright Wang Zhuochun 2013, 2014.
   5 #
   6 # This file is part of VimFx.
   7 #
   8 # VimFx is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # VimFx is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  20 ###
  21
  22 # This file defines all Normal mode commands. Commands that need to interact
  23 # with web page content do so by running `vim._run(name)`, which invokes `name`
  24 # in commands-frame.coffee.
  25
  26 # NOTE: Most tab related commands need to do their actual tab manipulations in
  27 # the next tick (`utils.nextTick`) to work around bug 1200334.
  28
  29 help      = require('./help')
  30 hints     = require('./hints')
  31 prefs     = require('./prefs')
  32 translate = require('./l10n')
  33 utils     = require('./utils')
  34
  35 commands = {}
  36
  37
  38
  39 commands.focus_location_bar = ({vim}) ->
  40   vim.window.focusAndSelectUrlBar()
  41
  42 commands.focus_search_bar = ({vim, count}) ->
  43   # The `.webSearch()` method opens a search engine in a tab if the search bar
  44   # has been removed. Therefore we first check if it exists.
  45   if vim.window.BrowserSearch.searchBar
  46     vim.window.BrowserSearch.webSearch()
  47
  48 helper_paste_and_go = (props, {vim}) ->
  49   {gURLBar} = vim.window
  50   gURLBar.value = vim.window.readFromClipboard()
  51   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  52
  53 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  54
  55 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  56
  57 commands.copy_current_url = ({vim}) ->
  58   utils.writeToClipboard(vim.window.gBrowser.currentURI.spec)
  59   vim.notify(translate('notification.copy_current_url'))
  60
  61 commands.go_up_path = ({vim, count}) ->
  62   vim._run('go_up_path', {count})
  63
  64 commands.go_to_root = ({vim}) ->
  65   vim._run('go_to_root')
  66
  67 commands.go_home = ({vim}) ->
  68   vim.window.BrowserHome()
  69
  70 helper_go_history = (direction, {vim, count = 1}) ->
  71   {SessionStore, gBrowser} = vim.window
  72
  73   # TODO: When Firefox 43 is released, only use the `.getSessionHistory`
  74   # version and bump the minimum Firefox version.
  75   if SessionStore.getSessionHistory
  76     SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  77       {index} = sessionHistory
  78       newIndex = index + count * (if direction == 'back' then -1 else 1)
  79       newIndex = Math.max(newIndex, 0)
  80       newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  81       if newIndex == index
  82         vim.notify(translate("notification.history_#{direction}.limit"))
  83       else
  84         gBrowser.gotoIndex(newIndex)
  85     )
  86   else
  87     # Until then, fall back to a no-count version.
  88     if direction == 'back' then gBrowser.goBack() else gBrowser.goForward()
  89
  90 commands.history_back    = helper_go_history.bind(null, 'back')
  91
  92 commands.history_forward = helper_go_history.bind(null, 'forward')
  93
  94 commands.history_list = ({vim}) ->
  95   menu = vim.window.document.getElementById('backForwardMenu')
  96   utils.openPopup(menu)
  97   vim.notify(translate('notification.history_list.none')) unless menu.open
  98
  99 commands.reload = ({vim}) ->
 100   vim.window.BrowserReload()
 101
 102 commands.reload_force = ({vim}) ->
 103   vim.window.BrowserReloadSkipCache()
 104
 105 commands.reload_all = ({vim}) ->
 106   vim.window.gBrowser.reloadAllTabs()
 107
 108 commands.reload_all_force = ({vim}) ->
 109   for tab in vim.window.gBrowser.visibleTabs
 110     gBrowser = tab.linkedBrowser
 111     consts = gBrowser.webNavigation
 112     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 113     gBrowser.reload(flags)
 114   return
 115
 116 commands.stop = ({vim}) ->
 117   vim.window.BrowserStop()
 118
 119 commands.stop_all = ({vim}) ->
 120   for tab in vim.window.gBrowser.visibleTabs
 121     tab.linkedBrowser.stop()
 122   return
 123
 124
 125
 126 helper_scroll = (vim, uiEvent, args...) ->
 127   [
 128     method, type, directions, amounts
 129     properties = null, adjustment = 0, name = 'scroll'
 130   ] = args
 131   options = {
 132     method, type, directions, amounts, properties, adjustment
 133     smooth: (prefs.root.get('general.smoothScroll') and
 134              prefs.root.get("general.smoothScroll.#{type}"))
 135   }
 136   reset = prefs.root.tmp(
 137     'layout.css.scroll-behavior.spring-constant',
 138     vim.options["smoothScroll.#{type}.spring-constant"]
 139   )
 140
 141   helpContainer = help.getHelp(vim.window)
 142   if uiEvent or helpContainer
 143     activeElement = helpContainer or utils.getActiveElement(vim.window)
 144     if vim._state.scrollableElements.has(activeElement) or helpContainer
 145       utils.scroll(activeElement, options)
 146       reset()
 147       return
 148
 149   vim._run(name, options, reset)
 150
 151
 152 helper_scrollByLinesX = (amount, {vim, uiEvent, count = 1}) ->
 153   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 154   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['left'],
 155                 [amount * distance * count * 5])
 156
 157 helper_scrollByLinesY = (amount, {vim, uiEvent, count = 1}) ->
 158   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 159   helper_scroll(vim, uiEvent, 'scrollBy', 'lines', ['top'],
 160                 [amount * distance * count * 20])
 161
 162 helper_scrollByPagesY = (amount, type, {vim, uiEvent, count = 1}) ->
 163   adjustment = prefs.get("scroll.#{type}_page_adjustment")
 164   helper_scroll(vim, uiEvent, 'scrollBy', 'pages', ['top'],
 165                 [amount * count], ['clientHeight'], adjustment)
 166
 167 helper_scrollToX = (amount, {vim, uiEvent}) ->
 168   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['left'],
 169                 [amount], ['scrollLeftMax'])
 170   helper_mark_last_scroll_position(vim)
 171
 172 helper_scrollToY = (amount, {vim, uiEvent}) ->
 173   helper_scroll(vim, uiEvent, 'scrollTo', 'other', ['top'],
 174                 [amount], ['scrollTopMax'])
 175   helper_mark_last_scroll_position(vim)
 176
 177 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 178 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 179 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 180 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 181 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 182 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 183 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 184 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 185 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 186 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 187 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 188 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 189
 190 helper_mark_last_scroll_position = (vim) ->
 191   keyStr = vim.options['scroll.last_position_mark']
 192   vim._run('mark_scroll_position', {keyStr, notify: false})
 193
 194 commands.mark_scroll_position = ({vim}) ->
 195   vim.enterMode('marks', (keyStr) -> vim._run('mark_scroll_position', {keyStr}))
 196
 197 commands.scroll_to_mark = ({vim}) ->
 198   vim.enterMode('marks', (keyStr) ->
 199     unless keyStr == vim.options['scroll.last_position_mark']
 200       helper_mark_last_scroll_position(vim)
 201     helper_scroll(vim, 'scrollTo', 'other', ['top', 'left'], keyStr,
 202                   ['scrollTopMax', 'scrollLeftMax'], 0, 'scroll_to_mark')
 203   )
 204
 205
 206
 207 commands.tab_new = ({vim}) ->
 208   utils.nextTick(vim.window, ->
 209     vim.window.BrowserOpenTab()
 210   )
 211
 212 commands.tab_duplicate = ({vim}) ->
 213   {gBrowser} = vim.window
 214   utils.nextTick(vim.window, ->
 215     gBrowser.duplicateTab(gBrowser.selectedTab)
 216   )
 217
 218 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 219   tabs = gBrowser.visibleTabs
 220   {selectedTab} = gBrowser
 221
 222   currentIndex  = tabs.indexOf(selectedTab)
 223   absoluteIndex = currentIndex + relativeIndex
 224   numTabsTotal  = tabs.length
 225   numPinnedTabs = gBrowser._numPinnedTabs
 226
 227   [numTabs, min] = switch
 228     when not pinnedSeparate  then [numTabsTotal,  0]
 229     when selectedTab.pinned  then [numPinnedTabs, 0]
 230     else [numTabsTotal - numPinnedTabs, numPinnedTabs]
 231
 232   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 233   # current direction.
 234   if (relativeIndex < 0 and currentIndex == min) or
 235      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 236     if absoluteIndex < min
 237       absoluteIndex += numTabs
 238     else if absoluteIndex >= min + numTabs
 239       absoluteIndex -= numTabs
 240
 241   absoluteIndex = Math.max(min, absoluteIndex)
 242   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 243
 244   return absoluteIndex
 245
 246 helper_switch_tab = (direction, {vim, count = 1}) ->
 247   {gBrowser} = vim.window
 248   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 249   utils.nextTick(vim.window, ->
 250     gBrowser.selectTabAtIndex(index)
 251   )
 252
 253 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 254
 255 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 256
 257 helper_move_tab = (direction, {vim, count = 1}) ->
 258   {gBrowser} = vim.window
 259   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 260   utils.nextTick(vim.window, ->
 261     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 262   )
 263
 264 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 265
 266 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 267
 268 commands.tab_move_to_window = ({vim}) ->
 269   {gBrowser} = vim.window
 270   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 271
 272 commands.tab_select_first = ({vim, count = 1}) ->
 273   utils.nextTick(vim.window, ->
 274     vim.window.gBrowser.selectTabAtIndex(count - 1)
 275   )
 276
 277 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 278   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 279   utils.nextTick(vim.window, ->
 280     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 281   )
 282
 283 commands.tab_select_last = ({vim, count = 1}) ->
 284   utils.nextTick(vim.window, ->
 285     vim.window.gBrowser.selectTabAtIndex(-count)
 286   )
 287
 288 commands.tab_toggle_pinned = ({vim}) ->
 289   currentTab = vim.window.gBrowser.selectedTab
 290   if currentTab.pinned
 291     vim.window.gBrowser.unpinTab(currentTab)
 292   else
 293     vim.window.gBrowser.pinTab(currentTab)
 294
 295 commands.tab_close = ({vim, count = 1}) ->
 296   {gBrowser} = vim.window
 297   return if gBrowser.selectedTab.pinned
 298   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 299   utils.nextTick(vim.window, ->
 300     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 301       gBrowser.removeTab(tab)
 302     return
 303   )
 304
 305 commands.tab_restore = ({vim, count = 1}) ->
 306   utils.nextTick(vim.window, ->
 307     for index in [0...count] by 1
 308       restoredTab = vim.window.undoCloseTab()
 309       if not restoredTab and index == 0
 310         vim.notify(translate('notification.tab_restore.none'))
 311         break
 312     return
 313   )
 314
 315 commands.tab_restore_list = ({vim}) ->
 316   {window} = vim
 317   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 318     window, 'menuitem'
 319   )
 320   if fragment.childElementCount == 0
 321     vim.notify(translate('notification.tab_restore.none'))
 322   else
 323     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 324
 325 commands.tab_close_to_end = ({vim}) ->
 326   {gBrowser} = vim.window
 327   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 328
 329 commands.tab_close_other = ({vim}) ->
 330   {gBrowser} = vim.window
 331   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 332
 333
 334
 335 helper_follow = (name, vim, callback, count = null) ->
 336   vim.markPageInteraction()
 337
 338   # Enter hints mode immediately, with an empty set of markers. The user might
 339   # press keys before the `vim._run` callback is invoked. Those key presses
 340   # should be handled in hints mode, not normal mode.
 341   initialMarkers = []
 342   storage = vim.enterMode('hints', initialMarkers, callback, count)
 343
 344   vim._run(name, null, ({wrappers, viewport}) ->
 345     # The user might have exited hints mode (and perhaps even entered it again)
 346     # before this callback is invoked. If so, `storage.markers` has been
 347     # cleared, or set to a new value. Only proceed if it is unchanged.
 348     return unless storage.markers == initialMarkers
 349
 350     if wrappers.length > 0
 351       markers = hints.injectHints(vim.window, wrappers, viewport, vim.options)
 352       storage.markers = markers
 353     else
 354       vim.notify(translate('notification.follow.none'))
 355       vim.enterMode('normal')
 356   )
 357
 358 helper_follow_clickable = ({inTab, inBackground}, {vim, count = 1}) ->
 359   callback = (marker, timesLeft, keyStr) ->
 360     {type, elementIndex} = marker.wrapper
 361     isLast = (timesLeft == 1)
 362     isLink = (type == 'link')
 363
 364     switch
 365       when keyStr.startsWith(vim.options.hints_toggle_in_tab)
 366         inTab = not inTab
 367       when keyStr.startsWith(vim.options.hints_toggle_in_background)
 368         inTab = true
 369         inBackground = not inBackground
 370       else
 371         unless isLast
 372           inTab = true
 373           inBackground = true
 374
 375     inTab = false unless isLink
 376
 377     if type == 'text' or (isLink and not (inTab and inBackground))
 378       isLast = true
 379
 380     vim._focusMarkerElement(elementIndex)
 381
 382     if inTab
 383       utils.nextTick(vim.window, ->
 384         utils.openTab(vim.window, marker.wrapper.href, {
 385           inBackground
 386           relatedToCurrent: true
 387         })
 388       )
 389     else
 390       vim._run('click_marker_element', {
 391         elementIndex, type
 392         preventTargetBlank: vim.options.prevent_target_blank
 393       })
 394
 395     return not isLast
 396
 397   name = if inTab then 'follow_in_tab' else 'follow'
 398   helper_follow(name, vim, callback, count)
 399
 400 commands.follow =
 401   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 402
 403 commands.follow_in_tab =
 404   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 405
 406 commands.follow_in_focused_tab =
 407   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 408
 409 commands.follow_in_window = ({vim}) ->
 410   callback = (marker) ->
 411     vim._focusMarkerElement(marker.wrapper.elementIndex)
 412     vim.window.openLinkIn(marker.wrapper.href, 'window', {})
 413   helper_follow('follow_in_tab', vim, callback)
 414
 415 commands.follow_multiple = (args) ->
 416   args.count = Infinity
 417   commands.follow(args)
 418
 419 commands.follow_copy = ({vim}) ->
 420   callback = (marker) ->
 421     {elementIndex} = marker.wrapper
 422     property = switch marker.wrapper.type
 423       when 'link'            then 'href'
 424       when 'text'            then 'value'
 425       when 'contenteditable' then 'textContent'
 426     vim._run('copy_marker_element', {elementIndex, property})
 427   helper_follow('follow_copy', vim, callback)
 428
 429 commands.follow_focus = ({vim}) ->
 430   callback = (marker) ->
 431     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 432   return helper_follow('follow_focus', vim, callback)
 433
 434 commands.click_browser_element = ({vim}) ->
 435   markerElements = []
 436
 437   filter = (element, getElementShape) ->
 438     document = element.ownerDocument
 439     type = switch
 440       when vim._state.scrollableElements.has(element)
 441         'scrollable'
 442       when element.tabIndex > -1 and
 443            not (element.nodeName.endsWith('box') and
 444                 element.nodeName != 'checkbox') and
 445            element.nodeName != 'tabs'
 446         'clickable'
 447     return unless type
 448     return unless shape = getElementShape(element)
 449     length = markerElements.push(element)
 450     return {type, semantic: true, shape, elementIndex: length - 1}
 451
 452   callback = (marker) ->
 453     element = markerElements[marker.wrapper.elementIndex]
 454     switch marker.wrapper.type
 455       when 'scrollable'
 456         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 457       when 'clickable'
 458         utils.focusElement(element)
 459         utils.simulateClick(element)
 460
 461   {wrappers, viewport} =
 462     hints.getMarkableElementsAndViewport(vim.window, filter)
 463
 464   if wrappers.length > 0
 465     markers = hints.injectHints(vim.window, wrappers, viewport, {
 466       hint_chars: vim.options.hint_chars
 467       ui: true
 468     })
 469     vim.enterMode('hints', markers, callback)
 470   else
 471     vim.notify(translate('notification.follow.none'))
 472
 473 helper_follow_pattern = (type, {vim}) ->
 474   options =
 475     pattern_selector: vim.options.pattern_selector
 476     pattern_attrs:    vim.options.pattern_attrs
 477     patterns:         vim.options["#{type}_patterns"]
 478   vim._run('follow_pattern', {type, options})
 479
 480 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 481
 482 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 483
 484 commands.focus_text_input = ({vim, count}) ->
 485   vim.markPageInteraction()
 486   vim._run('focus_text_input', {count})
 487
 488
 489
 490 findStorage = {lastSearchString: ''}
 491
 492 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 493   helpSearchInput = help.getSearchInput(vim.window)
 494   if helpSearchInput
 495     helpSearchInput.select()
 496     return
 497
 498   helper_mark_last_scroll_position(vim)
 499   findBar = vim.window.gBrowser.getFindBar()
 500
 501   mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 502   findBar.startFind(mode)
 503   utils.focusElement(findBar._findField, {select: true})
 504
 505   return if linksOnly
 506   return unless highlightButton = findBar.getElement('highlight')
 507   if highlightButton.checked != highlight
 508     highlightButton.click()
 509
 510 commands.find = helper_find.bind(null, {highlight: false})
 511
 512 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 513
 514 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 515
 516 helper_find_again = (direction, {vim}) ->
 517   findBar = vim.window.gBrowser.getFindBar()
 518   if findStorage.lastSearchString.length == 0
 519     vim.notify(translate('notification.find_again.none'))
 520     return
 521   helper_mark_last_scroll_position(vim)
 522   findBar._findField.value = findStorage.lastSearchString
 523   findBar.onFindAgainCommand(direction)
 524   message = findBar._findStatusDesc.textContent
 525   vim.notify(message) if message
 526
 527 commands.find_next     = helper_find_again.bind(null, false)
 528
 529 commands.find_previous = helper_find_again.bind(null, true)
 530
 531
 532
 533 commands.window_new = ({vim}) ->
 534   vim.window.OpenBrowserWindow()
 535
 536 commands.window_new_private = ({vim}) ->
 537   vim.window.OpenBrowserWindow({private: true})
 538
 539 commands.enter_mode_ignore = ({vim}) ->
 540   vim.enterMode('ignore')
 541
 542 # Quote next keypress (pass it through to the page).
 543 commands.quote = ({vim, count = 1}) ->
 544   vim.enterMode('ignore', count)
 545
 546 commands.enter_reader_view = ({vim}) ->
 547   button = vim.window.document.getElementById('reader-mode-button')
 548   if not button?.hidden
 549     button.click()
 550   else
 551     vim.notify(translate('notification.enter_reader_view.none'))
 552
 553 commands.help = ({vim}) ->
 554   help.injectHelp(vim.window, vim._parent)
 555
 556 commands.dev = ({vim}) ->
 557   vim.window.DeveloperToolbar.show(true) # `true` to focus.
 558
 559 commands.esc = ({vim}) ->
 560   vim._run('esc')
 561   utils.blurActiveBrowserElement(vim)
 562   vim.window.DeveloperToolbar.hide()
 563   vim.window.gBrowser.getFindBar().close()
 564   # TODO: Remove when Tab Groups have been removed.
 565   vim.window.TabView?.hide()
 566   hints.removeHints(vim.window) # Better safe than sorry.
 567
 568   unless help.getSearchInput(vim.window)?.getAttribute('focused')
 569     help.removeHelp(vim.window)
 570
 571
 572
 573 module.exports = {
 574   commands
 575   findStorage
 576 }