extension/lib/commands.coffee

   1 # This file defines all Normal mode commands. Commands that need to interact
   2 # with web page content do so by running `vim._run(name)`, which invokes `name`
   3 # in commands-frame.coffee.
   4
   5 # NOTE: Most tab related commands need to do their actual tab manipulations in
   6 # the next tick (`utils.nextTick`) to work around bug 1200334.
   7
   8 config = require('./config')
   9 help = require('./help')
  10 markableElements = require('./markable-elements')
  11 MarkerContainer = require('./marker-container')
  12 parsePrefs = require('./parse-prefs')
  13 prefs = require('./prefs')
  14 SelectionManager = require('./selection')
  15 translate = require('./translate')
  16 utils = require('./utils')
  17 viewportUtils = require('./viewport')
  18
  19 ffRequire = Cu.import('resource://devtools/shared/Loader.jsm').require
  20
  21 {gDevToolsBrowser} = ffRequire('devtools/client/framework/devtools-browser')
  22 {ContentClick} = Cu.import('resource:///modules/ContentClick.jsm', {})
  23 {FORWARD, BACKWARD} = SelectionManager
  24
  25 READER_VIEW_PREFIX = 'about:reader?url='
  26 SPRING_CONSTANT_PREF = 'layout.css.scroll-behavior.spring-constant'
  27
  28 commands = {}
  29
  30
  31
  32 commands.focus_location_bar = ({vim}) ->
  33   vim.window.focusAndSelectUrlBar()
  34
  35 commands.focus_search_bar = ({vim, count}) ->
  36   # The `.webSearch()` method opens a search engine in a tab if the search bar
  37   # has been removed. Therefore we first check if it exists.
  38   if vim.window.BrowserSearch.searchBar
  39     vim.window.BrowserSearch.webSearch()
  40   else
  41     vim.notify(translate('notification.focus_search_bar.none'))
  42
  43 helper_paste_and_go = (props, {vim}) ->
  44   {gURLBar} = vim.window
  45   gURLBar.value = vim.window.readFromClipboard()
  46   gURLBar.handleCommand(new vim.window.KeyboardEvent('keydown', props))
  47
  48 commands.paste_and_go = helper_paste_and_go.bind(null, null)
  49
  50 commands.paste_and_go_in_tab = helper_paste_and_go.bind(null, {altKey: true})
  51
  52 commands.copy_current_url = ({vim}) ->
  53   url = vim.window.gBrowser.currentURI.spec
  54   adjustedUrl =
  55     if url.startsWith(READER_VIEW_PREFIX)
  56       decodeURIComponent(url[READER_VIEW_PREFIX.length..])
  57     else
  58       url
  59   utils.writeToClipboard(adjustedUrl)
  60   vim.notify(translate('notification.copy_current_url.success'))
  61
  62 commands.go_up_path = ({vim, count}) ->
  63   vim._run('go_up_path', {count})
  64
  65 commands.go_to_root = ({vim}) ->
  66   vim._run('go_to_root')
  67
  68 commands.go_home = ({vim}) ->
  69   vim.window.BrowserHome()
  70
  71 helper_go_history = (direction, {vim, count = 1}) ->
  72   {window} = vim
  73   {SessionStore, gBrowser} = window
  74
  75   if (direction == 'back'    and not gBrowser.canGoBack) or
  76      (direction == 'forward' and not gBrowser.canGoForward)
  77     vim.notify(translate("notification.history_#{direction}.limit"))
  78     return
  79
  80   # `SessionStore.getSessionHistory()` (used below to support counts) starts
  81   # lots of asynchronous tasks internally, which is a bit unreliable, it has
  82   # turned out. The primary use of the `history_back` and `history_forward`
  83   # commands is to go _one_ step back or forward, though, so those cases are
  84   # optimized to use more reliable ways of going back and forward. Also, some
  85   # extensions override the following functions, so calling them also gives
  86   # better interoperability.
  87   if count == 1
  88     if direction == 'back'
  89       window.BrowserBack()
  90     else
  91       window.BrowserForward()
  92     return
  93
  94   SessionStore.getSessionHistory(gBrowser.selectedTab, (sessionHistory) ->
  95     {index} = sessionHistory
  96     newIndex = index + count * (if direction == 'back' then -1 else 1)
  97     newIndex = Math.max(newIndex, 0)
  98     newIndex = Math.min(newIndex, sessionHistory.entries.length - 1)
  99     gBrowser.gotoIndex(newIndex)
 100   )
 101
 102 commands.history_back    = helper_go_history.bind(null, 'back')
 103
 104 commands.history_forward = helper_go_history.bind(null, 'forward')
 105
 106 commands.history_list = ({vim}) ->
 107   menu = vim.window.document.getElementById('backForwardMenu')
 108   utils.openPopup(menu)
 109   if menu.childElementCount == 0
 110     vim.notify(translate('notification.history_list.none'))
 111
 112 commands.reload = ({vim}) ->
 113   vim.window.BrowserReload()
 114
 115 commands.reload_force = ({vim}) ->
 116   vim.window.BrowserReloadSkipCache()
 117
 118 commands.reload_all = ({vim}) ->
 119   vim.window.gBrowser.reloadAllTabs()
 120
 121 commands.reload_all_force = ({vim}) ->
 122   for tab in vim.window.gBrowser.visibleTabs
 123     gBrowser = tab.linkedBrowser
 124     consts = gBrowser.webNavigation
 125     flags = consts.LOAD_FLAGS_BYPASS_PROXY | consts.LOAD_FLAGS_BYPASS_CACHE
 126     gBrowser.reload(flags)
 127   return
 128
 129 commands.stop = ({vim}) ->
 130   vim.window.BrowserStop()
 131
 132 commands.stop_all = ({vim}) ->
 133   for tab in vim.window.gBrowser.visibleTabs
 134     tab.linkedBrowser.stop()
 135   return
 136
 137
 138
 139 scrollData = {
 140   nonce: null
 141   springConstant: null
 142   lastRepeat: 0
 143 }
 144
 145 helper_scroll = (vim, event, args...) ->
 146   [
 147     method, type, directions, amounts
 148     properties = null, adjustment = 0, name = 'scroll', extra = {}
 149   ] = args
 150
 151   elapsed = event.timeStamp - scrollData.lastRepeat
 152
 153   if event.repeat and elapsed < vim.options['scroll.repeat_timeout']
 154     return
 155
 156   scrollData.lastRepeat = event.timeStamp
 157
 158   options = {
 159     method, type, directions, amounts, properties, adjustment, extra
 160     smooth: (
 161       prefs.root.get('general.smoothScroll') and
 162       prefs.root.get("general.smoothScroll.#{type}")
 163     )
 164   }
 165
 166   # Temporarily set Firefox’s “spring constant” pref to get the desired smooth
 167   # scrolling speed. Reset it `reset_timeout` milliseconds after the last
 168   # scrolling command was invoked.
 169   scrollData.nonce = nonce = {}
 170   scrollData.springConstant ?= prefs.root.get(SPRING_CONSTANT_PREF)
 171   prefs.root.set(
 172     SPRING_CONSTANT_PREF,
 173     vim.options["smoothScroll.#{type}.spring-constant"]
 174   )
 175   reset = ->
 176     vim.window.setTimeout((->
 177       return unless scrollData.nonce == nonce
 178       prefs.root.set(SPRING_CONSTANT_PREF, scrollData.springConstant)
 179       scrollData.nonce = null
 180       scrollData.springConstant = null
 181     ), vim.options['scroll.reset_timeout'])
 182
 183   {isUIEvent = vim.isUIEvent(event)} = extra
 184   helpScroll = help.getHelp(vim.window)?.querySelector('.wrapper')
 185   if isUIEvent or helpScroll
 186     activeElement = helpScroll or utils.getActiveElement(vim.window)
 187     if vim._state.scrollableElements.has(activeElement) or helpScroll
 188       viewportUtils.scroll(activeElement, options)
 189       reset()
 190       return
 191
 192   vim._run(name, options, reset)
 193
 194
 195 helper_scrollByLinesX = (amount, {vim, event, count = 1}) ->
 196   distance = prefs.root.get('toolkit.scrollbox.horizontalScrollDistance')
 197   boost = if event.repeat then vim.options['scroll.horizontal_boost'] else 1
 198   helper_scroll(
 199     vim, event, 'scrollBy', 'lines', ['left'],
 200     [amount * distance * boost * count * 5]
 201   )
 202
 203 helper_scrollByLinesY = (amount, {vim, event, count = 1}) ->
 204   distance = prefs.root.get('toolkit.scrollbox.verticalScrollDistance')
 205   boost = if event.repeat then vim.options['scroll.vertical_boost'] else 1
 206   helper_scroll(
 207     vim, event, 'scrollBy', 'lines', ['top'],
 208     [amount * distance * boost * count * 20]
 209   )
 210
 211 helper_scrollByPagesY = (amount, type, {vim, event, count = 1}) ->
 212   adjustment = vim.options["scroll.#{type}_page_adjustment"]
 213   helper_scroll(
 214     vim, event, 'scrollBy', 'pages', ['top'], [amount * count],
 215     ['clientHeight'], adjustment
 216   )
 217
 218 helper_scrollToX = (amount, {vim, event}) ->
 219   helper_mark_last_scroll_position(vim)
 220   helper_scroll(
 221     vim, event, 'scrollTo', 'other', ['left'], [amount], ['scrollLeftMax']
 222   )
 223
 224 helper_scrollToY = (amount, {vim, event}) ->
 225   helper_mark_last_scroll_position(vim)
 226   helper_scroll(
 227     vim, event, 'scrollTo', 'other', ['top'], [amount], ['scrollTopMax']
 228   )
 229
 230 commands.scroll_left           = helper_scrollByLinesX.bind(null, -1)
 231 commands.scroll_right          = helper_scrollByLinesX.bind(null, +1)
 232 commands.scroll_down           = helper_scrollByLinesY.bind(null, +1)
 233 commands.scroll_up             = helper_scrollByLinesY.bind(null, -1)
 234 commands.scroll_page_down      = helper_scrollByPagesY.bind(null, +1,   'full')
 235 commands.scroll_page_up        = helper_scrollByPagesY.bind(null, -1,   'full')
 236 commands.scroll_half_page_down = helper_scrollByPagesY.bind(null, +0.5, 'half')
 237 commands.scroll_half_page_up   = helper_scrollByPagesY.bind(null, -0.5, 'half')
 238 commands.scroll_to_top         = helper_scrollToY.bind(null, 0)
 239 commands.scroll_to_bottom      = helper_scrollToY.bind(null, Infinity)
 240 commands.scroll_to_left        = helper_scrollToX.bind(null, 0)
 241 commands.scroll_to_right       = helper_scrollToX.bind(null, Infinity)
 242
 243 helper_mark_last_scroll_position = (vim) ->
 244   keyStr = vim.options['scroll.last_position_mark']
 245   vim._run('mark_scroll_position', {keyStr, notify: false, addToJumpList: true})
 246
 247 commands.mark_scroll_position = ({vim}) ->
 248   vim._enterMode('marks', (keyStr) ->
 249     vim._run('mark_scroll_position', {keyStr})
 250   )
 251   vim.notify(translate('notification.mark_scroll_position.enter'))
 252
 253 commands.scroll_to_mark = ({vim, event}) ->
 254   vim._enterMode('marks', (keyStr) ->
 255     lastPositionMark = vim.options['scroll.last_position_mark']
 256     helper_scroll(
 257       vim, event, 'scrollTo', 'other', ['left', 'top'], [0, 0]
 258       ['scrollLeftMax', 'scrollTopMax'], 0, 'scroll_to_mark'
 259       {keyStr, lastPositionMark, isUIEvent: false}
 260     )
 261     vim.hideNotification()
 262   )
 263   vim.notify(translate('notification.scroll_to_mark.enter'))
 264
 265 helper_scroll_to_position = (direction, {vim, event, count = 1}) ->
 266   lastPositionMark = vim.options['scroll.last_position_mark']
 267   helper_scroll(
 268     vim, event, 'scrollTo', 'other', ['left', 'top'], [0, 0]
 269     ['scrollLeftMax', 'scrollTopMax'], 0, 'scroll_to_position'
 270     {count, direction, lastPositionMark, isUIEvent: false}
 271   )
 272
 273 commands.scroll_to_previous_position =
 274   helper_scroll_to_position.bind(null, 'previous')
 275
 276 commands.scroll_to_next_position =
 277   helper_scroll_to_position.bind(null, 'next')
 278
 279
 280
 281 commands.tab_new = ({vim}) ->
 282   utils.nextTick(vim.window, ->
 283     vim.window.BrowserOpenTab()
 284   )
 285
 286 commands.tab_new_after_current = ({vim}) ->
 287   {window} = vim
 288   newTabPosition = window.gBrowser.selectedTab._tPos + 1
 289   utils.nextTick(window, ->
 290     utils.listenOnce(window, 'TabOpen', (event) ->
 291       newTab = event.originalTarget
 292       window.gBrowser.moveTabTo(newTab, newTabPosition)
 293     )
 294     window.BrowserOpenTab()
 295   )
 296
 297 commands.tab_duplicate = ({vim}) ->
 298   {gBrowser} = vim.window
 299   utils.nextTick(vim.window, ->
 300     gBrowser.duplicateTab(gBrowser.selectedTab)
 301   )
 302
 303 absoluteTabIndex = (relativeIndex, gBrowser, {pinnedSeparate}) ->
 304   tabs = gBrowser.visibleTabs
 305   {selectedTab} = gBrowser
 306
 307   currentIndex = tabs.indexOf(selectedTab)
 308   absoluteIndex = currentIndex + relativeIndex
 309   numTabsTotal = tabs.length
 310   numPinnedTabs = gBrowser._numPinnedTabs
 311
 312   [numTabs, min] = switch
 313     when not pinnedSeparate
 314       [numTabsTotal,  0]
 315     when selectedTab.pinned
 316       [numPinnedTabs, 0]
 317     else
 318       [numTabsTotal - numPinnedTabs, numPinnedTabs]
 319
 320   # Wrap _once_ if at one of the ends of the tab bar and cannot move in the
 321   # current direction.
 322   if (relativeIndex < 0 and currentIndex == min) or
 323      (relativeIndex > 0 and currentIndex == min + numTabs - 1)
 324     if absoluteIndex < min
 325       absoluteIndex += numTabs
 326     else if absoluteIndex >= min + numTabs
 327       absoluteIndex -= numTabs
 328
 329   absoluteIndex = Math.max(min, absoluteIndex)
 330   absoluteIndex = Math.min(absoluteIndex, min + numTabs - 1)
 331
 332   return absoluteIndex
 333
 334 helper_switch_tab = (direction, {vim, count = 1}) ->
 335   {gBrowser} = vim.window
 336   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: false})
 337   utils.nextTick(vim.window, ->
 338     gBrowser.selectTabAtIndex(index)
 339   )
 340
 341 commands.tab_select_previous = helper_switch_tab.bind(null, -1)
 342
 343 commands.tab_select_next     = helper_switch_tab.bind(null, +1)
 344
 345 helper_is_visited = (tab) ->
 346   return tab.getAttribute('VimFx-visited') or not tab.getAttribute('unread')
 347
 348 commands.tab_select_most_recent = ({vim, count = 1}) ->
 349   {gBrowser} = vim.window
 350   tabsSorted =
 351     Array.filter(
 352       gBrowser.tabs,
 353       (tab) -> not tab.closing and helper_is_visited(tab)
 354     ).sort((a, b) -> b.lastAccessed - a.lastAccessed)[1..] # Remove current tab.
 355   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 356   if tab
 357     gBrowser.selectedTab = tab
 358   else
 359     vim.notify(translate('notification.tab_select_most_recent.none'))
 360
 361 commands.tab_select_oldest_unvisited = ({vim, count = 1}) ->
 362   {gBrowser} = vim.window
 363   tabsSorted =
 364     Array.filter(
 365       gBrowser.tabs,
 366       (tab) -> not tab.closing and not helper_is_visited(tab)
 367     ).sort((a, b) -> a.lastAccessed - b.lastAccessed)
 368   tab = tabsSorted[Math.min(count - 1, tabsSorted.length - 1)]
 369   if tab
 370     gBrowser.selectedTab = tab
 371   else
 372     vim.notify(translate('notification.tab_select_oldest_unvisited.none'))
 373
 374 helper_move_tab = (direction, {vim, count = 1}) ->
 375   {gBrowser} = vim.window
 376   index = absoluteTabIndex(direction * count, gBrowser, {pinnedSeparate: true})
 377   utils.nextTick(vim.window, ->
 378     gBrowser.moveTabTo(gBrowser.selectedTab, index)
 379   )
 380
 381 commands.tab_move_backward = helper_move_tab.bind(null, -1)
 382
 383 commands.tab_move_forward  = helper_move_tab.bind(null, +1)
 384
 385 commands.tab_move_to_window = ({vim}) ->
 386   {gBrowser} = vim.window
 387   gBrowser.replaceTabWithWindow(gBrowser.selectedTab)
 388
 389 commands.tab_select_first = ({vim, count = 1}) ->
 390   utils.nextTick(vim.window, ->
 391     vim.window.gBrowser.selectTabAtIndex(count - 1)
 392   )
 393
 394 commands.tab_select_first_non_pinned = ({vim, count = 1}) ->
 395   firstNonPinned = vim.window.gBrowser._numPinnedTabs
 396   utils.nextTick(vim.window, ->
 397     vim.window.gBrowser.selectTabAtIndex(firstNonPinned + count - 1)
 398   )
 399
 400 commands.tab_select_last = ({vim, count = 1}) ->
 401   utils.nextTick(vim.window, ->
 402     vim.window.gBrowser.selectTabAtIndex(-count)
 403   )
 404
 405 commands.tab_toggle_pinned = ({vim}) ->
 406   currentTab = vim.window.gBrowser.selectedTab
 407   if currentTab.pinned
 408     vim.window.gBrowser.unpinTab(currentTab)
 409   else
 410     vim.window.gBrowser.pinTab(currentTab)
 411
 412 commands.tab_close = ({vim, count = 1}) ->
 413   {gBrowser} = vim.window
 414   return if gBrowser.selectedTab.pinned
 415   currentIndex = gBrowser.visibleTabs.indexOf(gBrowser.selectedTab)
 416   utils.nextTick(vim.window, ->
 417     for tab in gBrowser.visibleTabs[currentIndex...(currentIndex + count)]
 418       gBrowser.removeTab(tab)
 419     return
 420   )
 421
 422 commands.tab_restore = ({vim, count = 1}) ->
 423   utils.nextTick(vim.window, ->
 424     for index in [0...count] by 1
 425       restoredTab = vim.window.undoCloseTab()
 426       if not restoredTab and index == 0
 427         vim.notify(translate('notification.tab_restore.none'))
 428         break
 429     return
 430   )
 431
 432 commands.tab_restore_list = ({vim}) ->
 433   {window} = vim
 434   fragment = window.RecentlyClosedTabsAndWindowsMenuUtils.getTabsFragment(
 435     window, 'menuitem'
 436   )
 437   if fragment.childElementCount == 0
 438     vim.notify(translate('notification.tab_restore.none'))
 439   else
 440     utils.openPopup(utils.injectTemporaryPopup(window.document, fragment))
 441
 442 commands.tab_close_to_end = ({vim}) ->
 443   {gBrowser} = vim.window
 444   gBrowser.removeTabsToTheEndFrom(gBrowser.selectedTab)
 445
 446 commands.tab_close_other = ({vim}) ->
 447   {gBrowser} = vim.window
 448   gBrowser.removeAllTabsBut(gBrowser.selectedTab)
 449
 450
 451
 452 helper_follow = ({name, callback}, {vim, count, callbackOverride = null}) ->
 453   {window} = vim
 454   vim.markPageInteraction()
 455   help.removeHelp(window)
 456
 457   markerContainer = new MarkerContainer({
 458     window
 459     hintChars: vim.options['hints.chars']
 460     getComplementaryWrappers: (callback) ->
 461       vim._run(name, {pass: 'complementary'}, ({wrappers, viewport}) ->
 462         # `markerContainer.container` is `null`ed out when leaving Hints mode.
 463         # If this callback is called after we’ve left Hints mode (and perhaps
 464         # even entered it again), simply discard the result.
 465         return unless markerContainer.container
 466         if wrappers.length == 0
 467           vim.notify(translate('notification.follow.none'))
 468         callback({wrappers, viewport})
 469       )
 470   })
 471   MarkerContainer.remove(window) # Better safe than sorry.
 472   window.gBrowser.selectedBrowser.parentNode.appendChild(
 473     markerContainer.container
 474   )
 475
 476   chooseCallback = (marker, timesLeft, keyStr) ->
 477     if callbackOverride
 478       {type, href = null, elementIndex} = marker.wrapper
 479       return callbackOverride({type, href, id: elementIndex, timesLeft})
 480     else
 481       return callback(marker, timesLeft, keyStr)
 482
 483   # Enter Hints mode immediately, with an empty set of markers. The user might
 484   # press keys before any hints have been generated. Those keypresses should be
 485   # handled in Hints mode, not Normal mode.
 486   vim._enterMode('hints', {
 487     markerContainer, count
 488     callback: chooseCallback
 489     matchText: vim.options['hints.match_text']
 490     sleep: vim.options['hints.sleep']
 491   })
 492
 493   injectHints = ({wrappers, viewport, pass}) ->
 494     # See `getComplementaryWrappers` above.
 495     return unless markerContainer.container
 496
 497     if wrappers.length == 0
 498       if pass in ['single', 'second'] and markerContainer.markers.length == 0
 499         vim.notify(translate('notification.follow.none'))
 500         vim._enterMode('normal')
 501     else
 502       markerContainer.injectHints(wrappers, viewport, pass)
 503
 504     if pass == 'first'
 505       vim._run(name, {pass: 'second'}, injectHints)
 506
 507   vim._run(name, {pass: 'auto'}, injectHints)
 508
 509 helper_follow_clickable = (options, args) ->
 510   {vim} = args
 511
 512   callback = (marker, timesLeft, keyStr) ->
 513     {inTab, inBackground} = options
 514     {type, elementIndex} = marker.wrapper
 515     isLast = (timesLeft == 1)
 516     isLink = (type == 'link')
 517     {window} = vim
 518
 519     switch
 520       when keyStr.startsWith(vim.options['hints.toggle_in_tab'])
 521         inTab = not inTab
 522       when keyStr.startsWith(vim.options['hints.toggle_in_background'])
 523         inTab = true
 524         inBackground = not inBackground
 525       else
 526         unless isLast
 527           inTab = true
 528           inBackground = true
 529
 530     inTab = false unless isLink
 531
 532     if type == 'text' or (isLink and not (inTab and inBackground))
 533       isLast = true
 534
 535     vim._focusMarkerElement(elementIndex)
 536
 537     if inTab
 538       utils.nextTick(window, ->
 539         # `ContentClick.contentAreaClick` is what Firefox invokes when you click
 540         # links using the mouse. Using that instead of simply
 541         # `gBrowser.loadOneTab(url, options)` gives better interoperability with
 542         # other add-ons, such as Tree Style Tab and BackTrack Tab History.
 543         reset = prefs.root.tmp('browser.tabs.loadInBackground', true)
 544         ContentClick.contentAreaClick({
 545           href: marker.wrapper.href
 546           shiftKey: not inBackground
 547           ctrlKey: true
 548           metaKey: true
 549           originAttributes: window.document.nodePrincipal?.originAttributes ? {}
 550         }, vim.browser)
 551         reset()
 552       )
 553
 554     # The point of “clicking” scrollable elements is focusing them (which is
 555     # done above) so that scrolling commands may scroll them. Simulating a click
 556     # here usually _unfocuses_ the element.
 557     else if type != 'scrollable'
 558       vim._run('click_marker_element', {
 559         elementIndex, type
 560         browserOffset: vim._getBrowserOffset()
 561         preventTargetBlank: vim.options.prevent_target_blank
 562       })
 563
 564     return not isLast
 565
 566   name = if options.inTab then 'follow_in_tab' else 'follow'
 567   helper_follow({name, callback}, args)
 568
 569 commands.follow =
 570   helper_follow_clickable.bind(null, {inTab: false, inBackground: true})
 571
 572 commands.follow_in_tab =
 573   helper_follow_clickable.bind(null, {inTab: true, inBackground: true})
 574
 575 commands.follow_in_focused_tab =
 576   helper_follow_clickable.bind(null, {inTab: true, inBackground: false})
 577
 578 helper_follow_in_window = (options, args) ->
 579   {vim} = args
 580
 581   callback = (marker) ->
 582     vim._focusMarkerElement(marker.wrapper.elementIndex)
 583     {href} = marker.wrapper
 584     vim.window.openLinkIn(href, 'window', options) if href
 585     return false
 586
 587   helper_follow({name: 'follow_in_tab', callback}, args)
 588
 589 commands.follow_in_window =
 590   helper_follow_in_window.bind(null, {})
 591
 592 commands.follow_in_private_window =
 593   helper_follow_in_window.bind(null, {private: true})
 594
 595 commands.follow_multiple = (args) ->
 596   args.count = Infinity
 597   commands.follow(args)
 598
 599 commands.follow_copy = (args) ->
 600   {vim} = args
 601
 602   callback = (marker) ->
 603     property = switch marker.wrapper.type
 604       when 'link'
 605         'href'
 606       when 'text'
 607         'value'
 608       when 'contenteditable', 'complementary'
 609         '_selection'
 610     helper_copy_marker_element(vim, marker.wrapper.elementIndex, property)
 611     return false
 612
 613   helper_follow({name: 'follow_copy', callback}, args)
 614
 615 commands.follow_focus = (args) ->
 616   {vim} = args
 617
 618   callback = (marker) ->
 619     vim._focusMarkerElement(marker.wrapper.elementIndex, {select: true})
 620     return false
 621
 622   helper_follow({name: 'follow_focus', callback}, args)
 623
 624 commands.open_context_menu = (args) ->
 625   {vim} = args
 626
 627   callback = (marker) ->
 628     {type, elementIndex} = marker.wrapper
 629     vim._run('click_marker_element', {
 630       elementIndex, type
 631       browserOffset: vim._getBrowserOffset()
 632     })
 633     return false
 634
 635   helper_follow({name: 'follow_context', callback}, args)
 636
 637 commands.click_browser_element = ({vim}) ->
 638   {window} = vim
 639   markerElements = []
 640
 641   getButtonMenu = (element) ->
 642     if element.localName == 'dropmarker' and
 643        element.parentNode?.localName == 'toolbarbutton'
 644       return element.parentNode.querySelector('menupopup')
 645     else
 646       return null
 647
 648   filter = ({complementary}, element, getElementShape) ->
 649     type = switch
 650       when vim._state.scrollableElements.has(element)
 651         'scrollable'
 652       when getButtonMenu(element)
 653         'dropmarker'
 654       when utils.isFocusable(element) or
 655            (element.onclick and element.localName != 'statuspanel')
 656         'clickable'
 657
 658     if complementary
 659       type = if type then null else 'complementary'
 660
 661     return unless type
 662
 663     # `getElementShape(element, -1)` is intentionally _not_ used in the
 664     # `complementary` run, because it results in tons of useless hints for
 665     # hidden context menus.
 666     shape = getElementShape(element)
 667     return unless shape.nonCoveredPoint
 668
 669     # The tabs and their close buttons as well as the tab bar scroll arrows get
 670     # better hints, since switching or closing tabs is the most common use case
 671     # for the `eb` command.
 672     isTab = element.classList?.contains('tabbrowser-tab')
 673     isPrioritized =
 674       isTab or
 675       element.classList?.contains('tab-close-button') or
 676       element.classList?.contains('scrollbutton-up') or
 677       element.classList?.contains('scrollbutton-down')
 678
 679     length = markerElements.push(element)
 680     return {
 681       type, shape, isTab, isPrioritized,
 682       combinedArea: shape.area,
 683       elementIndex: length - 1,
 684     }
 685
 686   callback = (marker) ->
 687     element = markerElements[marker.wrapper.elementIndex]
 688     switch marker.wrapper.type
 689       when 'scrollable'
 690         utils.focusElement(element, {flag: 'FLAG_BYKEY'})
 691       when 'dropmarker'
 692         getButtonMenu(element).openPopup(
 693           element.parentNode, # Anchor node.
 694           'after_end', # Position.
 695           0, 0, # Offset.
 696           false, # Isn’t a context menu.
 697           true, # Allow the 'position' attribute to override the above position.
 698         )
 699       when 'clickable', 'complementary'
 700         # VimFx’s own button won’t trigger unless the click is simulated in the
 701         # next tick. This might be true for other buttons as well.
 702         utils.nextTick(window, ->
 703           utils.focusElement(element)
 704           browserOffset = {x: window.screenX, y: window.screenY}
 705           switch
 706             when element.localName == 'tab'
 707               # Only 'mousedown' seems to be able to activate tabs.
 708               utils.simulateMouseEvents(element, ['mousedown'], browserOffset)
 709             when element.closest('tab')
 710               # If `.click()` is used on a tab close button, its tab will be
 711               # selected first, which might cause the selected tab to change.
 712               utils.simulateMouseEvents(element, 'click-xul', browserOffset)
 713             else
 714               # `.click()` seems to trigger more buttons (such as NoScript’s
 715               # button and Firefox’s “hamburger” menu button) than simulating
 716               # 'click-xul'.
 717               element.click()
 718               utils.openDropdown(element)
 719         )
 720     return false
 721
 722   wrappers = markableElements.find(
 723     window, filter.bind(null, {complementary: false})
 724   )
 725
 726   if wrappers.length > 0
 727     viewport = viewportUtils.getWindowViewport(window)
 728
 729     markerContainer = new MarkerContainer({
 730       window
 731       hintChars: vim.options['hints.chars']
 732       adjustZoom: false
 733       minWeightDiff: 0
 734       getComplementaryWrappers: (callback) ->
 735         newWrappers = markableElements.find(
 736           window, filter.bind(null, {complementary: true})
 737         )
 738         callback({wrappers: newWrappers, viewport})
 739     })
 740     MarkerContainer.remove(window) # Better safe than sorry.
 741     markerContainer.container.classList.add('ui')
 742     window.document.getElementById('browser-panel').appendChild(
 743       markerContainer.container
 744     )
 745
 746     [firstWrappers, secondWrappers] =
 747       utils.partition(wrappers, (wrapper) -> wrapper.isPrioritized)
 748
 749     numChars = markerContainer.alphabet.length
 750     numPrimary = markerContainer.primaryHintChars.length
 751     numTabs = firstWrappers.filter(({isTab}) -> isTab).length
 752     index = 0
 753
 754     for wrapper in firstWrappers
 755       if wrapper.isTab
 756         # Given the hint chars `abc de`, give the tabs weights so that the hints
 757         # consistently become `a b ca cb cc cd cea ceb cec ced ceea ceeb` and so
 758         # on. The rule is that the weight of a tab must be larger than the sum
 759         # of all tabs with a longer hint. We start out at `1` and then use
 760         # smaller and smaller fractions. This is to make sure that the tabs get
 761         # consistent hints as the number of tabs or the size of the window
 762         # changes.
 763         exponent = (index - numPrimary + 1) // (numChars - 1) + 1
 764         wrapper.combinedArea = 1 / numChars ** exponent
 765         index += 1
 766       else
 767         # Make sure that the tab close buttons and the tab bar scroll buttons
 768         # come after all the tabs. Treating them all as the same size is fine.
 769         # Their sum must be small enough in order not to affect the tab hints.
 770         # It might look like using `0` is a good idea, but that results in
 771         # increasingly worse hints the more tab close buttons there are.
 772         wrapper.combinedArea = 1 / numChars ** numTabs
 773
 774     # Since most of the best hint characters might be used for the tabs, make
 775     # sure that all other elements don’t get really bad hints. First, favor
 776     # larger elements by sorting them. Then, give them all the same weight so
 777     # that larger elements (such as the location bar, search bar, the web
 778     # console input and other large areas in the devtools) don’t overpower the
 779     # smaller ones. The usual “the larger the element, the better the hint” rule
 780     # doesn’t really apply the same way for browser UI elements as in web pages.
 781     secondWrappers.sort((a, b) -> b.combinedArea - a.combinedArea)
 782     for wrapper in secondWrappers
 783       wrapper.combinedArea = 1
 784
 785     markerContainer.injectHints(firstWrappers, viewport, 'first')
 786     markerContainer.injectHints(secondWrappers, viewport, 'second')
 787     vim._enterMode('hints', {markerContainer, callback, matchText: false})
 788
 789   else
 790     vim.notify(translate('notification.follow.none'))
 791
 792 helper_follow_pattern = (type, {vim}) ->
 793   options = {
 794     pattern_selector: vim.options.pattern_selector
 795     pattern_attrs: vim.options.pattern_attrs
 796     patterns: vim.options["#{type}_patterns"]
 797   }
 798   browserOffset = vim._getBrowserOffset()
 799   vim._run('follow_pattern', {type, browserOffset, options})
 800
 801 commands.follow_previous = helper_follow_pattern.bind(null, 'prev')
 802
 803 commands.follow_next     = helper_follow_pattern.bind(null, 'next')
 804
 805 commands.focus_text_input = ({vim, count}) ->
 806   vim.markPageInteraction()
 807   vim._run('focus_text_input', {count})
 808
 809 helper_follow_selectable = ({select}, args) ->
 810   {vim} = args
 811
 812   callback = (marker) ->
 813     vim._run('element_text_select', {
 814       elementIndex: marker.wrapper.elementIndex
 815       full: select
 816       scroll: select
 817     })
 818     vim._enterMode('caret', {select})
 819     return false
 820
 821   helper_follow({name: 'follow_selectable', callback}, args)
 822
 823 commands.element_text_caret =
 824   helper_follow_selectable.bind(null, {select: false})
 825
 826 commands.element_text_select =
 827   helper_follow_selectable.bind(null, {select: true})
 828
 829 commands.element_text_copy = (args) ->
 830   {vim} = args
 831
 832   callback = (marker) ->
 833     helper_copy_marker_element(vim, marker.wrapper.elementIndex, '_selection')
 834     return false
 835
 836   helper_follow({name: 'follow_selectable', callback}, args)
 837
 838 helper_copy_marker_element = (vim, elementIndex, property) ->
 839   if property == '_selection'
 840     # Selecting the text and then copying that selection is better than copying
 841     # `.textContent`. Slack uses markdown-style backtick syntax for code spans
 842     # and then includes those backticks in the compiled output (!), in hidden
 843     # `<span>`s, so `.textContent` would copy those too. In `contenteditable`
 844     # elements, text selection gives better whitespace than `.textContent`.
 845     vim._run('element_text_select', {elementIndex, full: true}, ->
 846       vim.window.goDoCommand('cmd_copy') # See `caret.copy_selection_and_exit`.
 847       vim._run('clear_selection')
 848     )
 849   else
 850     vim._run('copy_marker_element', {elementIndex, property})
 851
 852
 853
 854 findStorage = {
 855   lastSearchString: ''
 856   busy: false
 857 }
 858
 859 helper_find_from_top_of_viewport = (vim, direction, callback) ->
 860   if vim.options.find_from_top_of_viewport
 861     vim._run('find_from_top_of_viewport', {direction}, ->
 862       callback()
 863     )
 864   else
 865     callback()
 866
 867 helper_find = ({highlight, linksOnly = false}, {vim}) ->
 868   if findStorage.busy
 869     # Make sure to enter find mode here, since that’s where `findStorage.busy`
 870     # is reset to `false` again. Otherwise we can get stuck in the “busy” state.
 871     vim._enterMode('find')
 872     return
 873
 874   helpSearchInput = help.getSearchInput(vim.window)
 875   if helpSearchInput
 876     helpSearchInput.select()
 877     return
 878
 879   # Important: Enter Find mode immediately. See `onInput` for Find mode.
 880   findStorage.busy = true
 881   vim._enterMode('find')
 882
 883   helper_mark_last_scroll_position(vim)
 884   vim._run('mark_scroll_position', {
 885     keyStr: vim.options['scroll.last_find_mark']
 886     notify: false
 887   })
 888
 889   helper_find_from_top_of_viewport(vim, FORWARD, ->
 890     return unless vim.mode == 'find'
 891     utils.getFindBar(vim.window.gBrowser).then((findBar) ->
 892       mode = if linksOnly then findBar.FIND_LINKS else findBar.FIND_NORMAL
 893       findBar.startFind(mode)
 894       utils.focusElement(findBar._findField, {select: true})
 895
 896       return if linksOnly
 897       return unless highlightButton = findBar.getElement('highlight')
 898       if highlightButton.checked != highlight
 899         highlightButton.click()
 900     )
 901   )
 902
 903 commands.find = helper_find.bind(null, {highlight: false})
 904
 905 commands.find_highlight_all = helper_find.bind(null, {highlight: true})
 906
 907 commands.find_links_only = helper_find.bind(null, {linksOnly: true})
 908
 909 helper_find_again = (direction, {vim}) ->
 910   return if findStorage.busy
 911
 912   utils.getFindBar(vim.window.gBrowser).then((findBar) ->
 913     if findStorage.lastSearchString.length == 0
 914       vim.notify(translate('notification.find_again.none'))
 915       return
 916
 917     findStorage.busy = true
 918
 919     helper_mark_last_scroll_position(vim)
 920     helper_find_from_top_of_viewport(vim, direction, ->
 921       findBar._findField.value = findStorage.lastSearchString
 922
 923       # `.onFindResult` is temporarily hacked to be able to know when the
 924       # asynchronous `.onFindAgainCommand` is done. When PDFs are shown using
 925       # PDF.js, `.updateControlState` is called instead of `.onFindResult`, so
 926       # hack that one too.
 927       originalOnFindResult = findBar.onFindResult
 928       originalUpdateControlState = findBar.updateControlState
 929
 930       findBar.onFindResult = (data) ->
 931         # Prevent the find bar from re-opening if there are no matches.
 932         data.storeResult = false
 933         findBar.onFindResult = originalOnFindResult
 934         findBar.updateControlState = originalUpdateControlState
 935         findBar.onFindResult(data)
 936         callback()
 937
 938       findBar.updateControlState = (args...) ->
 939         # Firefox inconsistently _doesn’t_ re-open the find bar if there are no
 940         # matches here, so no need to take care of that in this case.
 941         findBar.onFindResult = originalOnFindResult
 942         findBar.updateControlState = originalUpdateControlState
 943         findBar.updateControlState(args...)
 944         callback()
 945
 946       callback = ->
 947         message = findBar._findStatusDesc.textContent
 948         vim.notify(message) if message
 949         findStorage.busy = false
 950
 951       findBar.onFindAgainCommand(not direction)
 952     )
 953   )
 954
 955 commands.find_next     = helper_find_again.bind(null, FORWARD)
 956
 957 commands.find_previous = helper_find_again.bind(null, BACKWARD)
 958
 959
 960
 961 commands.window_new = ({vim}) ->
 962   vim.window.OpenBrowserWindow()
 963
 964 commands.window_new_private = ({vim}) ->
 965   vim.window.OpenBrowserWindow({private: true})
 966
 967 commands.enter_mode_ignore = ({vim, blacklist = false}) ->
 968   type = if blacklist then 'blacklist' else 'explicit'
 969   vim._enterMode('ignore', {type})
 970
 971 # Quote next keypress (pass it through to the page).
 972 commands.quote = ({vim, count = 1}) ->
 973   vim._enterMode('ignore', {type: 'explicit', count})
 974
 975 commands.enter_reader_view = ({vim}) ->
 976   button = vim.window.document.getElementById('reader-mode-button')
 977   if not button?.hidden
 978     button.click()
 979   else
 980     vim.notify(translate('notification.enter_reader_view.none'))
 981
 982 commands.reload_config_file = ({vim}) ->
 983   vim._parent.emit('shutdown')
 984   config.load(vim._parent, {allowDeprecated: false}, (status) -> switch status
 985     when null
 986       vim.notify(translate('notification.reload_config_file.none'))
 987     when true
 988       vim.notify(translate('notification.reload_config_file.success'))
 989     else
 990       vim.notify(translate('notification.reload_config_file.failure'))
 991   )
 992
 993 commands.edit_blacklist = ({vim}) ->
 994   url = vim.browser.currentURI.spec
 995   location = new vim.window.URL(url)
 996   newPattern = if location.host then "*#{location.host}*" else location.href
 997   delimiter = '  '
 998   blacklistString = prefs.get('blacklist')
 999
1000   if vim._isBlacklisted(url)
1001     blacklist = parsePrefs.parseSpaceDelimitedString(blacklistString).parsed
1002     [matching, nonMatching] = utils.partition(blacklist, (string, index) ->
1003       return vim.options.blacklist[index].test(url)
1004     )
1005     newBlacklistString = "
1006       #{matching.join(delimiter)}\
1007       #{delimiter.repeat(7)}\
1008       #{nonMatching.join(delimiter)}
1009     "
1010     extraMessage = translate('pref.blacklist.extra.is_blacklisted')
1011   else
1012     newBlacklistString = "#{newPattern}#{delimiter}#{blacklistString}"
1013     extraMessage = translate('pref.blacklist.extra.added', newPattern)
1014
1015   message = """
1016     #{translate('pref.blacklist.title')}: #{translate('pref.blacklist.desc')}
1017
1018     #{extraMessage}
1019   """
1020
1021   vim._modal('prompt', [message, newBlacklistString.trim()], (input) ->
1022     return if input == null
1023     # Just set the blacklist as if the user had typed it in the Add-ons Manager,
1024     # and let the regular pref parsing take care of it.
1025     prefs.set('blacklist', input)
1026     vim._onLocationChange(url)
1027   )
1028
1029 commands.help = ({vim}) ->
1030   help.toggleHelp(vim.window, vim._parent)
1031
1032 commands.dev = ({vim}) ->
1033   vim.window.DeveloperToolbar.show(true) # `true` to focus.
1034
1035 commands.esc = ({vim}) ->
1036   vim._run('esc')
1037   vim.hideNotification()
1038
1039   # Firefox does things differently when blurring the location bar, depending on
1040   # whether the autocomplete popup is open or not. To be consistent, always
1041   # close the autocomplete popup before blurring.
1042   vim.window.gURLBar.closePopup()
1043
1044   utils.blurActiveBrowserElement(vim)
1045   utils.getFindBar(vim.window.gBrowser).then((findBar) -> findBar.close())
1046
1047   # Better safe than sorry.
1048   MarkerContainer.remove(vim.window)
1049   vim._parent.resetCaretBrowsing()
1050
1051   # Calling `.hide()` when the toolbar is not open can destroy it for the rest
1052   # of the Firefox session. The code here is taken from the `.toggle()` method.
1053   developerToolbar = gDevToolsBrowser.getDeveloperToolbar(vim.window)
1054   if developerToolbar.visible
1055     developerToolbar.hide().catch(console.error)
1056
1057   unless help.getSearchInput(vim.window)?.getAttribute('focused')
1058     help.removeHelp(vim.window)
1059
1060   vim._setFocusType('none') # Better safe than sorry.
1061
1062
1063
1064 module.exports = {
1065   commands
1066   findStorage
1067 }