extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet } = require 'prefs'
   8
   9 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  10
  11 # “Selecting an element” means “focusing and selecting the text, if any, of an
  12 # element”.
  13
  14 # Select the Address Bar.
  15 command_focus = (vim) ->
  16   # This function works even if the Address Bar has been removed.
  17   vim.rootWindow.focusAndSelectUrlBar()
  18
  19 # Select the Search Bar.
  20 command_focus_search = (vim) ->
  21   # The `.webSearch()` method opens a search engine in a tab if the Search Bar
  22   # has been removed. Therefore we first check if it exists.
  23   if vim.rootWindow.BrowserSearch.searchBar
  24     vim.rootWindow.BrowserSearch.webSearch()
  25
  26 helper_paste = (vim) ->
  27   url = utils.readFromClipboard(vim.window)
  28   postData = null
  29   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  30     url = submission.uri.spec
  31     { postData } = submission
  32   return {url, postData}
  33
  34 # Go to or search for the contents of the system clipboard.
  35 command_paste = (vim) ->
  36   { url, postData } = helper_paste(vim)
  37   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  38
  39 # Go to or search for the contents of the system clipboard in a new tab.
  40 command_paste_tab = (vim) ->
  41   { url, postData } = helper_paste(vim)
  42   vim.rootWindow.gBrowser.selectedTab =
  43     vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  44
  45 # Copy the URL or text of a marker element to the system clipboard.
  46 command_marker_yank = (vim) ->
  47   callback = (marker) ->
  48     if url = marker.element.href
  49       marker.element.focus()
  50       utils.writeToClipboard(url)
  51     else if utils.isTextInputElement(marker.element)
  52       utils.writeToClipboard(marker.element.value)
  53
  54   vim.enterMode('hints', callback)
  55
  56 # Focus element.
  57 command_marker_focus = (vim) ->
  58   callback = (marker) -> marker.element.focus()
  59
  60   vim.enterMode('hints', callback)
  61
  62 # Copy the current URL to the system clipboard.
  63 command_yank = (vim) ->
  64   utils.writeToClipboard(vim.window.location.href)
  65
  66 # Reload the current tab, possibly from cache.
  67 command_reload = (vim) ->
  68   vim.rootWindow.BrowserReload()
  69
  70 # Reload the current tab, skipping cache.
  71 command_reload_force = (vim) ->
  72   vim.rootWindow.BrowserReloadSkipCache()
  73
  74 # Reload all tabs, possibly from cache.
  75 command_reload_all = (vim) ->
  76   vim.rootWindow.gBrowser.reloadAllTabs()
  77
  78 # Reload all tabs, skipping cache.
  79 command_reload_all_force = (vim) ->
  80   for tab in vim.rootWindow.gBrowser.visibleTabs
  81     window = tab.linkedBrowser.contentWindow
  82     window.location.reload(true)
  83
  84 # Stop loading the current tab.
  85 command_stop = (vim) ->
  86   vim.window.stop()
  87
  88 # Stop loading all tabs.
  89 command_stop_all = (vim) ->
  90   for tab in vim.rootWindow.gBrowser.visibleTabs
  91     window = tab.linkedBrowser.contentWindow
  92     window.stop()
  93
  94 # Scroll to the top of the page.
  95 command_scroll_to_top = (vim) ->
  96   vim.rootWindow.goDoCommand('cmd_scrollTop')
  97
  98 # Scroll to the bottom of the page.
  99 command_scroll_to_bottom = (vim) ->
 100   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 101
 102 # Scroll down a bit.
 103 command_scroll_down = (vim) ->
 104   step = getPref('scroll_step_lines')
 105   utils.simulateWheel(vim.window, 0, +step, utils.WHEEL_MODE_LINE)
 106
 107 # Scroll up a bit.
 108 command_scroll_up = (vim) ->
 109   step = getPref('scroll_step_lines')
 110   utils.simulateWheel(vim.window, 0, -step, utils.WHEEL_MODE_LINE)
 111
 112 # Scroll left a bit.
 113 command_scroll_left = (vim) ->
 114   step = getPref('scroll_step_lines')
 115   utils.simulateWheel(vim.window, -step, 0, utils.WHEEL_MODE_LINE)
 116
 117 # Scroll right a bit.
 118 command_scroll_right = (vim) ->
 119   step = getPref('scroll_step_lines')
 120   utils.simulateWheel(vim.window, +step, 0, utils.WHEEL_MODE_LINE)
 121
 122 # Scroll down half a page.
 123 command_scroll_half_page_down = (vim) ->
 124   utils.simulateWheel(vim.window, 0, +0.5, utils.WHEEL_MODE_PAGE)
 125
 126 # Scroll up half a page.
 127 command_scroll_half_page_up = (vim) ->
 128   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 129
 130 # Scroll down full a page.
 131 command_scroll_page_down = (vim) ->
 132   utils.simulateWheel(vim.window, 0, +1, utils.WHEEL_MODE_PAGE)
 133
 134 # Scroll up full a page.
 135 command_scroll_page_up = (vim) ->
 136   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 137
 138 # Open a new tab and select the Address Bar.
 139 command_open_tab = (vim) ->
 140   vim.rootWindow.BrowserOpenTab()
 141
 142 # Switch to the previous tab.
 143 command_tab_prev = (vim) ->
 144   wrap = true
 145   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true) # wrap
 146
 147 # Switch to the next tab.
 148 command_tab_next = (vim) ->
 149   wrap = true
 150   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(+1, true) # wrap
 151
 152 # Move the current tab backward.
 153 command_tab_move_left = (vim) ->
 154   { gBrowser } = vim.rootWindow
 155   lastIndex = gBrowser.tabContainer.selectedIndex
 156   gBrowser.moveTabBackward()
 157   if gBrowser.tabContainer.selectedIndex == lastIndex
 158     gBrowser.moveTabToEnd()
 159
 160 # Move the current tab forward.
 161 command_tab_move_right = (vim) ->
 162   { gBrowser } = vim.rootWindow
 163   lastIndex = gBrowser.tabContainer.selectedIndex
 164   gBrowser.moveTabForward()
 165   if gBrowser.tabContainer.selectedIndex == lastIndex
 166     gBrowser.moveTabToStart()
 167
 168 # Load the home page.
 169 command_home = (vim) ->
 170   vim.rootWindow.BrowserHome()
 171
 172 # Switch to the first tab.
 173 command_tab_first = (vim) ->
 174   vim.rootWindow.gBrowser.selectTabAtIndex(0)
 175
 176 # Switch to the last tab.
 177 command_tab_last = (vim) ->
 178   vim.rootWindow.gBrowser.selectTabAtIndex(-1)
 179
 180 # Close current tab.
 181 command_close_tab = (vim) ->
 182   unless vim.rootWindow.gBrowser.selectedTab.pinned
 183     vim.rootWindow.gBrowser.removeCurrentTab()
 184
 185 # Restore last closed tab.
 186 command_restore_tab = (vim) ->
 187   vim.rootWindow.undoCloseTab()
 188
 189 helper_follow = ({ inTab, multiple }, vim) ->
 190   callback = (matchedMarker, markers) ->
 191     matchedMarker.element.focus()
 192     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 193     isEditable = utils.isElementEditable(matchedMarker.element)
 194     if multiple and not isEditable
 195       # By not resetting immediately one is able to see the last char being
 196       # matched, which gives some nice visual feedback that you've typed the
 197       # right char.
 198       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 199       return true
 200
 201   vim.enterMode('hints', callback)
 202
 203 # Follow links with hint markers.
 204 command_follow = helper_follow.bind(undefined, {inTab: false})
 205
 206 # Follow links in a new Tab with hint markers.
 207 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 208
 209 # Follow multiple links with hint markers.
 210 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 211
 212 helper_follow_pattern = do ->
 213   # Search for the prev/next patterns in the following attributes of the
 214   # element. `rel` should be kept as the first attribute, since the standard
 215   # way of marking up prev/next links (`rel="prev"` and `rel="next"`) should be
 216   # favored. Even though some of these attributes only allow a fixed set of
 217   # keywords, we pattern-match them anyways since lots of sites don’t follow
 218   # the spec and use the attributes arbitrarily.
 219   attrs = ['rel', 'role', 'data-tooltip', 'aria-label']
 220
 221   return (type, vim) ->
 222     links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 223       .filter(utils.isElementVisible)
 224
 225     patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 226
 227     if matchingLink = utils.getBestPatternMatch(patterns, attrs, links)
 228       utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 229
 230 # Follow previous page.
 231 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 232
 233 # Follow next page.
 234 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 235
 236 # Go up one level in the URL hierarchy.
 237 command_go_up_path = (vim) ->
 238   path = vim.window.location.pathname
 239   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 240
 241 # Go up to root of the URL hierarchy.
 242 command_go_to_root = (vim) ->
 243   vim.window.location.href = vim.window.location.origin
 244
 245 # Go back in history.
 246 command_back = (vim) ->
 247   vim.rootWindow.BrowserBack()
 248
 249 # Go forward in history.
 250 command_forward = (vim) ->
 251   vim.rootWindow.BrowserForward()
 252
 253 findStorage = {lastSearchString: ''}
 254
 255 helper_find = (highlight, vim) ->
 256   findBar = vim.rootWindow.gBrowser.getFindBar()
 257
 258   findBar.onFindCommand()
 259   findBar._findField.focus()
 260   findBar._findField.select()
 261
 262   return unless highlightButton = findBar.getElement('highlight')
 263   if highlightButton.checked != highlight
 264     highlightButton.click()
 265
 266 # Open the find bar, making sure that hightlighting is off.
 267 command_find = helper_find.bind(undefined, false)
 268
 269 # Open the find bar, making sure that hightlighting is on.
 270 command_find_hl = helper_find.bind(undefined, true)
 271
 272 helper_find_again = (direction, vim) ->
 273   findBar = vim.rootWindow.gBrowser.getFindBar()
 274   if findStorage.lastSearchString.length > 0
 275     findBar._findField.value = findStorage.lastSearchString
 276     findBar.onFindAgainCommand(direction)
 277
 278 # Search for the last pattern.
 279 command_find_next = helper_find_again.bind(undefined, false)
 280
 281 # Search for the last pattern backwards.
 282 command_find_prev = helper_find_again.bind(undefined, true)
 283
 284 # Enter insert mode.
 285 command_insert_mode = (vim) ->
 286   vim.enterMode('insert')
 287
 288 # Display the Help Dialog.
 289 command_help = (vim) ->
 290   help.injectHelp(vim.window.document, commands)
 291
 292 # Open and select the Developer Toolbar.
 293 command_dev = (vim) ->
 294   vim.rootWindow.DeveloperToolbar.show(true) # focus
 295
 296 command_Esc = (vim, event) ->
 297   utils.blurActiveElement(vim.window)
 298
 299   # Blur active XUL control.
 300   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 301   vim.window.setTimeout(callback, 0)
 302
 303   help.removeHelp(vim.window.document)
 304
 305   vim.rootWindow.DeveloperToolbar.hide()
 306
 307   vim.rootWindow.gBrowser.getFindBar().close()
 308
 309   vim.rootWindow.TabView.hide()
 310
 311
 312 class Command
 313   constructor: (@group, @name, @func, keys) ->
 314     @defaultKeys = keys
 315     if isPrefSet(@prefName('keys'))
 316       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 317     else
 318       @keyValues = keys
 319
 320   # Name of the preference for a given property.
 321   prefName: (value) -> "commands.#{ @name }.#{ value }"
 322
 323   keys: (value) ->
 324     if value is undefined
 325       return @keyValues
 326     else
 327       @keyValues = value or @defaultKeyValues
 328       setPref(@prefName('keys'), value and JSON.stringify(value))
 329
 330   help: -> _("help_command_#{ @name }")
 331
 332 commands = [
 333   new Command('urls',   'focus',                 command_focus,                 ['o'])
 334   new Command('urls',   'focus_search',          command_focus_search,          ['O'])
 335   new Command('urls',   'paste',                 command_paste,                 ['p'])
 336   new Command('urls',   'paste_tab',             command_paste_tab,             ['P'])
 337   new Command('urls',   'marker_yank',           command_marker_yank,           ['y,f'])
 338   new Command('urls',   'marker_focus',          command_marker_focus,          ['v,f'])
 339   new Command('urls',   'yank',                  command_yank,                  ['y,y'])
 340   new Command('urls',   'reload',                command_reload,                ['r'])
 341   new Command('urls',   'reload_force',          command_reload_force,          ['R'])
 342   new Command('urls',   'reload_all',            command_reload_all,            ['a,r'])
 343   new Command('urls',   'reload_all_force',      command_reload_all_force,      ['a,R'])
 344   new Command('urls',   'stop',                  command_stop,                  ['s'])
 345   new Command('urls',   'stop_all',              command_stop_all,              ['a,s'])
 346
 347   new Command('nav',    'scroll_to_top',         command_scroll_to_top ,        ['g,g'])
 348   new Command('nav',    'scroll_to_bottom',      command_scroll_to_bottom,      ['G'])
 349   new Command('nav',    'scroll_down',           command_scroll_down,           ['j', 'c-e'])
 350   new Command('nav',    'scroll_up',             command_scroll_up,             ['k', 'c-y'])
 351   new Command('nav',    'scroll_left',           command_scroll_left,           ['h'])
 352   new Command('nav',    'scroll_right',          command_scroll_right ,         ['l'])
 353   new Command('nav',    'scroll_half_page_down', command_scroll_half_page_down, ['d'])
 354   new Command('nav',    'scroll_half_page_up',   command_scroll_half_page_up,   ['u'])
 355   new Command('nav',    'scroll_page_down',      command_scroll_page_down,      ['c-f'])
 356   new Command('nav',    'scroll_page_up',        command_scroll_page_up,        ['c-b'])
 357
 358   new Command('tabs',   'open_tab',              command_open_tab,              ['t'])
 359   new Command('tabs',   'tab_prev',              command_tab_prev,              ['J', 'g,T'])
 360   new Command('tabs',   'tab_next',              command_tab_next,              ['K', 'g,t'])
 361   new Command('tabs',   'tab_move_left',         command_tab_move_left,         ['c-J'])
 362   new Command('tabs',   'tab_move_right',        command_tab_move_right,        ['c-K'])
 363   new Command('tabs',   'home',                  command_home,                  ['g,h'])
 364   new Command('tabs',   'tab_first',             command_tab_first,             ['g,H', 'g,^'])
 365   new Command('tabs',   'tab_last',              command_tab_last,              ['g,L', 'g,$'])
 366   new Command('tabs',   'close_tab',             command_close_tab,             ['x'])
 367   new Command('tabs',   'restore_tab',           command_restore_tab,           ['X'])
 368
 369   new Command('browse', 'follow',                command_follow,                ['f'])
 370   new Command('browse', 'follow_in_tab',         command_follow_in_tab,         ['F'])
 371   new Command('browse', 'follow_multiple',       command_follow_multiple,       ['a,f'])
 372   new Command('browse', 'follow_previous',       command_follow_prev,           ['['])
 373   new Command('browse', 'follow_next',           command_follow_next,           [']'])
 374   new Command('browse', 'go_up_path',            command_go_up_path,            ['g,u'])
 375   new Command('browse', 'go_to_root',            command_go_to_root,            ['g,U'])
 376   new Command('browse', 'back',                  command_back,                  ['H'])
 377   new Command('browse', 'forward',               command_forward,               ['L'])
 378
 379   new Command('misc',   'find',                  command_find,                  ['/'])
 380   new Command('misc',   'find_hl',               command_find_hl,               ['a,/'])
 381   new Command('misc',   'find_next',             command_find_next,             ['n'])
 382   new Command('misc',   'find_prev',             command_find_prev,             ['N'])
 383   new Command('misc',   'insert_mode',           command_insert_mode,           ['i'])
 384   new Command('misc',   'help',                  command_help,                  ['?'])
 385   new Command('misc',   'dev',                   command_dev,                   [':'])
 386
 387   escapeCommand =
 388   new Command('misc',   'Esc',                   command_Esc,                   ['Esc'])
 389 ]
 390
 391 searchForMatchingCommand = (keys) ->
 392   for index in [0...keys.length] by 1
 393     str = keys[index..].join(',')
 394     for command in commands
 395       for key in command.keys()
 396         # The following hack is a workaround for the issue where letter `c` is
 397         # considered a start of command with control modifier `c-xxx`.
 398         if "#{ key },".startsWith("#{ str },")
 399           return {match: true, exact: (key == str), command}
 400
 401   return {match: false}
 402
 403 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 404
 405 exports.commands                  = commands
 406 exports.searchForMatchingCommand  = searchForMatchingCommand
 407 exports.isEscCommandKey           = isEscCommandKey
 408 exports.findStorage               = findStorage