extension/lib/help.coffee

   1 ###
   2 # Copyright Simon Lydell 2015.
   3 #
   4 # This file is part of VimFx.
   5 #
   6 # VimFx is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # VimFx is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  18 ###
  19
  20 # This file creates VimFx’s Keyboard Shortcuts help screen.
  21
  22 translate = require('./l10n')
  23 utils     = require('./utils')
  24
  25 CONTAINER_ID  = 'VimFxHelpDialogContainer'
  26 MAX_FONT_SIZE = 20
  27 SEARCH_MATCH_CLASS     = 'search-match'
  28 SEARCH_NON_MATCH_CLASS = 'search-non-match'
  29 SEARCH_HIGHLIGHT_CLASS = 'search-highlight'
  30
  31 injectHelp = (window, vimfx) ->
  32   removeHelp(window)
  33
  34   {document} = window
  35
  36   container = utils.createBox(document)
  37   container.id = CONTAINER_ID
  38
  39   wrapper = utils.createBox(document, 'wrapper', container)
  40
  41   header = createHeader(document, vimfx)
  42   wrapper.appendChild(header)
  43
  44   content = createContent(document, vimfx)
  45   wrapper.appendChild(content)
  46
  47   searchInput = document.createElement('textbox')
  48   utils.setAttributes(searchInput, {
  49     class: 'search-input'
  50     placeholder: translate('help.search')
  51   })
  52   searchInput.oninput = -> search(content, searchInput.value.trimLeft())
  53   searchInput.onkeydown = (event) -> searchInput.blur() if event.key == 'Enter'
  54   container.appendChild(searchInput)
  55
  56   window.gBrowser.mCurrentBrowser.parentNode.appendChild(container)
  57
  58   # The font size of menu items is used by default, which is usually quite
  59   # small. Try to increase it without causing a scrollbar.
  60   computedStyle = window.getComputedStyle(container)
  61   fontSize = originalFontSize =
  62     parseFloat(computedStyle.getPropertyValue('font-size'))
  63   while wrapper.scrollTopMax == 0 and fontSize <= MAX_FONT_SIZE
  64     fontSize++
  65     container.style.fontSize = "#{fontSize}px"
  66   container.style.fontSize = "#{Math.max(fontSize - 1, originalFontSize)}px"
  67
  68   # Uncomment this line if you want to use `gulp help.html`!
  69   # utils.writeToClipboard(container.outerHTML)
  70
  71 removeHelp = (window) -> getHelp(window)?.remove()
  72
  73 getHelp = (window) -> window.document.getElementById(CONTAINER_ID)
  74
  75 getSearchInput = (window) -> getHelp(window)?.querySelector('.search-input')
  76
  77 createHeader = (document, vimfx) ->
  78   $ = utils.createBox.bind(null, document)
  79
  80   header = $('header')
  81
  82   mainHeading = $('heading-main', header)
  83   $('logo',  mainHeading) # Content is added by CSS.
  84   $('title', mainHeading, translate('help.title'))
  85
  86   closeButton = $('close-button', header, '×')
  87   closeButton.onclick = removeHelp.bind(null, document.ownerGlobal)
  88
  89   return header
  90
  91 createContent = (document, vimfx) ->
  92   $ = utils.createBox.bind(null, document)
  93
  94   content = $('content')
  95
  96   for mode in vimfx.getGroupedCommands({enabledOnly: true})
  97     modeHeading = $('heading-mode search-item', null, mode.name)
  98
  99     for category, index in mode.categories
 100       categoryContainer = $('category', content)
 101       # `data-` attributes are currently unused by VimFx, but provide a great
 102       # way to customize the help dialog with custom CSS.
 103       utils.setAttributes(categoryContainer, {
 104         'data-mode':     mode._name
 105         'data-category': category._name
 106       })
 107
 108       # Append the mode heading inside the first category container, rather than
 109       # before it, for layout purposes.
 110       if index == 0
 111         categoryContainer.appendChild(modeHeading)
 112         categoryContainer.classList.add('first')
 113
 114       if category.name
 115         $('heading-category search-item', categoryContainer, category.name)
 116
 117       for {command, name, enabledSequences} in category.commands
 118         commandContainer = $('command search-item', categoryContainer)
 119         utils.setAttributes(commandContainer, {'data-command': command.name})
 120         commandContainer.setAttribute('data-command', name)
 121         for sequence in enabledSequences
 122           keySequence = $('key-sequence', commandContainer)
 123           [specialKeys, rest] = splitSequence(sequence, vimfx.SPECIAL_KEYS)
 124           $('key-sequence-special-keys', keySequence, specialKeys)
 125           $('key-sequence-rest search-text', keySequence, rest)
 126         $('description search-text', commandContainer, command.description())
 127
 128   return content
 129
 130 splitSequence = (sequence, specialKeys) ->
 131   specialKeyEnds = specialKeys.map((key) ->
 132     pos = sequence.lastIndexOf(key)
 133     return if pos == -1 then 0 else pos + key.length
 134   )
 135   splitPos = Math.max(specialKeyEnds...)
 136   return [sequence[0...splitPos], sequence[splitPos..]]
 137
 138 search = (content, term) ->
 139   document   = content.ownerDocument
 140   ignoreCase = (term == term.toLowerCase())
 141   regex = RegExp("(#{utils.regexEscape(term)})", if ignoreCase then 'i' else '')
 142   clear = (term == '')
 143
 144   for item in content.querySelectorAll('.search-item')
 145     texts = item.querySelectorAll('.search-text')
 146     texts = [item] if texts.length == 0
 147     className = SEARCH_NON_MATCH_CLASS
 148
 149     for element in texts
 150       {textContent} = element
 151       # Clear the previous highlighting. This is possible to do for non-matches
 152       # as well, but too slow.
 153       if item.classList.contains(SEARCH_MATCH_CLASS)
 154         element.textContent = textContent
 155
 156       continue if clear or not regex.test(textContent)
 157
 158       className = SEARCH_MATCH_CLASS
 159       element.textContent = '' # Empty the element.
 160       for part, index in textContent.split(regex)
 161         # Even indices are surrounding text, odd ones are matches.
 162         if index % 2 == 0
 163           element.appendChild(document.createTextNode(part))
 164         else
 165           utils.createBox(document, SEARCH_HIGHLIGHT_CLASS, element, part)
 166
 167     item.classList.remove(SEARCH_MATCH_CLASS, SEARCH_NON_MATCH_CLASS)
 168     item.classList.add(className) unless clear
 169
 170   return
 171
 172 module.exports = {
 173   injectHelp
 174   removeHelp
 175   getHelp
 176   getSearchInput
 177 }