tmk_core/protocol/usb_hid/USB_Host_Shield_2.0/examples/Xbox/XBOXRECV/XBOXRECV.ino

   1 /*
   2  Example sketch for the Xbox Wireless Reciver library - developed by Kristian Lauszus
   3  It supports up to four controllers wirelessly
   4  For more information see the blog post: http://blog.tkjelectronics.dk/2012/12/xbox-360-receiver-added-to-the-usb-host-library/ or
   5  send me an e-mail:  kristianl@tkjelectronics.com
   6  */
   7
   8 #include <XBOXRECV.h>
   9
  10 // Satisfy the IDE, which needs to see the include statment in the ino too.
  11 #ifdef dobogusinclude
  12 #include <spi4teensy3.h>
  13 #include <SPI.h>
  14 #endif
  15
  16 USB Usb;
  17 XBOXRECV Xbox(&Usb);
  18
  19 void setup() {
  20   Serial.begin(115200);
  21 #if !defined(__MIPSEL__)
  22   while (!Serial); // Wait for serial port to connect - used on Leonardo, Teensy and other boards with built-in USB CDC serial connection
  23 #endif
  24   if (Usb.Init() == -1) {
  25     Serial.print(F("\r\nOSC did not start"));
  26     while (1); //halt
  27   }
  28   Serial.print(F("\r\nXbox Wireless Receiver Library Started"));
  29 }
  30 void loop() {
  31   Usb.Task();
  32   if (Xbox.XboxReceiverConnected) {
  33     for (uint8_t i = 0; i < 4; i++) {
  34       if (Xbox.Xbox360Connected[i]) {
  35         if (Xbox.getButtonPress(L2, i) || Xbox.getButtonPress(R2, i)) {
  36           Serial.print("L2: ");
  37           Serial.print(Xbox.getButtonPress(L2, i));
  38           Serial.print("\tR2: ");
  39           Serial.println(Xbox.getButtonPress(R2, i));
  40           Xbox.setRumbleOn(Xbox.getButtonPress(L2, i), Xbox.getButtonPress(R2, i), i);
  41         }
  42
  43         if (Xbox.getAnalogHat(LeftHatX, i) > 7500 || Xbox.getAnalogHat(LeftHatX, i) < -7500 || Xbox.getAnalogHat(LeftHatY, i) > 7500 || Xbox.getAnalogHat(LeftHatY, i) < -7500 || Xbox.getAnalogHat(RightHatX, i) > 7500 || Xbox.getAnalogHat(RightHatX, i) < -7500 || Xbox.getAnalogHat(RightHatY, i) > 7500 || Xbox.getAnalogHat(RightHatY, i) < -7500) {
  44           if (Xbox.getAnalogHat(LeftHatX, i) > 7500 || Xbox.getAnalogHat(LeftHatX, i) < -7500) {
  45             Serial.print(F("LeftHatX: "));
  46             Serial.print(Xbox.getAnalogHat(LeftHatX, i));
  47             Serial.print("\t");
  48           }
  49           if (Xbox.getAnalogHat(LeftHatY, i) > 7500 || Xbox.getAnalogHat(LeftHatY, i) < -7500) {
  50             Serial.print(F("LeftHatY: "));
  51             Serial.print(Xbox.getAnalogHat(LeftHatY, i));
  52             Serial.print("\t");
  53           }
  54           if (Xbox.getAnalogHat(RightHatX, i) > 7500 || Xbox.getAnalogHat(RightHatX, i) < -7500) {
  55             Serial.print(F("RightHatX: "));
  56             Serial.print(Xbox.getAnalogHat(RightHatX, i));
  57             Serial.print("\t");
  58           }
  59           if (Xbox.getAnalogHat(RightHatY, i) > 7500 || Xbox.getAnalogHat(RightHatY, i) < -7500) {
  60             Serial.print(F("RightHatY: "));
  61             Serial.print(Xbox.getAnalogHat(RightHatY, i));
  62           }
  63           Serial.println();
  64         }
  65
  66         if (Xbox.getButtonClick(UP, i)) {
  67           Xbox.setLedOn(LED1, i);
  68           Serial.println(F("Up"));
  69         }
  70         if (Xbox.getButtonClick(DOWN, i)) {
  71           Xbox.setLedOn(LED4, i);
  72           Serial.println(F("Down"));
  73         }
  74         if (Xbox.getButtonClick(LEFT, i)) {
  75           Xbox.setLedOn(LED3, i);
  76           Serial.println(F("Left"));
  77         }
  78         if (Xbox.getButtonClick(RIGHT, i)) {
  79           Xbox.setLedOn(LED2, i);
  80           Serial.println(F("Right"));
  81         }
  82
  83         if (Xbox.getButtonClick(START, i)) {
  84           Xbox.setLedMode(ALTERNATING, i);
  85           Serial.println(F("Start"));
  86         }
  87         if (Xbox.getButtonClick(BACK, i)) {
  88           Xbox.setLedBlink(ALL, i);
  89           Serial.println(F("Back"));
  90         }
  91         if (Xbox.getButtonClick(L3, i))
  92           Serial.println(F("L3"));
  93         if (Xbox.getButtonClick(R3, i))
  94           Serial.println(F("R3"));
  95
  96         if (Xbox.getButtonClick(L1, i))
  97           Serial.println(F("L1"));
  98         if (Xbox.getButtonClick(R1, i))
  99           Serial.println(F("R1"));
 100         if (Xbox.getButtonClick(XBOX, i)) {
 101           Xbox.setLedMode(ROTATING, i);
 102           Serial.print(F("Xbox (Battery: "));
 103           Serial.print(Xbox.getBatteryLevel(i)); // The battery level in the range 0-3
 104           Serial.println(F(")"));
 105         }
 106         if (Xbox.getButtonClick(SYNC, i)) {
 107           Serial.println(F("Sync"));
 108           Xbox.disconnect(i);
 109         }
 110
 111         if (Xbox.getButtonClick(A, i))
 112           Serial.println(F("A"));
 113         if (Xbox.getButtonClick(B, i))
 114           Serial.println(F("B"));
 115         if (Xbox.getButtonClick(X, i))
 116           Serial.println(F("X"));
 117         if (Xbox.getButtonClick(Y, i))
 118           Serial.println(F("Y"));
 119       }
 120     }
 121   }
 122 }