extension/lib/hints.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file contains functions for getting markable elements, and related data,
  22 # as well as for creating and inserting markers for markable elements.
  23
  24 huffman  = require('n-ary-huffman')
  25 {Marker} = require('./marker')
  26 utils    = require('./utils')
  27
  28 {devtools} = Cu.import('resource://devtools/shared/Loader.jsm', {})
  29
  30 CONTAINER_ID = 'VimFxMarkersContainer'
  31
  32 Element     = Ci.nsIDOMElement
  33 XULDocument = Ci.nsIDOMXULDocument
  34
  35 # For some time we used to return the hints container from `injectHints`, and
  36 # use that reference to remove the hints when needed. That’s fine in theory, but
  37 # in case anything breaks we might loose that reference and end up with
  38 # unremovable hints on the screen. Explicitly looking for an element with the
  39 # container ID is more fail-safe.
  40 removeHints = (window) ->
  41   window.document.getElementById(CONTAINER_ID)?.remove()
  42
  43 # Create `Marker`s for every element (represented by a regular object of data
  44 # about the element—a “wrapper,” a stand-in for the real element, which is only
  45 # accessible in frame scripts) in `wrappers`, and insert them into `window`.
  46 injectHints = (window, wrappers, viewport, options) ->
  47   semantic   = []
  48   unsemantic = []
  49   combined   = []
  50   markerMap  = {}
  51
  52   for wrapper in wrappers
  53     marker = new Marker(wrapper, window.document)
  54     group = switch
  55       when wrapper.parentIndex? then combined
  56       when wrapper.semantic     then semantic
  57       else unsemantic
  58     group.push(marker)
  59     markerMap[wrapper.elementIndex] = marker
  60
  61   markers = semantic.concat(unsemantic)
  62
  63   # Each marker gets a unique `z-index`, so that it can be determined if a
  64   # marker overlaps another. Put more important markers (higher weight) at the
  65   # end, so that they get higher `z-index`, in order not to be overlapped.
  66   zIndex = 0
  67   setZIndexes = (markers) ->
  68     markers.sort((a, b) -> a.weight - b.weight)
  69     for marker in markers when marker not instanceof huffman.BranchPoint
  70       marker.markerElement.style.zIndex = zIndex++
  71       # Add `z-index` space for all the children of the marker.
  72       zIndex += marker.wrapper.numChildren if marker.wrapper.numChildren?
  73     return
  74
  75   # The `markers` passed to this function have been sorted by `setZIndexes` in
  76   # advance, so we can skip sorting in the `huffman.createTree` function.
  77   hintChars = options.hint_chars
  78   createHuffmanTree = (markers) ->
  79     return huffman.createTree(markers, hintChars.length, {sorted: true})
  80
  81   # Semantic elements should always get better hints and higher `z-index`:es
  82   # than unsemantic ones, even if they are smaller. The former is achieved by
  83   # putting the unsemantic elements in their own branch of the huffman tree.
  84   if unsemantic.length > 0
  85     if markers.length > hintChars.length
  86       setZIndexes(unsemantic)
  87       subTree = createHuffmanTree(unsemantic)
  88       semantic.push(subTree)
  89     else
  90       semantic.push(unsemantic...)
  91
  92   setZIndexes(semantic)
  93
  94   tree = createHuffmanTree(semantic)
  95   tree.assignCodeWords(hintChars, (marker, hint) -> marker.setHint(hint))
  96
  97   # Markers for links with the same href can be combined to use the same hint.
  98   # They should all have the same `z-index` (because they all have the same
  99   # combined weight), but in case any of them cover another they still get a
 100   # unique `z-index` (space for this was added in `setZIndexes`).
 101   for marker in combined
 102     parent = markerMap[marker.wrapper.parentIndex]
 103     marker.markerElement.style.zIndex = parent.markerElement.style.zIndex++
 104     marker.setHint(parent.hint)
 105   markers.push(combined...)
 106
 107   removeHints(window) # Better safe than sorry.
 108   container = window.document.createElement('box')
 109   container.id = CONTAINER_ID
 110
 111   zoom = 1
 112
 113   if options.ui
 114     container.classList.add('ui')
 115     window.document.getElementById('browser-panel').appendChild(container)
 116   else
 117     {ZoomManager, gBrowser: {selectedBrowser: browser}} = window
 118     browser.parentNode.appendChild(container)
 119     # If “full zoom” is not used, it means that “Zoom text only” is enabled.
 120     # If so, that “zoom” does not need to be taken into account.
 121     # `.getCurrentMode()` is added by the “Default FullZoom Level” extension.
 122     if ZoomManager.getCurrentMode?(browser) ? ZoomManager.useFullZoom
 123       zoom = ZoomManager.getZoomForBrowser(browser)
 124
 125   for marker in markers
 126     container.appendChild(marker.markerElement)
 127     # Must be done after the hints have been inserted into the DOM (see
 128     # marker.coffee).
 129     marker.setPosition(viewport, zoom)
 130
 131   return {markers, markerMap}
 132
 133 getMarkableElementsAndViewport = (window, filter) ->
 134   {
 135     clientWidth, clientHeight # Viewport size excluding scrollbars, usually.
 136     scrollWidth, scrollHeight
 137   } = window.document.documentElement
 138   {innerWidth, innerHeight} = window # Viewport size including scrollbars.
 139   # We don’t want markers to cover the scrollbars, so we should use
 140   # `clientWidth` and `clientHeight`. However, when there are no scrollbars
 141   # those might be too small. Then we use `innerWidth` and `innerHeight`.
 142   width  = if scrollWidth  > innerWidth  then clientWidth  else innerWidth
 143   height = if scrollHeight > innerHeight then clientHeight else innerHeight
 144   viewport = {
 145     left:   0
 146     top:    0
 147     right:  width
 148     bottom: height
 149     width
 150     height
 151   }
 152
 153   wrappers = []
 154   getMarkableElements(window, viewport, wrappers, filter)
 155   return {wrappers, viewport}
 156
 157 # `filter` is a function that is given every element in every frame of the page.
 158 # It should return wrapper objects for markable elements and a falsy value for
 159 # all other elements. All returned wrappers are added to `wrappers`. `wrappers`
 160 # is modified instead of using return values to avoid array concatenation for
 161 # each frame. It might sound expensive to go through _every_ element, but that’s
 162 # actually what other methods like using XPath or CSS selectors would need to do
 163 # anyway behind the scenes.
 164 getMarkableElements = (window, viewport, wrappers, filter, parents = []) ->
 165   {document} = window
 166
 167   for element in getAllElements(document) when element instanceof Element
 168     # `getRects` is fast and filters out most elements, so run it first of all.
 169     rects = getRects(element, viewport)
 170     continue unless rects.length > 0
 171     continue unless wrapper = filter(
 172       element, (elementArg) ->
 173         return getElementShape(window, viewport, parents, elementArg,
 174                                if elementArg == element then rects else null)
 175     )
 176     wrappers.push(wrapper)
 177
 178   for frame in window.frames when frame.frameElement
 179     rect = frame.frameElement.getBoundingClientRect() # Frames only have one.
 180     continue unless isInsideViewport(rect, viewport)
 181
 182     # Calculate the visible part of the frame, according to the parent.
 183     {clientWidth, clientHeight} = frame.document.documentElement
 184     frameViewport =
 185       left:   Math.max(viewport.left - rect.left, 0)
 186       top:    Math.max(viewport.top  - rect.top,  0)
 187       right:  clientWidth  + Math.min(viewport.right  - rect.right,  0)
 188       bottom: clientHeight + Math.min(viewport.bottom - rect.bottom, 0)
 189
 190     # `.getComputedStyle()` may return `null` if the computed style isn’t
 191     # availble yet. If so, consider the element not visible.
 192     continue unless computedStyle = window.getComputedStyle(frame.frameElement)
 193     offset =
 194       left: rect.left +
 195         parseFloat(computedStyle.getPropertyValue('border-left-width')) +
 196         parseFloat(computedStyle.getPropertyValue('padding-left'))
 197       top: rect.top +
 198         parseFloat(computedStyle.getPropertyValue('border-top-width')) +
 199         parseFloat(computedStyle.getPropertyValue('padding-top'))
 200
 201     getMarkableElements(frame, frameViewport, wrappers, filter,
 202                         parents.concat({window, offset}))
 203
 204   return
 205
 206 getAllElements = (document) ->
 207   unless document instanceof XULDocument
 208     return document.getElementsByTagName('*')
 209
 210   # Use a `Set` since this algorithm may find the same element more than once.
 211   # Ideally we should find a way to find all elements without duplicates.
 212   elements = new Set()
 213   getAllRegular = (element) ->
 214     # The first time `zF` is run `.getElementsByTagName('*')` may oddly include
 215     # `undefined` in its result! Filter those out.
 216     for child in element.getElementsByTagName('*') when child
 217       elements.add(child)
 218       getAllAnonymous(child)
 219     return
 220   getAllAnonymous = (element) ->
 221     for child in document.getAnonymousNodes(element) or []
 222       continue unless child instanceof Element
 223       elements.add(child)
 224       getAllRegular(child)
 225     return
 226   getAllRegular(document.documentElement)
 227   return Array.from(elements)
 228
 229 getRects = (element, viewport) ->
 230   # `element.getClientRects()` returns a list of rectangles, usually just one,
 231   # which is identical to the one returned by `element.getBoundingClientRect()`.
 232   # However, if `element` is inline and line-wrapped, then it returns one
 233   # rectangle for each line, since each line may be of different length, for
 234   # example. That allows us to properly add hints to line-wrapped links.
 235   return Array.filter(
 236     element.getClientRects(), (rect) -> isInsideViewport(viewport, rect)
 237   )
 238
 239 # Returns the “shape” of `element`:
 240 #
 241 # - `nonCoveredPoint`: The coordinates of the first point of `element` that
 242 #   isn’t covered by another element (except children of `element`). It also
 243 #   contains the offset needed to make those coordinates relative to the top
 244 #   frame, as well as the rectangle that the coordinates occur in.
 245 # - `area`: The area of the part of `element` that is inside `viewport`.
 246 #
 247 # Returns `null` if `element` is outside `viewport` or entirely covered by other
 248 # elements.
 249 getElementShape = (window, viewport, parents, element, rects = null) ->
 250   rects ?= getRects(element, viewport)
 251   totalArea = 0
 252   visibleRects = []
 253   for rect in rects
 254     visibleRect = adjustRectToViewport(rect, viewport)
 255     continue if visibleRect.area == 0
 256     totalArea += visibleRect.area
 257     visibleRects.push(visibleRect)
 258
 259   if visibleRects.length == 0
 260     if rects.length == 1 and totalArea == 0
 261       [rect] = rects
 262       if rect.width > 0 or rect.height > 0
 263         # If we get here, it means that everything inside `element` is floated
 264         # and/or absolutely positioned (and that `element` hasn’t been made to
 265         # “contain” the floats). For example, a link in a menu could contain a
 266         # span of text floated to the left and an icon floated to the right.
 267         # Those are still clickable. Therefore we return the shape of the first
 268         # visible child instead. At least in that example, that’s the best bet.
 269         for child in element.children
 270           shape = getElementShape(window, viewport, parents, child)
 271           return shape if shape
 272     return null
 273
 274   # Even if `element` has a visible rect, it might be covered by other elements.
 275   for visibleRect in visibleRects
 276     nonCoveredPoint = getFirstNonCoveredPoint(window, viewport, element,
 277                                               visibleRect, parents)
 278     break if nonCoveredPoint
 279
 280   return null unless nonCoveredPoint
 281
 282   return {
 283     nonCoveredPoint, area: totalArea
 284   }
 285
 286 MINIMUM_EDGE_DISTANCE = 4
 287 isInsideViewport = (rect, viewport) ->
 288   return \
 289     rect.left   <= viewport.right  - MINIMUM_EDGE_DISTANCE and
 290     rect.top    <= viewport.bottom + MINIMUM_EDGE_DISTANCE and
 291     rect.right  >= viewport.left   + MINIMUM_EDGE_DISTANCE and
 292     rect.bottom >= viewport.top    - MINIMUM_EDGE_DISTANCE
 293
 294 adjustRectToViewport = (rect, viewport) ->
 295   # The right and bottom values are subtracted by 1 because
 296   # `document.elementFromPoint(right, bottom)` does not return the element
 297   # otherwise.
 298   left   = Math.max(rect.left,       viewport.left)
 299   right  = Math.min(rect.right - 1,  viewport.right)
 300   top    = Math.max(rect.top,        viewport.top)
 301   bottom = Math.min(rect.bottom - 1, viewport.bottom)
 302
 303   # Make sure that `right >= left and bottom >= top`, since we subtracted by 1
 304   # above.
 305   right  = Math.max(right, left)
 306   bottom = Math.max(bottom, top)
 307
 308   width  = right - left
 309   height = bottom - top
 310   area   = Math.floor(width * height)
 311
 312   return {
 313     left, right, top, bottom
 314     height, width, area
 315   }
 316
 317 getFirstNonCoveredPoint = (window, viewport, element, elementRect, parents) ->
 318   # Tries a point `(x + dx, y + dy)`. Returns `(x, y)` (and the frame offset)
 319   # if it passes the tests. Otherwise it tries to the right of whatever is at
 320   # `(x, y)`, `tryRight` times . If nothing succeeds, `false` is returned. `dx`
 321   # and `dy` are used to offset the wanted point `(x, y)` while trying (see the
 322   # invocations of `tryPoint` below).
 323   tryPoint = (x, dx, y, dy, tryRight = 0) ->
 324     elementAtPoint = window.document.elementFromPoint(x + dx, y + dy)
 325     offset = {left: 0, top: 0}
 326     found = false
 327
 328     # Ensure that `element`, or a child of `element` (anything inside an `<a>`
 329     # is clickable too), really is present at (x,y). Note that this is not 100%
 330     # bullet proof: Combinations of CSS can cause this check to fail, even
 331     # though `element` isn’t covered. We don’t try to temporarily reset such CSS
 332     # because of performance. Instead we rely on that some of the attempts below
 333     # will work.
 334     if contains(element, elementAtPoint)
 335       found = true
 336       # If we’re currently in a frame, there might be something on top of the
 337       # frame that covers `element`. Therefore we ensure that the frame really
 338       # is present at the point for each parent in `parents`.
 339       currentWindow = window
 340       for parent in parents by -1
 341         # If leaving the devtools container take the devtools zoom into account.
 342         if currentWindow.DevTools and not parent.window.DevTools
 343           toolbox = window.gDevTools.getToolbox(
 344             devtools.TargetFactory.forTab(window.top.gBrowser.selectedTab)
 345           )
 346           if toolbox
 347             devtoolsZoom = toolbox.zoomValue
 348             offset.left *= devtoolsZoom
 349             offset.top  *= devtoolsZoom
 350             x  *= devtoolsZoom
 351             y  *= devtoolsZoom
 352             dx *= devtoolsZoom
 353             dy *= devtoolsZoom
 354
 355         offset.left += parent.offset.left
 356         offset.top  += parent.offset.top
 357         elementAtPoint = parent.window.document.elementFromPoint(
 358           offset.left + x + dx, offset.top + y + dy
 359         )
 360         unless contains(currentWindow.frameElement, elementAtPoint)
 361           found = false
 362           break
 363         currentWindow = parent.window
 364
 365     if found
 366       return {x, y, offset}
 367     else
 368       return false if elementAtPoint == null or tryRight == 0
 369       rect = elementAtPoint.getBoundingClientRect()
 370       x = rect.right - offset.left + 1
 371       return false if x > viewport.right
 372       return tryPoint(x, 0, y, 0, tryRight - 1)
 373
 374
 375   # Try the left-middle point, or immediately to the right of a covering element
 376   # at that point. If both of those are covered the whole element is considered
 377   # to be covered. The reasoning is:
 378   #
 379   # - A marker should show up as near the left edge of its visible area as
 380   #   possible. Having it appear to the far right (for example) is confusing.
 381   # - We can’t try too many times because of performance.
 382   # - We used to try left-top first, but if `element` has `border-radius`, the
 383   #   corners won’t really belong to `element`, so `document.elementFromPoint()`
 384   #   will return whatever is behind. This will result in missing or
 385   #   out-of-place markers. The solution is to temporarily add a CSS class that
 386   #   removes `border-radius`, but that turned out to be rather slow, making it
 387   #   not worth it. Usually you don’t see the difference between left-top and
 388   #   left-middle, because links are usually not that high.
 389   # - We used to try left-bottom as well, but that is so rare that it’s not
 390   #   worth it.
 391   #
 392   # It is safer to try points at least one pixel into the element from the
 393   # edges, hence the `+1`.
 394   {left, top, bottom, height} = elementRect
 395   nonCoveredPoint = tryPoint(left, +1, Math.floor(top + height / 2), 0, 1)
 396
 397   return nonCoveredPoint
 398
 399 # In XUL documents there are “anonymous” elements. These are never returned by
 400 # `document.elementFromPoint` but their closest non-anonymous parents are.
 401 normalize = (element) ->
 402   normalized = element.ownerDocument.getBindingParent(element) or element
 403   normalized = normalized.parentNode while normalized.prefix?
 404   return normalized
 405
 406 # Returns whether `element` corresponds to `elementAtPoint`. This is only
 407 # complicated for browser elements in the web page content area.
 408 # `.elementAtPoint()` always returns `<tabbrowser#content>` then. The element
 409 # might be in another tab and thus invisible, but `<tabbrowser#content>` is the
 410 # same and visible in _all_ tabs, so we have to check that the element really
 411 # belongs to the current tab.
 412 contains = (element, elementAtPoint) ->
 413   return false unless elementAtPoint
 414   container = normalize(element)
 415   if elementAtPoint.nodeName == 'tabbrowser' and elementAtPoint.id == 'content'
 416     {gBrowser} = element.ownerGlobal.top
 417     tabpanel = gBrowser.getNotificationBox(gBrowser.selectedBrowser)
 418     return tabpanel.contains(element)
 419   else
 420     # Note that `a.contains(a)` is supposed to be true, but strangely aren’t for
 421     # `<menulist>`s in the Add-ons Manager, so do a direct comparison as well.
 422     return container == elementAtPoint or container.contains(elementAtPoint)
 423
 424 module.exports = {
 425   removeHints
 426   injectHints
 427   getMarkableElementsAndViewport
 428 }