extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet } = require 'prefs'
   8
   9 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  10
  11 # “Selecting an element” means “focusing and selecting the text, if any, of an
  12 # element”.
  13
  14 # Select the Address Bar.
  15 command_focus = (vim) ->
  16   # This function works even if the Address Bar has been removed.
  17   vim.rootWindow.focusAndSelectUrlBar()
  18
  19 # Select the Search Bar.
  20 command_focus_search = (vim) ->
  21   # The `.webSearch()` method opens a search engine in a tab if the Search Bar
  22   # has been removed. Therefore we first check if it exists.
  23   if vim.rootWindow.BrowserSearch.searchBar
  24     vim.rootWindow.BrowserSearch.webSearch()
  25
  26 helper_paste = (vim) ->
  27   url = utils.readFromClipboard(vim.window)
  28   postData = null
  29   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  30     url = submission.uri.spec
  31     { postData } = submission
  32   return {url, postData}
  33
  34 # Go to or search for the contents of the system clipboard.
  35 command_paste = (vim) ->
  36   { url, postData } = helper_paste(vim)
  37   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  38
  39 # Go to or search for the contents of the system clipboard in a new tab.
  40 command_paste_tab = (vim) ->
  41   { url, postData } = helper_paste(vim)
  42   vim.rootWindow.gBrowser.selectedTab =
  43     vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  44
  45 # Copy the URL or text of a marker element to the system clipboard.
  46 command_marker_yank = (vim) ->
  47   callback = (marker) ->
  48     if url = marker.element.href
  49       marker.element.focus()
  50       utils.writeToClipboard(url)
  51     else if utils.isTextInputElement(marker.element)
  52       utils.writeToClipboard(marker.element.value)
  53
  54   vim.enterMode('hints', callback)
  55
  56 # Focus element.
  57 command_marker_focus = (vim) ->
  58   callback = (marker) -> marker.element.focus()
  59
  60   vim.enterMode('hints', callback)
  61
  62 # Copy the current URL to the system clipboard.
  63 command_yank = (vim) ->
  64   utils.writeToClipboard(vim.window.location.href)
  65
  66 # Reload the current tab, possibly from cache.
  67 command_reload = (vim) ->
  68   vim.rootWindow.BrowserReload()
  69
  70 # Reload the current tab, skipping cache.
  71 command_reload_force = (vim) ->
  72   vim.rootWindow.BrowserReloadSkipCache()
  73
  74 # Reload all tabs, possibly from cache.
  75 command_reload_all = (vim) ->
  76   vim.rootWindow.gBrowser.reloadAllTabs()
  77
  78 # Reload all tabs, skipping cache.
  79 command_reload_all_force = (vim) ->
  80   for tab in vim.rootWindow.gBrowser.visibleTabs
  81     window = tab.linkedBrowser.contentWindow
  82     window.location.reload(true)
  83
  84 # Stop loading the current tab.
  85 command_stop = (vim) ->
  86   vim.window.stop()
  87
  88 # Stop loading all tabs.
  89 command_stop_all = (vim) ->
  90   for tab in vim.rootWindow.gBrowser.visibleTabs
  91     window = tab.linkedBrowser.contentWindow
  92     window.stop()
  93
  94 # Scroll to the top of the page.
  95 command_scroll_to_top = (vim) ->
  96   vim.rootWindow.goDoCommand('cmd_scrollTop')
  97
  98 # Scroll to the bottom of the page.
  99 command_scroll_to_bottom = (vim) ->
 100   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 101
 102 # Scroll down a bit.
 103 command_scroll_down = (vim, event, count) ->
 104   step = getPref('scroll_step_lines') * count
 105   utils.simulateWheel(vim.window, 0, +step, utils.WHEEL_MODE_LINE)
 106
 107 # Scroll up a bit.
 108 command_scroll_up = (vim, event, count) ->
 109   step = getPref('scroll_step_lines') * count
 110   utils.simulateWheel(vim.window, 0, -step, utils.WHEEL_MODE_LINE)
 111
 112 # Scroll left a bit.
 113 command_scroll_left = (vim, event, count) ->
 114   step = getPref('scroll_step_lines') * count
 115   utils.simulateWheel(vim.window, -step, 0, utils.WHEEL_MODE_LINE)
 116
 117 # Scroll right a bit.
 118 command_scroll_right = (vim, event, count) ->
 119   step = getPref('scroll_step_lines') * count
 120   utils.simulateWheel(vim.window, +step, 0, utils.WHEEL_MODE_LINE)
 121
 122 # Scroll down half a page.
 123 command_scroll_half_page_down = (vim, event, count) ->
 124   utils.simulateWheel(vim.window, 0, +0.5 * count, utils.WHEEL_MODE_PAGE)
 125
 126 # Scroll up half a page.
 127 command_scroll_half_page_up = (vim, event, count) ->
 128   utils.simulateWheel(vim.window, 0, -0.5 * count, utils.WHEEL_MODE_PAGE)
 129
 130 # Scroll down full a page.
 131 command_scroll_page_down = (vim, event, count) ->
 132   utils.simulateWheel(vim.window, 0, +1 * count, utils.WHEEL_MODE_PAGE)
 133
 134 # Scroll up full a page.
 135 command_scroll_page_up = (vim, event, count) ->
 136   utils.simulateWheel(vim.window, 0, -1 * count, utils.WHEEL_MODE_PAGE)
 137
 138 # Open a new tab and select the Address Bar.
 139 command_open_tab = (vim) ->
 140   vim.rootWindow.BrowserOpenTab()
 141
 142 absoluteTabIndex = (relativeIndex, gBrowser) ->
 143   tabs = gBrowser.visibleTabs
 144   { selectedTab } = gBrowser
 145
 146   currentIndex  = tabs.indexOf(selectedTab)
 147   absoluteIndex = currentIndex + relativeIndex
 148   numTabs       = tabs.length
 149
 150   wrap = (Math.abs(relativeIndex) == 1)
 151   if wrap
 152     absoluteIndex %%= numTabs
 153   else
 154     absoluteIndex = Math.max(0, absoluteIndex)
 155     absoluteIndex = Math.min(absoluteIndex, numTabs - 1)
 156
 157   return absoluteIndex
 158
 159 helper_switch_tab = (direction, vim, event, count) ->
 160   { gBrowser } = vim.rootWindow
 161   gBrowser.selectTabAtIndex(absoluteTabIndex(direction * count, gBrowser))
 162
 163 # Switch to the previous tab.
 164 command_tab_prev = helper_switch_tab.bind(undefined, -1)
 165
 166 # Switch to the next tab.
 167 command_tab_next = helper_switch_tab.bind(undefined, +1)
 168
 169 helper_move_tab = (direction, vim, event, count) ->
 170   { gBrowser }    = vim.rootWindow
 171   { selectedTab } = gBrowser
 172   { pinned }      = selectedTab
 173
 174   index = absoluteTabIndex(direction * count, gBrowser)
 175
 176   if index < gBrowser._numPinnedTabs
 177     gBrowser.pinTab(selectedTab) unless pinned
 178   else
 179     gBrowser.unpinTab(selectedTab) if pinned
 180
 181   gBrowser.moveTabTo(selectedTab, index)
 182
 183 # Move the current tab backward.
 184 command_tab_move_left = helper_move_tab.bind(undefined, -1)
 185
 186 # Move the current tab forward.
 187 command_tab_move_right = helper_move_tab.bind(undefined, +1)
 188
 189 # Load the home page.
 190 command_home = (vim) ->
 191   vim.rootWindow.BrowserHome()
 192
 193 # Switch to the first tab.
 194 command_tab_first = (vim) ->
 195   vim.rootWindow.gBrowser.selectTabAtIndex(0)
 196
 197 # Switch to the last tab.
 198 command_tab_last = (vim) ->
 199   vim.rootWindow.gBrowser.selectTabAtIndex(-1)
 200
 201 # Close current tab.
 202 command_close_tab = (vim) ->
 203   unless vim.rootWindow.gBrowser.selectedTab.pinned
 204     vim.rootWindow.gBrowser.removeCurrentTab()
 205
 206 # Restore last closed tab.
 207 command_restore_tab = (vim) ->
 208   vim.rootWindow.undoCloseTab()
 209
 210 helper_follow = ({ inTab, multiple }, vim) ->
 211   callback = (matchedMarker, markers) ->
 212     if matchedMarker.element.target == '_blank'
 213       targetReset = matchedMarker.element.target
 214       matchedMarker.element.target = ''
 215
 216     matchedMarker.element.focus()
 217     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 218
 219     matchedMarker.element.target = targetReset if targetReset
 220
 221     isEditable = utils.isElementEditable(matchedMarker.element)
 222     if multiple and not isEditable
 223       # By not resetting immediately one is able to see the last char being
 224       # matched, which gives some nice visual feedback that you've typed the
 225       # right char.
 226       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 227       return true
 228
 229   vim.enterMode('hints', callback)
 230
 231 # Follow links with hint markers.
 232 command_follow = helper_follow.bind(undefined, {inTab: false})
 233
 234 # Follow links in a new Tab with hint markers.
 235 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 236
 237 # Follow multiple links with hint markers.
 238 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 239
 240 helper_follow_pattern = do ->
 241   # Search for the prev/next patterns in the following attributes of the
 242   # element. `rel` should be kept as the first attribute, since the standard
 243   # way of marking up prev/next links (`rel="prev"` and `rel="next"`) should be
 244   # favored. Even though some of these attributes only allow a fixed set of
 245   # keywords, we pattern-match them anyways since lots of sites don’t follow
 246   # the spec and use the attributes arbitrarily.
 247   attrs = ['rel', 'role', 'data-tooltip', 'aria-label']
 248
 249   return (type, vim) ->
 250     links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 251       .filter(utils.isElementVisible)
 252
 253     patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 254
 255     if matchingLink = utils.getBestPatternMatch(patterns, attrs, links)
 256       utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 257
 258 # Follow previous page.
 259 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 260
 261 # Follow next page.
 262 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 263
 264 # Go up one level in the URL hierarchy.
 265 command_go_up_path = (vim) ->
 266   path = vim.window.location.pathname
 267   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 268
 269 # Go up to root of the URL hierarchy.
 270 command_go_to_root = (vim) ->
 271   vim.window.location.href = vim.window.location.origin
 272
 273 # Go back in history.
 274 command_back = (vim) ->
 275   vim.rootWindow.BrowserBack()
 276
 277 # Go forward in history.
 278 command_forward = (vim) ->
 279   vim.rootWindow.BrowserForward()
 280
 281 findStorage = {lastSearchString: ''}
 282
 283 helper_find = (highlight, vim) ->
 284   findBar = vim.rootWindow.gBrowser.getFindBar()
 285
 286   findBar.onFindCommand()
 287   findBar._findField.focus()
 288   findBar._findField.select()
 289
 290   return unless highlightButton = findBar.getElement('highlight')
 291   if highlightButton.checked != highlight
 292     highlightButton.click()
 293
 294 # Open the find bar, making sure that hightlighting is off.
 295 command_find = helper_find.bind(undefined, false)
 296
 297 # Open the find bar, making sure that hightlighting is on.
 298 command_find_hl = helper_find.bind(undefined, true)
 299
 300 helper_find_again = (direction, vim) ->
 301   findBar = vim.rootWindow.gBrowser.getFindBar()
 302   if findStorage.lastSearchString.length > 0
 303     findBar._findField.value = findStorage.lastSearchString
 304     findBar.onFindAgainCommand(direction)
 305
 306 # Search for the last pattern.
 307 command_find_next = helper_find_again.bind(undefined, false)
 308
 309 # Search for the last pattern backwards.
 310 command_find_prev = helper_find_again.bind(undefined, true)
 311
 312 # Enter insert mode.
 313 command_insert_mode = (vim) ->
 314   vim.enterMode('insert')
 315
 316 # Display the Help Dialog.
 317 command_help = (vim) ->
 318   help.injectHelp(vim.window.document, commands)
 319
 320 # Open and select the Developer Toolbar.
 321 command_dev = (vim) ->
 322   vim.rootWindow.DeveloperToolbar.show(true) # focus
 323
 324 command_Esc = (vim, event) ->
 325   utils.blurActiveElement(vim.window)
 326
 327   # Blur active XUL control.
 328   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 329   vim.window.setTimeout(callback, 0)
 330
 331   help.removeHelp(vim.window.document)
 332
 333   vim.rootWindow.DeveloperToolbar.hide()
 334
 335   vim.rootWindow.gBrowser.getFindBar().close()
 336
 337   vim.rootWindow.TabView.hide()
 338
 339
 340 class Command
 341   constructor: (@group, @name, @func, keys) ->
 342     @defaultKeys = keys
 343     if isPrefSet(@prefName('keys'))
 344       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 345     else
 346       @keyValues = keys
 347
 348   # Name of the preference for a given property.
 349   prefName: (value) -> "commands.#{ @name }.#{ value }"
 350
 351   keys: (value) ->
 352     if value is undefined
 353       return @keyValues
 354     else
 355       @keyValues = value or @defaultKeyValues
 356       setPref(@prefName('keys'), value and JSON.stringify(value))
 357
 358   help: -> _("help_command_#{ @name }")
 359
 360 commands = [
 361   new Command('urls',   'focus',                 command_focus,                 ['o'])
 362   new Command('urls',   'focus_search',          command_focus_search,          ['O'])
 363   new Command('urls',   'paste',                 command_paste,                 ['p'])
 364   new Command('urls',   'paste_tab',             command_paste_tab,             ['P'])
 365   new Command('urls',   'marker_yank',           command_marker_yank,           ['y,f'])
 366   new Command('urls',   'marker_focus',          command_marker_focus,          ['v,f'])
 367   new Command('urls',   'yank',                  command_yank,                  ['y,y'])
 368   new Command('urls',   'reload',                command_reload,                ['r'])
 369   new Command('urls',   'reload_force',          command_reload_force,          ['R'])
 370   new Command('urls',   'reload_all',            command_reload_all,            ['a,r'])
 371   new Command('urls',   'reload_all_force',      command_reload_all_force,      ['a,R'])
 372   new Command('urls',   'stop',                  command_stop,                  ['s'])
 373   new Command('urls',   'stop_all',              command_stop_all,              ['a,s'])
 374
 375   new Command('nav',    'scroll_to_top',         command_scroll_to_top ,        ['g,g'])
 376   new Command('nav',    'scroll_to_bottom',      command_scroll_to_bottom,      ['G'])
 377   new Command('nav',    'scroll_down',           command_scroll_down,           ['j', 'c-e'])
 378   new Command('nav',    'scroll_up',             command_scroll_up,             ['k', 'c-y'])
 379   new Command('nav',    'scroll_left',           command_scroll_left,           ['h'])
 380   new Command('nav',    'scroll_right',          command_scroll_right ,         ['l'])
 381   new Command('nav',    'scroll_half_page_down', command_scroll_half_page_down, ['d'])
 382   new Command('nav',    'scroll_half_page_up',   command_scroll_half_page_up,   ['u'])
 383   new Command('nav',    'scroll_page_down',      command_scroll_page_down,      ['c-f'])
 384   new Command('nav',    'scroll_page_up',        command_scroll_page_up,        ['c-b'])
 385
 386   new Command('tabs',   'open_tab',              command_open_tab,              ['t'])
 387   new Command('tabs',   'tab_prev',              command_tab_prev,              ['J', 'g,T'])
 388   new Command('tabs',   'tab_next',              command_tab_next,              ['K', 'g,t'])
 389   new Command('tabs',   'tab_move_left',         command_tab_move_left,         ['c-J'])
 390   new Command('tabs',   'tab_move_right',        command_tab_move_right,        ['c-K'])
 391   new Command('tabs',   'home',                  command_home,                  ['g,h'])
 392   new Command('tabs',   'tab_first',             command_tab_first,             ['g,H', 'g,^'])
 393   new Command('tabs',   'tab_last',              command_tab_last,              ['g,L', 'g,$'])
 394   new Command('tabs',   'close_tab',             command_close_tab,             ['x'])
 395   new Command('tabs',   'restore_tab',           command_restore_tab,           ['X'])
 396
 397   new Command('browse', 'follow',                command_follow,                ['f'])
 398   new Command('browse', 'follow_in_tab',         command_follow_in_tab,         ['F'])
 399   new Command('browse', 'follow_multiple',       command_follow_multiple,       ['a,f'])
 400   new Command('browse', 'follow_previous',       command_follow_prev,           ['['])
 401   new Command('browse', 'follow_next',           command_follow_next,           [']'])
 402   new Command('browse', 'go_up_path',            command_go_up_path,            ['g,u'])
 403   new Command('browse', 'go_to_root',            command_go_to_root,            ['g,U'])
 404   new Command('browse', 'back',                  command_back,                  ['H'])
 405   new Command('browse', 'forward',               command_forward,               ['L'])
 406
 407   new Command('misc',   'find',                  command_find,                  ['/'])
 408   new Command('misc',   'find_hl',               command_find_hl,               ['a,/'])
 409   new Command('misc',   'find_next',             command_find_next,             ['n'])
 410   new Command('misc',   'find_prev',             command_find_prev,             ['N'])
 411   new Command('misc',   'insert_mode',           command_insert_mode,           ['i'])
 412   new Command('misc',   'help',                  command_help,                  ['?'])
 413   new Command('misc',   'dev',                   command_dev,                   [':'])
 414
 415   escapeCommand =
 416   new Command('misc',   'Esc',                   command_Esc,                   ['Esc'])
 417 ]
 418
 419 searchForMatchingCommand = (keys) ->
 420   for index in [0...keys.length] by 1
 421     str = keys[index..].join(',')
 422     for command in commands
 423       for key in command.keys()
 424         # The following hack is a workaround for the issue where letter `c` is
 425         # considered a start of command with control modifier `c-xxx`.
 426         if "#{ key },".startsWith("#{ str },")
 427           numbers = keys[0..index].join('').match(/[1-9]\d*/g)
 428
 429           # When letter `0` follows after a number, it is considered as number `0`
 430           # instead of a valid command.
 431           continue if key == '0' and numbers
 432
 433           count = parseInt(numbers[numbers.length - 1], 10) if numbers
 434           count = if count > 1 then count else 1
 435
 436           return {match: true, exact: (key == str), command, count}
 437
 438   return {match: false}
 439
 440 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 441
 442 exports.commands                  = commands
 443 exports.searchForMatchingCommand  = searchForMatchingCommand
 444 exports.isEscCommandKey           = isEscCommandKey
 445 exports.findStorage               = findStorage