extension/packages/commands.coffee

   1 utils = require 'utils'
   2 help  = require 'help'
   3 { _ } = require 'l10n'
   4 { getPref
   5 , getComplexPref
   6 , setPref
   7 , isPrefSet } = require 'prefs'
   8
   9 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  10
  11 # “Selecting an element” means “focusing and selecting the text, if any, of an
  12 # element”.
  13
  14 # Select the Address Bar.
  15 command_focus = (vim) ->
  16   # This function works even if the Address Bar has been removed.
  17   vim.rootWindow.focusAndSelectUrlBar()
  18
  19 # Select the Search Bar.
  20 command_focus_search = (vim) ->
  21   # The `.webSearch()` method opens a search engine in a tab if the Search Bar
  22   # has been removed. Therefore we first check if it exists.
  23   if vim.rootWindow.BrowserSearch.searchBar
  24     vim.rootWindow.BrowserSearch.webSearch()
  25
  26 helper_paste = (vim) ->
  27   url = utils.readFromClipboard(vim.window)
  28   postData = null
  29   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  30     url = submission.uri.spec
  31     { postData } = submission
  32   return {url, postData}
  33
  34 # Go to or search for the contents of the system clipboard.
  35 command_paste = (vim) ->
  36   { url, postData } = helper_paste(vim)
  37   vim.rootWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  38
  39 # Go to or search for the contents of the system clipboard in a new tab.
  40 command_paste_tab = (vim) ->
  41   { url, postData } = helper_paste(vim)
  42   vim.rootWindow.gBrowser.selectedTab =
  43     vim.rootWindow.gBrowser.addTab(url, null, null, postData, null, false)
  44
  45 # Copy the URL or text of a marker element to the system clipboard.
  46 command_marker_yank = (vim) ->
  47   callback = (marker) ->
  48     if url = marker.element.href
  49       marker.element.focus()
  50       utils.writeToClipboard(url)
  51     else if utils.isTextInputElement(marker.element)
  52       utils.writeToClipboard(marker.element.value)
  53
  54   vim.enterMode('hints', callback)
  55
  56 # Focus element.
  57 command_marker_focus = (vim) ->
  58   callback = (marker) -> marker.element.focus()
  59
  60   vim.enterMode('hints', callback)
  61
  62 # Copy the current URL to the system clipboard.
  63 command_yank = (vim) ->
  64   utils.writeToClipboard(vim.window.location.href)
  65
  66 # Reload the current tab, possibly from cache.
  67 command_reload = (vim) ->
  68   vim.rootWindow.BrowserReload()
  69
  70 # Reload the current tab, skipping cache.
  71 command_reload_force = (vim) ->
  72   vim.rootWindow.BrowserReloadSkipCache()
  73
  74 # Reload all tabs, possibly from cache.
  75 command_reload_all = (vim) ->
  76   vim.rootWindow.gBrowser.reloadAllTabs()
  77
  78 # Reload all tabs, skipping cache.
  79 command_reload_all_force = (vim) ->
  80   for tab in vim.rootWindow.gBrowser.visibleTabs
  81     window = tab.linkedBrowser.contentWindow
  82     window.location.reload(true)
  83
  84 # Stop loading the current tab.
  85 command_stop = (vim) ->
  86   vim.window.stop()
  87
  88 # Stop loading all tabs.
  89 command_stop_all = (vim) ->
  90   for tab in vim.rootWindow.gBrowser.visibleTabs
  91     window = tab.linkedBrowser.contentWindow
  92     window.stop()
  93
  94 # Scroll to the top of the page.
  95 command_scroll_to_top = (vim) ->
  96   vim.rootWindow.goDoCommand('cmd_scrollTop')
  97
  98 # Scroll to the bottom of the page.
  99 command_scroll_to_bottom = (vim) ->
 100   vim.rootWindow.goDoCommand('cmd_scrollBottom')
 101
 102 # Scroll down a bit.
 103 command_scroll_down = (vim) ->
 104   step = getPref('scroll_step_lines')
 105   utils.simulateWheel(vim.window, 0, +step, utils.WHEEL_MODE_LINE)
 106
 107 # Scroll up a bit.
 108 command_scroll_up = (vim) ->
 109   step = getPref('scroll_step_lines')
 110   utils.simulateWheel(vim.window, 0, -step, utils.WHEEL_MODE_LINE)
 111
 112 # Scroll left a bit.
 113 command_scroll_left = (vim) ->
 114   step = getPref('scroll_step_lines')
 115   utils.simulateWheel(vim.window, -step, 0, utils.WHEEL_MODE_LINE)
 116
 117 # Scroll right a bit.
 118 command_scroll_right = (vim) ->
 119   step = getPref('scroll_step_lines')
 120   utils.simulateWheel(vim.window, +step, 0, utils.WHEEL_MODE_LINE)
 121
 122 # Scroll down half a page.
 123 command_scroll_half_page_down = (vim) ->
 124   utils.simulateWheel(vim.window, 0, +0.5, utils.WHEEL_MODE_PAGE)
 125
 126 # Scroll up half a page.
 127 command_scroll_half_page_up = (vim) ->
 128   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 129
 130 # Scroll down full a page.
 131 command_scroll_page_down = (vim) ->
 132   utils.simulateWheel(vim.window, 0, +1, utils.WHEEL_MODE_PAGE)
 133
 134 # Scroll up full a page.
 135 command_scroll_page_up = (vim) ->
 136   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 137
 138 # Open a new tab and select the Address Bar.
 139 command_open_tab = (vim) ->
 140   vim.rootWindow.BrowserOpenTab()
 141
 142 # Switch to the previous tab.
 143 command_tab_prev = (vim) ->
 144   wrap = true
 145   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true) # wrap
 146
 147 # Switch to the next tab.
 148 command_tab_next = (vim) ->
 149   wrap = true
 150   vim.rootWindow.gBrowser.tabContainer.advanceSelectedTab(+1, true) # wrap
 151
 152 # Move the current tab backward.
 153 command_tab_move_left = (vim) ->
 154   { gBrowser } = vim.rootWindow
 155   lastIndex = gBrowser.tabContainer.selectedIndex
 156   gBrowser.moveTabBackward()
 157   if gBrowser.tabContainer.selectedIndex == lastIndex
 158     gBrowser.moveTabToEnd()
 159
 160 # Move the current tab forward.
 161 command_tab_move_right = (vim) ->
 162   { gBrowser } = vim.rootWindow
 163   lastIndex = gBrowser.tabContainer.selectedIndex
 164   gBrowser.moveTabForward()
 165   if gBrowser.tabContainer.selectedIndex == lastIndex
 166     gBrowser.moveTabToStart()
 167
 168 # Load the home page.
 169 command_home = (vim) ->
 170   vim.rootWindow.BrowserHome()
 171
 172 # Switch to the first tab.
 173 command_tab_first = (vim) ->
 174   vim.rootWindow.gBrowser.selectTabAtIndex(0)
 175
 176 # Switch to the last tab.
 177 command_tab_last = (vim) ->
 178   vim.rootWindow.gBrowser.selectTabAtIndex(-1)
 179
 180 # Close current tab.
 181 command_close_tab = (vim) ->
 182   unless vim.rootWindow.gBrowser.selectedTab.pinned
 183     vim.rootWindow.gBrowser.removeCurrentTab()
 184
 185 # Restore last closed tab.
 186 command_restore_tab = (vim) ->
 187   vim.rootWindow.undoCloseTab()
 188
 189 helper_follow = ({ inTab, multiple }, vim) ->
 190   callback = (matchedMarker, markers) ->
 191     if matchedMarker.element.target == '_blank'
 192       targetReset = matchedMarker.element.target
 193       matchedMarker.element.target = ''
 194
 195     matchedMarker.element.focus()
 196     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 197
 198     matchedMarker.element.target = targetReset if targetReset
 199
 200     isEditable = utils.isElementEditable(matchedMarker.element)
 201     if multiple and not isEditable
 202       # By not resetting immediately one is able to see the last char being
 203       # matched, which gives some nice visual feedback that you've typed the
 204       # right char.
 205       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 206       return true
 207
 208   vim.enterMode('hints', callback)
 209
 210 # Follow links with hint markers.
 211 command_follow = helper_follow.bind(undefined, {inTab: false})
 212
 213 # Follow links in a new Tab with hint markers.
 214 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 215
 216 # Follow multiple links with hint markers.
 217 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 218
 219 helper_follow_pattern = do ->
 220   # Search for the prev/next patterns in the following attributes of the
 221   # element. `rel` should be kept as the first attribute, since the standard
 222   # way of marking up prev/next links (`rel="prev"` and `rel="next"`) should be
 223   # favored. Even though some of these attributes only allow a fixed set of
 224   # keywords, we pattern-match them anyways since lots of sites don’t follow
 225   # the spec and use the attributes arbitrarily.
 226   attrs = ['rel', 'role', 'data-tooltip', 'aria-label']
 227
 228   return (type, vim) ->
 229     links = utils.getMarkableElements(vim.window.document, {type: 'action'})
 230       .filter(utils.isElementVisible)
 231
 232     patterns = utils.splitListString(getComplexPref("#{ type }_patterns"))
 233
 234     if matchingLink = utils.getBestPatternMatch(patterns, attrs, links)
 235       utils.simulateClick(matchingLink, {metaKey: false, ctrlKey: false})
 236
 237 # Follow previous page.
 238 command_follow_prev = helper_follow_pattern.bind(undefined, 'prev')
 239
 240 # Follow next page.
 241 command_follow_next = helper_follow_pattern.bind(undefined, 'next')
 242
 243 # Go up one level in the URL hierarchy.
 244 command_go_up_path = (vim) ->
 245   path = vim.window.location.pathname
 246   vim.window.location.pathname = path.replace(/// / [^/]+ /?$ ///, '')
 247
 248 # Go up to root of the URL hierarchy.
 249 command_go_to_root = (vim) ->
 250   vim.window.location.href = vim.window.location.origin
 251
 252 # Go back in history.
 253 command_back = (vim) ->
 254   vim.rootWindow.BrowserBack()
 255
 256 # Go forward in history.
 257 command_forward = (vim) ->
 258   vim.rootWindow.BrowserForward()
 259
 260 findStorage = {lastSearchString: ''}
 261
 262 helper_find = (highlight, vim) ->
 263   findBar = vim.rootWindow.gBrowser.getFindBar()
 264
 265   findBar.onFindCommand()
 266   findBar._findField.focus()
 267   findBar._findField.select()
 268
 269   return unless highlightButton = findBar.getElement('highlight')
 270   if highlightButton.checked != highlight
 271     highlightButton.click()
 272
 273 # Open the find bar, making sure that hightlighting is off.
 274 command_find = helper_find.bind(undefined, false)
 275
 276 # Open the find bar, making sure that hightlighting is on.
 277 command_find_hl = helper_find.bind(undefined, true)
 278
 279 helper_find_again = (direction, vim) ->
 280   findBar = vim.rootWindow.gBrowser.getFindBar()
 281   if findStorage.lastSearchString.length > 0
 282     findBar._findField.value = findStorage.lastSearchString
 283     findBar.onFindAgainCommand(direction)
 284
 285 # Search for the last pattern.
 286 command_find_next = helper_find_again.bind(undefined, false)
 287
 288 # Search for the last pattern backwards.
 289 command_find_prev = helper_find_again.bind(undefined, true)
 290
 291 # Enter insert mode.
 292 command_insert_mode = (vim) ->
 293   vim.enterMode('insert')
 294
 295 # Display the Help Dialog.
 296 command_help = (vim) ->
 297   help.injectHelp(vim.window.document, commands)
 298
 299 # Open and select the Developer Toolbar.
 300 command_dev = (vim) ->
 301   vim.rootWindow.DeveloperToolbar.show(true) # focus
 302
 303 command_Esc = (vim, event) ->
 304   utils.blurActiveElement(vim.window)
 305
 306   # Blur active XUL control.
 307   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 308   vim.window.setTimeout(callback, 0)
 309
 310   help.removeHelp(vim.window.document)
 311
 312   vim.rootWindow.DeveloperToolbar.hide()
 313
 314   vim.rootWindow.gBrowser.getFindBar().close()
 315
 316   vim.rootWindow.TabView.hide()
 317
 318
 319 class Command
 320   constructor: (@group, @name, @func, keys) ->
 321     @defaultKeys = keys
 322     @keyValues =
 323       if isPrefSet(@prefName('keys'))
 324         try JSON.parse(getPref(@prefName('keys')))
 325         catch then []
 326       else
 327         keys
 328     for key, index in @keyValues when Array.isArray(key)
 329       @keyValues[index] = key.join(',')
 330
 331   # Name of the preference for a given property.
 332   prefName: (value) -> "commands.#{ @name }.#{ value }"
 333
 334   keys: (value) ->
 335     if value is undefined
 336       return @keyValues
 337     else
 338       @keyValues = value or @defaultKeyValues
 339       setPref(@prefName('keys'), value and JSON.stringify(value))
 340
 341   help: -> _("help_command_#{ @name }")
 342
 343 commands = [
 344   new Command('urls',   'focus',                 command_focus,                 ['o'])
 345   new Command('urls',   'focus_search',          command_focus_search,          ['O'])
 346   new Command('urls',   'paste',                 command_paste,                 ['p'])
 347   new Command('urls',   'paste_tab',             command_paste_tab,             ['P'])
 348   new Command('urls',   'marker_yank',           command_marker_yank,           ['y,f'])
 349   new Command('urls',   'marker_focus',          command_marker_focus,          ['v,f'])
 350   new Command('urls',   'yank',                  command_yank,                  ['y,y'])
 351   new Command('urls',   'reload',                command_reload,                ['r'])
 352   new Command('urls',   'reload_force',          command_reload_force,          ['R'])
 353   new Command('urls',   'reload_all',            command_reload_all,            ['a,r'])
 354   new Command('urls',   'reload_all_force',      command_reload_all_force,      ['a,R'])
 355   new Command('urls',   'stop',                  command_stop,                  ['s'])
 356   new Command('urls',   'stop_all',              command_stop_all,              ['a,s'])
 357
 358   new Command('nav',    'scroll_to_top',         command_scroll_to_top ,        ['g,g'])
 359   new Command('nav',    'scroll_to_bottom',      command_scroll_to_bottom,      ['G'])
 360   new Command('nav',    'scroll_down',           command_scroll_down,           ['j', 'c-e'])
 361   new Command('nav',    'scroll_up',             command_scroll_up,             ['k', 'c-y'])
 362   new Command('nav',    'scroll_left',           command_scroll_left,           ['h'])
 363   new Command('nav',    'scroll_right',          command_scroll_right ,         ['l'])
 364   new Command('nav',    'scroll_half_page_down', command_scroll_half_page_down, ['d'])
 365   new Command('nav',    'scroll_half_page_up',   command_scroll_half_page_up,   ['u'])
 366   new Command('nav',    'scroll_page_down',      command_scroll_page_down,      ['c-f'])
 367   new Command('nav',    'scroll_page_up',        command_scroll_page_up,        ['c-b'])
 368
 369   new Command('tabs',   'open_tab',              command_open_tab,              ['t'])
 370   new Command('tabs',   'tab_prev',              command_tab_prev,              ['J', 'g,T'])
 371   new Command('tabs',   'tab_next',              command_tab_next,              ['K', 'g,t'])
 372   new Command('tabs',   'tab_move_left',         command_tab_move_left,         ['c-J'])
 373   new Command('tabs',   'tab_move_right',        command_tab_move_right,        ['c-K'])
 374   new Command('tabs',   'home',                  command_home,                  ['g,h'])
 375   new Command('tabs',   'tab_first',             command_tab_first,             ['g,H', 'g,^'])
 376   new Command('tabs',   'tab_last',              command_tab_last,              ['g,L', 'g,$'])
 377   new Command('tabs',   'close_tab',             command_close_tab,             ['x'])
 378   new Command('tabs',   'restore_tab',           command_restore_tab,           ['X'])
 379
 380   new Command('browse', 'follow',                command_follow,                ['f'])
 381   new Command('browse', 'follow_in_tab',         command_follow_in_tab,         ['F'])
 382   new Command('browse', 'follow_multiple',       command_follow_multiple,       ['a,f'])
 383   new Command('browse', 'follow_previous',       command_follow_prev,           ['['])
 384   new Command('browse', 'follow_next',           command_follow_next,           [']'])
 385   new Command('browse', 'go_up_path',            command_go_up_path,            ['g,u'])
 386   new Command('browse', 'go_to_root',            command_go_to_root,            ['g,U'])
 387   new Command('browse', 'back',                  command_back,                  ['H'])
 388   new Command('browse', 'forward',               command_forward,               ['L'])
 389
 390   new Command('misc',   'find',                  command_find,                  ['/'])
 391   new Command('misc',   'find_hl',               command_find_hl,               ['a,/'])
 392   new Command('misc',   'find_next',             command_find_next,             ['n'])
 393   new Command('misc',   'find_prev',             command_find_prev,             ['N'])
 394   new Command('misc',   'insert_mode',           command_insert_mode,           ['i'])
 395   new Command('misc',   'help',                  command_help,                  ['?'])
 396   new Command('misc',   'dev',                   command_dev,                   [':'])
 397
 398   escapeCommand =
 399   new Command('misc',   'Esc',                   command_Esc,                   ['Esc'])
 400 ]
 401
 402 searchForMatchingCommand = (keys) ->
 403   for index in [0...keys.length] by 1
 404     str = keys[index..].join(',')
 405     for command in commands
 406       for key in command.keys()
 407         # The following hack is a workaround for the issue where letter `c` is
 408         # considered a start of command with control modifier `c-xxx`.
 409         if "#{ key },".startsWith("#{ str },")
 410           return {match: true, exact: (key == str), command}
 411
 412   return {match: false}
 413
 414 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 415
 416 exports.commands                  = commands
 417 exports.searchForMatchingCommand  = searchForMatchingCommand
 418 exports.isEscCommandKey           = isEscCommandKey
 419 exports.findStorage               = findStorage