extension/bootstrap.coffee

   1 ###
   2 # Copyright Anton Khodakivskiy 2012, 2013, 2014.
   3 # Copyright Simon Lydell 2013, 2014, 2015.
   4 #
   5 # This file is part of VimFx.
   6 #
   7 # VimFx is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # VimFx is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with VimFx.  If not, see <http://www.gnu.org/licenses/>.
  19 ###
  20
  21 # This file boots the main VimFx process, as well as each frame script. It tries
  22 # to do the minimum amount of things to run main.coffee, or main-frame.coffee
  23 # for frame scripts. It defines a few global variables, and sets up a
  24 # Node.js-style `require` module loader.
  25
  26 # `bootstrap.js` files of different add-ons do _not_ share scope. However, frame
  27 # scripts for the same `<browser>` but from different add-ons _do_ share scope.
  28 # In order not to pollute that global scope in frame scripts, everything is done
  29 # in an IIFE here, and the `global` variable is handled with care.
  30
  31 do (global = this) ->
  32
  33   {classes: Cc, interfaces: Ci, utils: Cu} = Components
  34   IS_FRAME_SCRIPT = (typeof content != 'undefined')
  35
  36   if IS_FRAME_SCRIPT
  37     # Tell the main process that this frame script was created, and get data
  38     # back that only the main process has access to.
  39     [data] = sendSyncMessage('VimFx:tabCreated')
  40
  41     # The main process told this frame script not to do anything (or there was
  42     # an error and no message was received at all).
  43     return unless data
  44
  45     FRAME_SCRIPT_ENVIRONMENT = global
  46     global = {}
  47     [global.__SCRIPT_URI_SPEC__] = data
  48
  49   else
  50     # Make `Services` and `console` available globally, just like they are in
  51     # frame scripts by default.
  52     Cu.import('resource://gre/modules/Services.jsm')
  53     try
  54       # TODO: Only use this path when Firefox 44 is released.
  55       Cu.import('resource://gre/modules/Console.jsm')
  56     catch
  57       Cu.import('resource://gre/modules/devtools/Console.jsm')
  58
  59
  60     FRAME_SCRIPT_ENVIRONMENT = null
  61
  62   shutdownHandlers = []
  63
  64   createURI = (path, base = null) -> Services.io.newURI(path, null, base)
  65   baseURI   = createURI(global.__SCRIPT_URI_SPEC__)
  66
  67   # Everything up to the first `!` is the absolute path to the .xpi.
  68   dirname = (uri) -> uri.match(///^ [^!]+!/ (.+) /[^/]+ $///)[1]
  69
  70   require = (path, moduleRoot = '.', dir = '.') ->
  71     unless path[0] == '.'
  72       # Allow `require('module/lib/foo')` in additon to `require('module')`.
  73       [match, name, subPath] = path.match(///^ ([^/]+) (?: /(.+) )? ///)
  74       base = require.data[moduleRoot]?[name] ? moduleRoot
  75       dir  = "#{base}/node_modules/#{name}"
  76       main = require.data[dir]?['']
  77       path = subPath ? main ? 'index'
  78       moduleRoot = dir
  79
  80     fullPath = createURI("#{dir}/#{path}.js", baseURI).spec
  81
  82     unless require.scopes[fullPath]?
  83       module =
  84         exports:    {}
  85         onShutdown: (fn) -> shutdownHandlers.push(fn)
  86       require.scopes[fullPath] = scope = {
  87         require: (path) -> require(path, moduleRoot, "./#{dirname(fullPath)}")
  88         module, exports: module.exports
  89         Cc, Ci, Cu
  90         IS_FRAME_SCRIPT, FRAME_SCRIPT_ENVIRONMENT
  91       }
  92       Services.scriptloader.loadSubScript(fullPath, scope, 'UTF-8')
  93
  94     return require.scopes[fullPath].module.exports
  95
  96   require.scopes = {}
  97   require.data   = require('./require-data')
  98
  99   unless IS_FRAME_SCRIPT
 100     # Set default prefs and apply migrations as early as possible.
 101     {applyMigrations} = require('./lib/legacy')
 102     migrations        = require('./lib/migrations')
 103     prefs             = require('./lib/prefs')
 104
 105     prefs.default.init()
 106     applyMigrations(migrations)
 107
 108   main = if IS_FRAME_SCRIPT then './lib/main-frame' else './lib/main'
 109   global.startup = require(main)
 110
 111   global.shutdown = ->
 112     require('./lib/message-manager').send('shutdown') unless IS_FRAME_SCRIPT
 113
 114     for shutdownHandler in shutdownHandlers
 115       try
 116         shutdownHandler()
 117       catch error
 118         Cu.reportError(error)
 119     shutdownHandlers = null
 120
 121     # Release everything in `require`d modules. This must be done _after_ all
 122     # shutdownHandlers, since they use variables in these scopes.
 123     for path, scope of require.scopes
 124       for name of scope
 125         scope[name] = null
 126     require.scopes = null
 127
 128   global.install = ->
 129
 130   global.uninstall = ->
 131
 132   if IS_FRAME_SCRIPT
 133     global.startup()
 134
 135     # When updating the add-on, the previous version is going to shut down at
 136     # the same time as the new version starts up. Add the shutdown listener in
 137     # the next tick to prevent the previous version from triggering it.
 138     content.setTimeout((->
 139       require('./lib/message-manager').listenOnce('shutdown', global.shutdown)
 140     ), 0)