extension/packages/commands.coffee

   1 utils     = require 'utils'
   2 help      = require 'help'
   3 find      = require 'find'
   4 find_link = require 'find-link'
   5 { _ }     = require 'l10n'
   6 { getPref
   7 , getComplexPref
   8 , setPref
   9 , isPrefSet
  10 , getFirefoxPref } = require 'prefs'
  11
  12 { classes: Cc, interfaces: Ci, utils: Cu } = Components
  13
  14 # Open developer toolbar (Default shotrcut: Shift-F2)
  15 command_dev = (vim) ->
  16   if chromeWindow = utils.getRootWindow vim.window
  17     chromeWindow.DeveloperToolbar.show(true)
  18     chromeWindow.DeveloperToolbar.focus()
  19
  20 # Focus the Address Bar
  21 command_focus = (vim) ->
  22   if chromeWindow = utils.getRootWindow(vim.window)
  23     chromeWindow.focusAndSelectUrlBar()
  24
  25 # Focus the Search Bar
  26 command_focus_search = (vim) ->
  27   if chromeWindow = utils.getRootWindow(vim.window)
  28     if searchBar = chromeWindow.document.getElementById("searchbar")
  29       searchBar.select()
  30
  31 # Navigate to the address that is currently stored in the system clipboard
  32 command_paste = (vim) ->
  33   url = utils.readFromClipboard(vim.window)
  34   postData = null
  35   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  36     url = submission.uri.spec
  37     { postData } = submission
  38
  39   if chromeWindow = utils.getRootWindow(vim.window)
  40     chromeWindow.gBrowser.loadURIWithFlags(url, null, null, null, postData)
  41
  42 # Open new tab and navigate to the address that is currently stored in the system clipboard
  43 command_paste_tab = (vim) ->
  44   url = utils.readFromClipboard(vim.window)
  45   postData = null
  46   if not utils.isURL(url) and submission = utils.browserSearchSubmission(url)
  47     url = submission.uri.spec
  48     { postData } = submission
  49
  50   if chromeWindow = utils.getRootWindow vim.window
  51     chromeWindow.gBrowser.selectedTab = chromeWindow.gBrowser.addTab(url, null, null, postData, null, false)
  52
  53 # Open new tab and focus the address bar
  54 command_open_tab = (vim) ->
  55   if chromeWindow = utils.getRootWindow(vim.window)
  56     chromeWindow.BrowserOpenTab()
  57
  58 # Copy element URL to the clipboard
  59 command_marker_yank = (vim) ->
  60   callback = (marker) ->
  61     if url = marker.element.href
  62       marker.element.focus()
  63       utils.writeToClipboard(vim.window, url)
  64     else if utils.isTextInputElement(marker.element)
  65       utils.writeToClipboard(vim.window, marker.element.value)
  66
  67   vim.enterMode('hints', [callback])
  68
  69 # Focus element
  70 command_marker_focus = (vim) ->
  71   callback = (marker) -> marker.element.focus()
  72
  73   vim.enterMode('hints', [callback])
  74
  75 # Copy current URL to the clipboard
  76 command_yank = (vim) ->
  77   utils.writeToClipboard(vim.window, vim.window.location.toString())
  78
  79 # Reload the page, possibly from cache
  80 command_reload = (vim) ->
  81   vim.window.location.reload(false)
  82
  83 # Reload the page from the server
  84 command_reload_force = (vim) ->
  85   vim.window.location.reload(true)
  86
  87 # Reload the page, possibly from cache
  88 command_reload_all = (vim) ->
  89   if rootWindow = utils.getRootWindow(vim.window)
  90     if tabs = rootWindow.gBrowser.tabContainer
  91       for i in [0...tabs.itemCount]
  92         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
  93         window.location.reload(false)
  94
  95 # Reload the page from the server
  96 command_reload_all_force = (vim) ->
  97   if rootWindow = utils.getRootWindow(vim.window)
  98     if tabs = rootWindow.gBrowser.tabContainer
  99       for i in [0...tabs.itemCount]
 100         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
 101         window.location.reload(true)
 102
 103 command_stop = (vim) ->
 104   vim.window.stop()
 105
 106 command_stop_all = (vim) ->
 107   if rootWindow = utils.getRootWindow(vim.window)
 108     if tabs = rootWindow.gBrowser.tabContainer
 109       for i in [0...tabs.itemCount]
 110         window = tabs.getItemAtIndex(i).linkedBrowser.contentWindow
 111         window.stop()
 112
 113 # Scroll to the top of the page
 114 command_scroll_to_top = (vim) ->
 115   for i in [0...1000]
 116     utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 117
 118 # Scroll to the bottom of the page
 119 command_scroll_to_bottom = (vim) ->
 120   for i in [0...1000]
 121     utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 122
 123 # Scroll down a bit
 124 command_scroll_down = (vim) ->
 125   utils.simulateWheel(vim.window, 0, getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 126
 127 # Scroll up a bit
 128 command_scroll_up = (vim) ->
 129   utils.simulateWheel(vim.window, 0, -getPref('scroll_step_lines'), utils.WHEEL_MODE_LINE)
 130
 131 # Scroll left a bit
 132 command_scroll_left = (vim) ->
 133   utils.simulateWheel(vim.window, -getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 134
 135 # Scroll right a bit
 136 command_scroll_right = (vim) ->
 137   utils.simulateWheel(vim.window, getPref('scroll_step_lines'), 0, utils.WHEEL_MODE_LINE)
 138
 139 # Scroll down half a page
 140 command_scroll_half_page_down = (vim) ->
 141   utils.simulateWheel(vim.window, 0, 0.5, utils.WHEEL_MODE_PAGE)
 142
 143 # Scroll up half a page
 144 command_scroll_half_page_up = (vim) ->
 145   utils.simulateWheel(vim.window, 0, -0.5, utils.WHEEL_MODE_PAGE)
 146
 147 # Scroll down full a page
 148 command_scroll_page_down = (vim) ->
 149   utils.simulateWheel(vim.window, 0, 1, utils.WHEEL_MODE_PAGE)
 150
 151 # Scroll up full a page
 152 command_scroll_page_up = (vim) ->
 153   utils.simulateWheel(vim.window, 0, -1, utils.WHEEL_MODE_PAGE)
 154
 155 # Activate previous tab
 156 command_tab_prev = (vim) ->
 157   if rootWindow = utils.getRootWindow(vim.window)
 158     rootWindow.gBrowser.tabContainer.advanceSelectedTab(-1, true)
 159
 160 # Activate next tab
 161 command_tab_next = (vim) ->
 162   if rootWindow = utils.getRootWindow(vim.window)
 163     rootWindow.gBrowser.tabContainer.advanceSelectedTab(1, true)
 164
 165 command_home = (vim) ->
 166   url = getFirefoxPref('browser.startup.homepage')
 167   if chromeWindow = utils.getRootWindow(vim.window)
 168     chromeWindow.gBrowser.loadURIWithFlags(url, null, null, null, null)
 169
 170 # Go to the first tab
 171 command_tab_first = (vim) ->
 172   if rootWindow = utils.getRootWindow(vim.window)
 173     rootWindow.gBrowser.tabContainer.selectedIndex = 0
 174
 175 # Go to the last tab
 176 command_tab_last = (vim) ->
 177   if rootWindow = utils.getRootWindow(vim.window)
 178     itemCount = rootWindow.gBrowser.tabContainer.itemCount
 179     rootWindow.gBrowser.tabContainer.selectedIndex = itemCount - 1
 180
 181 # Go back in history
 182 command_back = (vim) ->
 183   vim.window.history.back()
 184
 185 # Go forward in history
 186 command_forward = (vim) ->
 187   vim.window.history.forward()
 188
 189 # Close current tab
 190 command_close_tab = (vim) ->
 191   if rootWindow = utils.getRootWindow(vim.window)
 192     unless rootWindow.gBrowser.selectedTab.pinned
 193       rootWindow.gBrowser.removeCurrentTab()
 194
 195 # Restore last closed tab
 196 command_restore_tab = (vim) ->
 197   if rootWindow = utils.getRootWindow(vim.window)
 198     ss = utils.getSessionStore()
 199     if ss and ss.getClosedTabCount(rootWindow) > 0
 200       ss.undoCloseTab(rootWindow, 0)
 201
 202 helper_follow = ({ inTab, multiple }, vim) ->
 203   callback = (matchedMarker, markers) ->
 204     matchedMarker.element.focus()
 205     utils.simulateClick(matchedMarker.element, {metaKey: inTab, ctrlKey: inTab})
 206     isEditable = utils.isElementEditable(matchedMarker.element)
 207     if multiple and not isEditable
 208       # By not resetting immediately one is able to see the last char being matched, which gives
 209       # some nice visual feedback that you've typed the right char.
 210       vim.window.setTimeout((-> marker.reset() for marker in markers), 100)
 211       return true
 212
 213   vim.enterMode('hints', [callback])
 214
 215 # Follow links with hint markers
 216 command_follow = helper_follow.bind(undefined, {inTab: false})
 217
 218 # Follow links in a new Tab with hint markers
 219 command_follow_in_tab = helper_follow.bind(undefined, {inTab: true})
 220
 221 # Follow multiple links with hint markers
 222 command_follow_multiple = helper_follow.bind(undefined, {inTab: true, multiple: true})
 223
 224 helper_follow_link = ({ type, inTab }, vim) ->
 225   patterns = getComplexPref("#{ type }_patterns").split(',')
 226   link = find_link.find(vim.window.document, patterns)
 227   utils.simulateClick(link, {metaKey: inTab, ctrlKey: inTab}) if link
 228
 229 # Follow previous page
 230 command_follow_prev = helper_follow_link.bind(undefined, { type: 'prev', inTab: false })
 231
 232 # Follow next page
 233 command_follow_next = helper_follow_link.bind(undefined, { type: 'next', inTab: false })
 234
 235 # Move current tab to the left
 236 command_tab_move_left = (vim) ->
 237   if gBrowser = utils.getRootWindow(vim.window)?.gBrowser
 238     if tab = gBrowser.selectedTab
 239       index = gBrowser.tabContainer.selectedIndex
 240       total = gBrowser.tabContainer.itemCount
 241
 242       # `total` is added to deal with negative offset
 243       gBrowser.moveTabTo(tab, (total + index - 1) % total)
 244
 245 # Move current tab to the right
 246 command_tab_move_right = (vim) ->
 247   if gBrowser = utils.getRootWindow(vim.window)?.gBrowser
 248     if tab = gBrowser.selectedTab
 249       index = gBrowser.tabContainer.selectedIndex
 250       total = gBrowser.tabContainer.itemCount
 251
 252       gBrowser.moveTabTo(tab, (index + 1) % total)
 253
 254 # Display the Help Dialog
 255 command_help = (vim) ->
 256   help.injectHelp(vim.window.document, commands)
 257
 258 find.findStr = ''
 259
 260 # Switch into find mode
 261 command_find = (vim, storage) ->
 262   find.injectFind vim.window.document, (findStr, startFindRng) ->
 263     # Reset region and find string if new find stirng has arrived
 264     if find.findStr != findStr
 265       [find.findStr, storage.findRng] = [findStr, startFindRng]
 266     # Perform forward find and store found region
 267     return storage.findRng = find.find(vim.window, find.findStr, storage.findRng, find.DIRECTION_FORWARDS)
 268
 269 # Switch into find mode with highlighting
 270 command_find_hl = (vim, storage) ->
 271   find.injectFind vim.window.document, (findStr) ->
 272     # Reset region and find string if new find stirng has arrived
 273     return find.highlight(vim.window, findStr)
 274
 275 # Search for the last pattern
 276 command_find_next = (vim, storage) ->
 277   if find.findStr.length > 0
 278     storage.findRng = find.find(vim.window, find.findStr, storage.findRng, find.DIRECTION_FORWARDS, true)
 279
 280 # Search for the last pattern backwards
 281 command_find_prev = (vim, storage) ->
 282   if find.findStr.length > 0
 283     storage.findRng = find.find(vim.window, find.findStr, storage.findRng, find.DIRECTION_BACKWARDS, true)
 284
 285 command_insert_mode = (vim) ->
 286   vim.enterMode('insert')
 287
 288 command_Esc = (vim, storage, event) ->
 289   utils.blurActiveElement(vim.window)
 290
 291   # Blur active XUL control
 292   callback = -> event.originalTarget?.ownerDocument?.activeElement?.blur()
 293   vim.window.setTimeout(callback, 0)
 294
 295   find.removeFind(vim.window.document)
 296
 297   help.removeHelp(vim.window.document)
 298
 299   if rootWindow = utils.getRootWindow(vim.window)
 300     rootWindow.DeveloperToolbar.hide()
 301
 302
 303 class Command
 304   constructor: (@group, @name, @func, keys) ->
 305     @defaultKeys = keys
 306     if isPrefSet(@prefName('keys'))
 307       try @keyValues = JSON.parse(getPref(@prefName('keys')))
 308     else
 309       @keyValues = keys
 310
 311   # Name of the preference for a given property
 312   prefName: (value) -> "commands.#{ @name }.#{ value }"
 313
 314   keys: (value) ->
 315     if value is undefined
 316       return @keyValues
 317     else
 318       @keyValues = value or @defaultKeyValues
 319       setPref(@prefName('keys'), value and JSON.stringify(value))
 320
 321   help: -> _("help_command_#{ @name }")
 322
 323 commands = [
 324   new Command('urls',   'focus',                  command_focus,                  ['o'])
 325   new Command('urls',   'focus_search',           command_focus_search,           ['O'])
 326   new Command('urls',   'paste',                  command_paste,                  ['p'])
 327   new Command('urls',   'paste_tab',              command_paste_tab,              ['P'])
 328   new Command('urls',   'marker_yank',            command_marker_yank,            ['y,f'])
 329   new Command('urls',   'marker_focus',           command_marker_focus,           ['v,f'])
 330   new Command('urls',   'yank',                   command_yank,                   ['y,y'])
 331   new Command('urls',   'reload',                 command_reload,                 ['r'])
 332   new Command('urls',   'reload_force',           command_reload_force,           ['R'])
 333   new Command('urls',   'reload_all',             command_reload_all,             ['a,r'])
 334   new Command('urls',   'reload_all_force',       command_reload_all_force,       ['a,R'])
 335   new Command('urls',   'stop',                   command_stop,                   ['s'])
 336   new Command('urls',   'stop_all',               command_stop_all,               ['a,s'])
 337
 338   new Command('nav',    'scroll_to_top',          command_scroll_to_top ,         ['g,g'])
 339   new Command('nav',    'scroll_to_bottom',       command_scroll_to_bottom,       ['G'])
 340   new Command('nav',    'scroll_down',            command_scroll_down,            ['j', 'c-e'])
 341   new Command('nav',    'scroll_up',              command_scroll_up,              ['k', 'c-y'])
 342   new Command('nav',    'scroll_left',            command_scroll_left,            ['h'])
 343   new Command('nav',    'scroll_right',           command_scroll_right ,          ['l'])
 344   new Command('nav',    'scroll_half_page_down',  command_scroll_half_page_down,  ['d'])
 345   new Command('nav',    'scroll_half_page_up',    command_scroll_half_page_up,    ['u'])
 346   new Command('nav',    'scroll_page_down',       command_scroll_page_down,       ['c-f'])
 347   new Command('nav',    'scroll_page_up',         command_scroll_page_up,         ['c-b'])
 348
 349   new Command('tabs',   'open_tab',               command_open_tab,               ['t'])
 350   new Command('tabs',   'tab_prev',               command_tab_prev,               ['J', 'g,T'])
 351   new Command('tabs',   'tab_next',               command_tab_next,               ['K', 'g,t'])
 352   new Command('tabs',   'tab_move_left',          command_tab_move_left,          ['c-J'])
 353   new Command('tabs',   'tab_move_right',         command_tab_move_right,         ['c-K'])
 354   new Command('tabs',   'home',                   command_home,                   ['g,h'])
 355   new Command('tabs',   'tab_first',              command_tab_first,              ['g,H', 'g,^'])
 356   new Command('tabs',   'tab_last',               command_tab_last,               ['g,L', 'g,$'])
 357   new Command('tabs',   'close_tab',              command_close_tab,              ['x'])
 358   new Command('tabs',   'restore_tab',            command_restore_tab,            ['X'])
 359
 360   new Command('browse', 'follow',                 command_follow,                 ['f'])
 361   new Command('browse', 'follow_in_tab',          command_follow_in_tab,          ['F'])
 362   new Command('browse', 'follow_multiple',        command_follow_multiple,        ['a,f'])
 363   new Command('browse', 'follow_previous',        command_follow_prev,            ['['])
 364   new Command('browse', 'follow_next',            command_follow_next,            [']'])
 365   new Command('browse', 'back',                   command_back,                   ['H'])
 366   new Command('browse', 'forward',                command_forward,                ['L'])
 367
 368   new Command('misc',   'find',                   command_find,                   ['/'])
 369   new Command('misc',   'find_hl',                command_find_hl,                ['a,/'])
 370   new Command('misc',   'find_next',              command_find_next,              ['n'])
 371   new Command('misc',   'find_prev',              command_find_prev,              ['N'])
 372   new Command('misc',   'insert_mode',            command_insert_mode,            ['i'])
 373   new Command('misc',   'help',                   command_help,                   ['?'])
 374   new Command('misc',   'dev',                    command_dev,                    [':'])
 375
 376   escapeCommand =
 377   new Command('misc',   'Esc',                    command_Esc,                    ['Esc'])
 378 ]
 379
 380 searchForMatchingCommand = (keys) ->
 381   for index in [0...keys.length] by 1
 382     str = keys[index..].join(',')
 383     for command in commands
 384       for key in command.keys()
 385         if key.startsWith(str)
 386           return {match: true, exact: (key == str), command}
 387
 388   return {match: false}
 389
 390 isEscCommandKey = (keyStr) -> keyStr in escapeCommand.keys()
 391
 392 exports.commands                  = commands
 393 exports.searchForMatchingCommand  = searchForMatchingCommand
 394 exports.isEscCommandKey           = isEscCommandKey